modules/roles/manifests/keyring.pp

   1 class roles::keyring {
   2   include apache2
   3
   4   rsync::site { 'keyring':
   5     source  => 'puppet:///modules/roles/keyring/rsyncd.conf',
   6     sslname => 'keyring.debian.org',
   7   }
   8
   9   ssl::service { 'keyring.debian.org':
  10     notify   => Exec['service apache2 reload'],
  11     key      => true,
  12     tlsaport => [443, 1873],
  13   }
  14
  15   include named::authoritative
  16
  17   $notify_address_bind = join(getfromhash($deprecated::allnodeinfo, 'denis.debian.org', 'ipHostNumber'), '; ')
  18
  19   ferm::rule::simple { 'keyserver':
  20     port => 11371
  21   }
  22
  23   Ferm::Rule::Simple <<| tag == 'named::keyring::ferm' |>>
  24
  25   concat::fragment { 'dsa-named-conf-puppet-misc---openpgpkey-zone':
  26     target  => '/etc/bind/named.conf.puppet-misc',
  27     order   => '020',
  28     content => @("EOF"),
  29       zone "_openpgpkey.debian.org" {
  30         type master;
  31         file "/srv/keyring.debian.org/_openpgpkey.debian.org.zone";
  32         allow-query { any; };
  33         allow-transfer {
  34           key tsig-denis.debian.org-kaufmann.debian.org ;
  35           127.0.0.1;
  36         };
  37         also-notify {
  38           ${notify_address_bind};
  39         };
  40       };
  41       | EOF
  42   }
  43
  44 }