modules/postgres/manifests/backup_server.pp

   1 #
   2 class postgres::backup_server {
   3   include postgres::backup_server::globals
   4
   5   ensure_packages ( [
   6     'libhash-merge-simple-perl',
   7     'libyaml-perl',
   8     'python-yaml',
   9     'pigz',
  10     'postgresql-client',
  11     'postgresql-client-9.6',
  12   ], {
  13     ensure => 'installed'
  14   })
  15
  16   ####
  17   # Regularly pull base backups
  18   #
  19   concat { $postgres::backup_server::globals::base_backup_clusters:
  20     ensure_newline => true,
  21   }
  22   Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_base_backup |>>
  23
  24   file { '/usr/local/bin/postgres-make-base-backups':
  25     mode    => '0555',
  26     content => template('postgres/backup_server/postgres-make-base-backups.erb'),
  27   }
  28   file { '/var/lib/dsa/postgres-make-base-backups':
  29     ensure => directory,
  30     owner => 'debbackup',
  31     mode => '0755',
  32   }
  33   concat::fragment { 'puppet-crontab--postgres-make_base_backups':
  34     target => '/etc/cron.d/puppet-crontab',
  35     content  => @("EOF")
  36       */30 * * * * debbackup sleep $(( RANDOM \% 1200 )); chronic ${$postgres::backup_server::globals::make_base_backups}
  37       | EOF
  38   }
  39
  40   ####
  41   # Maintain authorized_keys file on backup servers for WAL shipping
  42   #
  43   # do not let other hosts directly build our authorized_keys file,
  44   # instead go via a script that somewhat validates intput
  45   file { '/etc/dsa/postgresql-backup':
  46     ensure => 'directory',
  47   }
  48   file { '/usr/local/bin/postgres-make-backup-sshauthkeys':
  49     content => template('postgres/backup_server/postgres-make-backup-sshauthkeys.erb'),
  50     mode   => '0555',
  51     notify  => Exec['postgres-make-backup-sshauthkeys'],
  52   }
  53   file { '/usr/local/bin/postgres-make-one-base-backup':
  54     source  => 'puppet:///modules/postgres/backup_server/postgres-make-one-base-backup',
  55     mode   => '0555'
  56   }
  57   file { '/etc/dsa/postgresql-backup/sshkeys-manual':
  58     content => template('postgres/backup_server/sshkeys-manual.erb'),
  59     notify  => Exec['postgres-make-backup-sshauthkeys'],
  60   }
  61   concat { $postgres::backup_server::globals::sshkeys_sources:
  62     notify  => Exec['postgres-make-backup-sshauthkeys'],
  63   }
  64   concat::fragment { 'postgresql-backup/source-sshkeys-header':
  65     target => $postgres::backup_server::globals::sshkeys_sources ,
  66     content  => @(EOF),
  67         # <name> <ip addresses> <key>
  68         | EOF
  69     order  => '00',
  70   }
  71   Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_sshkey |>>
  72   exec { "postgres-make-backup-sshauthkeys":
  73     command => "/usr/local/bin/postgres-make-backup-sshauthkeys",
  74     refreshonly => true,
  75   }
  76
  77   ####
  78   # Maintain /etc/nagios/dsa-check-backuppg.conf
  79   #
  80   file { '/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d':
  81     ensure => 'directory',
  82     purge   => true,
  83     force   => true,
  84     recurse => true,
  85     source  => 'puppet:///files/empty/',
  86     notify => Exec['update dsa-check-backuppg-manual.conf'],
  87   }
  88   file { '/etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/manual.conf':
  89     content => template('postgres/backup_server/dsa-check-backuppg-manual.conf.erb'),
  90     notify => Exec['update dsa-check-backuppg-manual.conf']
  91   }
  92   File<<| tag == $postgres::backup_server::globals::tag_dsa_check_backupp |>>
  93   exec { "update dsa-check-backuppg-manual.conf":
  94     command  => @(EOF),
  95         perl -MYAML=LoadFile,Dump -MHash::Merge::Simple=merge -E 'say Dump(merge(map{LoadFile($_)}@ARGV))' /etc/dsa/postgresql-backup/dsa-check-backuppg.conf.d/*.conf > /etc/nagios/dsa-check-backuppg.conf
  96         | EOF
  97     provider => shell,
  98     refreshonly => true,
  99   }
 100
 101   ####
 102   # Maintain .pgpass file on backup servers
 103   # #
 104   concat { $postgres::backup_server::globals::pgpassfile:
 105     owner => 'debbackup',
 106     group => 'debbackup',
 107     mode  => '0400'
 108   }
 109   concat::fragment{ 'pgpass-local':
 110     target => $postgres::backup_server::globals::pgpassfile,
 111     source => '/home/debbackup/.pgpass-local',
 112     order  => '00'
 113   }
 114   Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_pgpassline |>>
 115 }