modules/postgres/manifests/cluster/hba_entry.pp

   1 # An entry in pg_hba and the corresponding firewall rule if necessary
   2 #
   3 # This currently only supports a limited number of entry types.  Only
   4 # what we need at the moment.
   5 #
   6 # See the upstream documentation at https://www.postgresql.org/docs/11/auth-pg-hba-conf.html
   7 # for details.
   8 #
   9 # @param pg_port          port of the postgres cluster
  10 # @param pg_cluster       cluster name
  11 # @param pg_version       pg version of the cluster
  12 # @param connection_type  connection type
  13 # @param database         database (or all, sameuser, replication, etc.)
  14 # @param user             user (or all, etc.)
  15 # @param address          hosts that match
  16 # @param method           auth method
  17 # @param order            ordering of this entry in pg_hba.conf
  18 define postgres::cluster::hba_entry (
  19   Optional[Integer] $pg_port = undef,
  20   Optional[String] $pg_cluster = undef,
  21   Optional[String] $pg_version = undef,
  22   Enum['local', 'hostssl'] $connection_type = 'hostssl',
  23   Variant[String,Array[String]] $database = 'sameuser',
  24   Variant[String,Array[String]] $user = 'all',
  25   Optional[Variant[Stdlib::IP::Address, Array[Stdlib::IP::Address]]] $address = undef,
  26   Enum['md5', 'trust'] $method = 'md5',
  27   String $order = '50',
  28 ) {
  29   $address_methods = ['md5']
  30   if $method in $address_methods {
  31     if !$address {
  32       fail("Authentication method ${method} needs an address")
  33     }
  34   } else {
  35     if !($method in $address_methods) {
  36       fail("Authentication method ${method} needs no address")
  37     }
  38   }
  39
  40   # get remaining cluster info and verify consistency
  41   ###
  42   $clusters = $facts['postgresql_clusters']
  43   if $pg_port {
  44     $filtered = $clusters.filter |$cluster| { $cluster['port'] == $pg_port }
  45     if $filtered.length != 1 {
  46       fail("Did not find exactly one cluster with port ${pg_port}")
  47     }
  48     $cluster = $filtered[0]
  49   } elsif $pg_cluster and $pg_version {
  50     $filtered = $clusters.filter |$cluster| { $cluster['version'] == $pg_version and $cluster['cluster'] == $pg_cluster}
  51     if $filtered.length != 1 {
  52       fail("Did not find exactly one cluster ${pg_version}/${pg_cluster}")
  53     }
  54     $cluster = $filtered[0]
  55   } else {
  56     fail('postgres::cluster::hba_entry needs either the port of both a pg version and cluster name')
  57   }
  58   $real_port    = $cluster['port']
  59   $real_version = $cluster['version']
  60   $real_cluster = $cluster['cluster']
  61   if $pg_version and $pg_version != $real_version {
  62     fail("Inconsisten cluster version information: ${pg_version} != ${real_version}")
  63   }
  64   if $pg_cluster and $pg_cluster != $real_cluster {
  65     fail("Inconsisten cluster name information: ${pg_cluster} != ${real_cluster}")
  66   }
  67   ###
  68
  69   if ($address) {
  70     ferm::rule::simple { "postgres::cluster::hba_entry::${name}":
  71       description => "allow access to pg${real_version}/${real_cluster}: ${name}",
  72       saddr       => $address,
  73       chain       => "pg-${real_port}",
  74     }
  75   }
  76
  77   $real_database = Array($database, true).sort().join(',')
  78   $real_user     = Array($user, true).sort().join(',')
  79   $real_address  = $address ? {
  80     undef   => [''],
  81     default => Array($address, true).map |$a| {
  82       if    $a =~ Stdlib::IP::Address::V4::CIDR     { $a }
  83       elsif $a =~ Stdlib::IP::Address::V4::Nosubnet { "${a}/32" }
  84       elsif $a =~ Stdlib::IP::Address::V6::CIDR     { $a }
  85       elsif $a =~ Stdlib::IP::Address::V6::Nosubnet { "${a}/128" }
  86       else { fail("Do not know address type for ${a}") }
  87     }
  88   }
  89
  90   @concat::fragment { "postgres::cluster::pg_hba::${name}":
  91     tag     => "postgres::cluster::${real_version}::${real_cluster}::hba",
  92     target  => "postgres::cluster::${real_version}::${real_cluster}::hba",
  93     order   => $order,
  94     content => inline_template( @(EOF) ),
  95                   #
  96                   # rule <%= @name %>
  97                   <% @real_address.each do |addr| -%>
  98                   <%= [@connection_type, @real_database, @real_user, addr, @method].join(' ') %>
  99                   <% end -%>
 100                   #
 101                   | EOF
 102   }
 103 }