modules/postgres/manifests/backup_server.pp

   1 #
   2 class postgres::backup_server::globals {
   3         $make_base_backups = '/usr/local/bin/postgres-make-base-backups'
   4         $pgpassfile = '/home/debbackup/.pgpass'
   5         $sshkeys_sources = '/etc/dsa/postgresql-backup/sshkeys-sources'
   6
   7         $tag_base_backup = "postgresql::server::backup-source-make-base-backup-entry"
   8         $tag_source_sshkey = "postgresql::server::backup-source-sshkey"
   9         $tag_source_pgpassline = "postgresql::server::backup-source-pgpassline"
  10         $tag_dsa_check_backupp = "postgresql::server::backup-dsa-check-backuppg"
  11 }
  12
  13 class postgres::backup_server {
  14         include postgres::backup_server::globals
  15
  16         ####
  17         # Regularly pull base backups
  18         #
  19         ensure_packages ( "postgresql-client-9.1", { ensure => 'installed' })
  20         ensure_packages ( "postgresql-client-9.4", { ensure => 'installed' })
  21
  22         concat { $postgres::backup_server::globals::make_base_backups:
  23                 mode => '0555',
  24         }
  25         concat::fragment { 'make-base-backups-header':
  26                 target => $postgres::backup_server::globals::make_base_backups,
  27                 content => template('postgres/backup_server/postgres-make-base-backups.erb'),
  28                 order  => '00',
  29         }
  30         Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_base_backup |>>
  31         concat::fragment { 'make-base-backups-tail':
  32                 target => $postgres::backup_server::globals::make_base_backups,
  33                 content  => @(EOTEMPLATE),
  34                                 # EOF by make-base-backups-tail fragment
  35                                 EOF
  36                                 | EOTEMPLATE
  37                 order  => '99',
  38         }
  39         file { '/etc/cron.d/puppet-postgres-make-base-backups': ensure => absent; }
  40         file { '/var/lib/dsa/postgres-make-base-backups':
  41                 ensure => directory,
  42                 owner => 'debbackup',
  43                 mode => '0755',
  44         }
  45         concat::fragment { 'dsa-puppet-stuff--postgres-make_base_backups':
  46                 target => '/etc/cron.d/dsa-puppet-stuff',
  47                 content  => @("EOF")
  48                         */30 * * * * debbackup sleep $(( RANDOM \% 1200 )); chronic ${$postgres::backup_server::globals::make_base_backups}
  49                         | EOF
  50         }
  51
  52         ####
  53         # Maintain authorized_keys file on backup servers for WAL shipping
  54         #
  55         # do not let other hosts directly build our authorized_keys file,
  56         # instead go via a script that somewhat validates intput
  57         file { '/etc/dsa/postgresql-backup':
  58                 ensure => 'directory',
  59         }
  60         file { '/usr/local/bin/postgres-make-backup-sshauthkeys':
  61                 content => template('postgres/backup_server/postgres-make-backup-sshauthkeys.erb'),
  62                 mode   => '0555',
  63                 notify  => Exec['postgres-make-backup-sshauthkeys'],
  64         }
  65         file { '/usr/local/bin/postgres-make-one-base-backup':
  66                 source  => 'puppet:///modules/postgres/backup_server/postgres-make-one-base-backup',
  67                 mode   => '0555'
  68         }
  69         file { '/etc/dsa/postgresql-backup/sshkeys-manual':
  70                 content => template('postgres/backup_server/sshkeys-manual.erb'),
  71                 notify  => Exec['postgres-make-backup-sshauthkeys'],
  72         }
  73         concat { $postgres::backup_server::globals::sshkeys_sources:
  74                 notify  => Exec['postgres-make-backup-sshauthkeys'],
  75         }
  76         concat::fragment { 'postgresql-backup/source-sshkeys-header':
  77                 target => $postgres::backup_server::globals::sshkeys_sources ,
  78                 content  => @(EOF),
  79                                 # <name> <ip addresses> <key>
  80                                 | EOF
  81                 order  => '00',
  82         }
  83         Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_sshkey |>>
  84         exec { "postgres-make-backup-sshauthkeys":
  85                 command => "/usr/local/bin/postgres-make-backup-sshauthkeys",
  86                 refreshonly => true,
  87         }
  88
  89         ####
  90         # Maintain /etc/nagios/dsa-check-backuppg.conf
  91         #
  92         file { '/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d':
  93                 ensure => 'directory',
  94                 purge   => true,
  95                 force   => true,
  96                 recurse => true,
  97                 source  => 'puppet:///files/empty/',
  98                 notify => Exec['update dsa-check-backuppg-manual.conf'],
  99         }
 100         file { '/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/manual.conf':
 101                 content => template('postgres/backup_server/dsa-check-backuppg-manual.conf.erb'),
 102                 notify => Exec['update dsa-check-backuppg-manual.conf']
 103         }
 104         file { '/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/moszumanska.conf':
 105                 ensure => 'absent',
 106                 notify => Exec['update dsa-check-backuppg-manual.conf']
 107         }
 108         File<<| tag == $postgres::backup_server::globals::tag_dsa_check_backupp |>>
 109         ensure_packages ( "libhash-merge-simple-perl", { ensure => 'installed' })
 110         exec { "update dsa-check-backuppg-manual.conf":
 111                 command  => @(EOF),
 112                                 perl -MYAML=LoadFile,Dump -MHash::Merge::Simple=merge -E 'say Dump(merge(map{LoadFile($_)}@ARGV))' /etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/*.conf > /etc/nagios/dsa-check-backuppg.conf
 113                                 | EOF
 114                 provider => shell,
 115                 refreshonly => true,
 116         }
 117
 118         ####
 119         # Maintain .pgpass file on backup servers
 120         # #
 121         concat { $postgres::backup_server::globals::pgpassfile:
 122                 owner => 'debbackup',
 123                 group => 'debbackup',
 124                 mode  => '0400'
 125         }
 126         concat::fragment{ 'pgpass-local':
 127                 target => $postgres::backup_server::globals::pgpassfile,
 128                 source => '/home/debbackup/.pgpass-local',
 129                 order  => '00'
 130         }
 131         Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_pgpassline |>>
 132 }
 133
 134 define postgres::backup_server::register_backup_clienthost (
 135         $sshpubkey = $::postgresql_key,
 136         $ipaddrlist = join(getfromhash($site::nodeinfo, 'ldap', 'ipHostNumber'), ","),
 137         $hostname = $::hostname,
 138 ) {
 139         include postgres::backup_server::globals
 140
 141         if $sshpubkey {
 142                 $addr = assert_type(String[1], $ipaddrlist)
 143                 @@concat::fragment { "postgresql::server::backup-source-clienthost::$name::$fqdn":
 144                         target => $postgres::backup_server::globals::sshkeys_sources ,
 145                         content  => @("EOF"),
 146                                         ${hostname} ${addr} ${sshpubkey}
 147                                         | EOF
 148                         tag     => $postgres::backup_server::globals::tag_source_sshkey,
 149                 }
 150         }
 151 }
 152
 153 define postgres::backup_server::register_backup_cluster (
 154         $hostname = $::hostname,
 155         $fqdn = $::fqdn,
 156         $pg_port,
 157         $pg_role,
 158         $pg_password,
 159         $pg_cluster,
 160         $pg_version,
 161 ) {
 162         include postgres::backup_server::globals
 163
 164         # foobar.debian.org:5432:*:debian-backup:swordfish
 165         @@concat::fragment { "postgresql::server::backup-source-pgpassline::$hostname::$pg_port::$pg_role":
 166                 target => $postgres::backup_server::globals::pgpassfile,
 167                 content => @("EOF"),
 168                                 ${fqdn}:${pg_port}:*:${pg_role}:${pg_password}
 169                                 | EOF
 170                 tag     => $postgres::backup_server::globals::tag_source_pgpassline,
 171         }
 172         #
 173         # vittoria.debian.org   5432    debian-backup           main            9.6
 174         @@concat::fragment { "postgresql::server::backup-source-make-base-backup-entry::$hostname::$pg_port::$pg_role":
 175                 target => $postgres::backup_server::globals::make_base_backups,
 176                 content => @("EOF"),
 177                                 ${fqdn} ${pg_port}      ${pg_role}      ${pg_cluster}   ${pg_version}
 178                                 | EOF
 179                 tag     => $postgres::backup_server::globals::tag_base_backup,
 180         }
 181
 182         @@file { "/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/${hostname}-${pg_cluster}.conf":
 183                 content  => @("EOF"),
 184                                 ---
 185                                 backups:
 186                                   ${hostname}:
 187                                     ${pg_cluster}:
 188                                 | EOF
 189                 tag     => $postgres::backup_server::globals::tag_dsa_check_backupp,
 190                 notify  => Exec['update dsa-check-backuppg-manual.conf']
 191         }
 192 }