modules/postgres/manifests/backup_server.pp

   1 #
   2 class postgres::backup_server {
   3   include postgres::backup_server::globals
   4
   5   $make_base_backups = '/usr/local/bin/postgres-make-base-backups'
   6
   7   ensure_packages ( [
   8     'libhash-merge-simple-perl',
   9     'libyaml-perl',
  10     'python-yaml',
  11     'pigz',
  12     'postgresql-client',
  13     'postgresql-client-9.6',
  14   ], {
  15     ensure => 'installed'
  16   })
  17
  18   ####
  19   # Regularly pull base backups
  20   #
  21   concat { $postgres::backup_server::globals::base_backup_clusters:
  22     ensure_newline => true,
  23   }
  24   Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_base_backup |>>
  25
  26   file { $make_base_backups:
  27     mode    => '0555',
  28     content => template('postgres/backup_server/postgres-make-base-backups.erb'),
  29   }
  30   file { '/var/lib/dsa/postgres-make-base-backups':
  31     ensure => directory,
  32     owner  => 'debbackup',
  33     mode   => '0755',
  34   }
  35   concat::fragment { 'puppet-crontab--postgres-make_base_backups':
  36     target  => '/etc/cron.d/puppet-crontab',
  37     content => @("EOF")
  38       */30 * * * * debbackup sleep $(( RANDOM \% 1200 )); chronic ${make_base_backups}
  39       | EOF
  40   }
  41
  42   ####
  43   # Maintain authorized_keys file on backup servers for WAL shipping
  44   #
  45   # do not let other hosts directly build our authorized_keys file,
  46   # instead go via a script that somewhat validates intput
  47   file { '/etc/dsa/postgresql-backup':
  48     ensure => 'directory',
  49   }
  50   file { '/usr/local/bin/postgres-make-backup-sshauthkeys':
  51     content => template('postgres/backup_server/postgres-make-backup-sshauthkeys.erb'),
  52     mode    => '0555',
  53     notify  => Exec['postgres-make-backup-sshauthkeys'],
  54   }
  55   file { '/usr/local/bin/postgres-make-one-base-backup':
  56     source => 'puppet:///modules/postgres/backup_server/postgres-make-one-base-backup',
  57     mode   => '0555'
  58   }
  59   file { '/etc/dsa/postgresql-backup/sshkeys-manual':
  60     content => template('postgres/backup_server/sshkeys-manual.erb'),
  61     notify  => Exec['postgres-make-backup-sshauthkeys'],
  62   }
  63   concat { $postgres::backup_server::globals::sshkeys_sources:
  64     notify => Exec['postgres-make-backup-sshauthkeys'],
  65   }
  66   concat::fragment { 'postgresql-backup/source-sshkeys-header':
  67     target  => $postgres::backup_server::globals::sshkeys_sources ,
  68     content => @(EOF),
  69         # <name> <ip addresses> <key>
  70         | EOF
  71     order   => '00',
  72   }
  73   Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_sshkey |>>
  74   exec { 'postgres-make-backup-sshauthkeys':
  75     command     => '/usr/local/bin/postgres-make-backup-sshauthkeys',
  76     refreshonly => true,
  77   }
  78
  79   ####
  80   # Maintain /etc/nagios/dsa-check-backuppg.conf
  81   #
  82   file { '/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d':
  83     ensure  => 'directory',
  84     purge   => true,
  85     force   => true,
  86     recurse => true,
  87     notify  => Exec['update dsa-check-backuppg.conf'],
  88   }
  89   file { '/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/globals.conf':
  90     content => template('postgres/backup_server/dsa-check-backuppg-globals.conf.erb'),
  91     notify  => Exec['update dsa-check-backuppg.conf']
  92   }
  93   File<<| tag == $postgres::backup_server::globals::tag_dsa_check_backupp |>>
  94   exec { 'update dsa-check-backuppg.conf':
  95     command     => @(EOF),
  96         perl -MYAML=LoadFile,Dump -MHash::Merge::Simple=merge -E 'say Dump(merge(map{LoadFile($_)}@ARGV))' /etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/*.conf > /etc/nagios/dsa-check-backuppg.conf
  97         | EOF
  98     provider    => shell,
  99     refreshonly => true,
 100   }
 101
 102   file { '/etc/sudoers.d/backup-server':
 103     mode    => '0440',
 104     content => template('postgres/backup_server/sudoers.erb'),
 105   }
 106
 107
 108   ####
 109   # Maintain .pgpass file on backup servers
 110   # #
 111   concat { $postgres::backup_server::globals::pgpassfile:
 112     owner => 'debbackup',
 113     group => 'debbackup',
 114     mode  => '0400'
 115   }
 116   concat::fragment{ 'pgpass-local':
 117     target => $postgres::backup_server::globals::pgpassfile,
 118     source => '/home/debbackup/.pgpass-local',
 119     order  => '00'
 120   }
 121   Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_pgpassline |>>
 122 }