modules/roles/manifests/debtags.pp

   1 # debtags.debian.org role
   2 #
   3 # @param db_address     hostname of the postgres server for this service
   4 # @param db_port        port of the postgres server for this service
   5 class roles::debtags (
   6   String  $db_address,
   7   Integer $db_port,
   8 ) {
   9   include apache2
  10   include apache2::ssl
  11   include roles::sso_rp
  12
  13   package { 'libapache2-mod-wsgi-py3': ensure => installed, }
  14   apache2::module { 'wsgi': require => Package['libapache2-mod-wsgi-py3'] }
  15
  16   ssl::service { 'debtags.debian.org':
  17     notify => Exec['service apache2 reload'],
  18     key    => true,
  19   }
  20
  21   apache2::site { '010-debtags.debian.org':
  22     site   => 'debtags.debian.org',
  23     source => 'puppet:///modules/roles/debtags/debtags.debian.org',
  24   }
  25
  26   @@postgres::cluster::hba_entry { "debtags-${::fqdn}":
  27     tag      => "postgres::cluster::${db_port}::hba::${db_address}",
  28     pg_port  => $db_port,
  29     database => 'debtags',
  30     user     => 'debtags',
  31     address  => $base::public_addresses,
  32   }
  33 }