modules/ferm/manifests/init.pp

   1 # = Class: ferm
   2 #
   3 # This class installs ferm and sets up rules
   4 #
   5 # == Sample Usage:
   6 #
   7 #   include ferm
   8 #
   9 class ferm {
  10         # realize (i.e. enable) all @ferm::rule virtual resources
  11         Ferm::Rule <| |>
  12         Ferm::Conf <| |>
  13
  14         File { mode => '0400' }
  15
  16         package { 'ferm':
  17                 ensure => installed
  18         }
  19         package { 'ulogd2':
  20                 ensure => installed
  21         }
  22         package { 'ulogd':
  23                 # Remove instead of purge ulogd because it deletes log files on purge.
  24                 ensure => absent
  25         }
  26
  27         service { 'ferm':
  28                 hasstatus   => false,
  29                 status      => '/bin/true',
  30         }
  31         exec {
  32                 "ferm reload":
  33                         command     => "service ferm reload",
  34                         refreshonly => true,
  35         }
  36
  37
  38         $munin_ips = getfromhash($site::nodeinfo, 'misc', 'v4addrs')
  39                 .map |$addr| { "ip_${addr}" }
  40
  41         munin::check { $munin_ips: script => 'ip_', }
  42
  43         $munin6_ips = getfromhash($site::nodeinfo, 'misc', 'v6addrs')
  44                 .map |$addr| { "ip_${addr}" }
  45         munin::ipv6check { $munin6_ips: }
  46
  47         file { '/etc/ferm':
  48                 ensure  => directory,
  49                 notify  => Exec['ferm reload'],
  50                 require => Package['ferm'],
  51                 mode    => '0755'
  52         }
  53         file { '/etc/ferm/dsa.d':
  54                 ensure => directory,
  55                 mode   => '0555',
  56                 purge   => true,
  57                 force   => true,
  58                 recurse => true,
  59                 source  => 'puppet:///files/empty/',
  60         }
  61         file { '/etc/ferm/conf.d':
  62                 ensure => directory,
  63                 mode   => '0555',
  64                 purge   => true,
  65                 force   => true,
  66                 recurse => true,
  67                 source  => 'puppet:///files/empty/',
  68         }
  69         file { '/etc/default/ferm':
  70                 source  => 'puppet:///modules/ferm/ferm.default',
  71                 require => Package['ferm'],
  72                 notify  => Exec['ferm reload'],
  73                 mode    => '0444',
  74         }
  75         file { '/etc/ferm/ferm.conf':
  76                 content => template('ferm/ferm.conf.erb'),
  77                 notify  => Exec['ferm reload'],
  78         }
  79         file { '/etc/ferm/conf.d/00-init.conf':
  80                 content => template('ferm/00-init.conf.erb'),
  81                 notify  => Exec['ferm reload'],
  82         }
  83         file { '/etc/ferm/conf.d/me.conf':
  84                 content => template('ferm/me.conf.erb'),
  85                 notify  => Exec['ferm reload'],
  86         }
  87         file { '/etc/ferm/conf.d/defs.conf':
  88                 content => template('ferm/defs.conf.erb'),
  89                 notify  => Exec['ferm reload'],
  90         }
  91
  92         file { '/etc/ferm/conf.d/50-munin-interfaces.conf':
  93                 content => template('ferm/conf.d-munin-interfaces.conf.erb'),
  94                 notify  => Exec['ferm reload'],
  95         }
  96         @ferm::rule { 'dsa-munin-interfaces-in':
  97                 prio        => '001',
  98                 description => 'munin accounting',
  99                 chain       => 'INPUT',
 100                 domain      => '(ip ip6)',
 101                 rule        => 'daddr ($MUNIN_IPS) NOP'
 102         }
 103         @ferm::rule { 'dsa-munin-interfaces-out':
 104                 prio        => '001',
 105                 description => 'munin accounting',
 106                 chain       => 'OUTPUT',
 107                 domain      => '(ip ip6)',
 108                 rule        => 'saddr ($MUNIN_IPS) NOP'
 109         }
 110
 111         file { '/etc/ferm/dsa.d/010-base.conf':
 112                 content => template('ferm/dsa.d-010-base.conf.erb'),
 113                 notify  => Exec['ferm reload'],
 114         }
 115
 116         augeas { 'logrotate_ulogd2':
 117                 context => '/files/etc/logrotate.d/ulogd2',
 118                 changes => [
 119                         'set rule/schedule daily',
 120                         'set rule/delaycompress delaycompress',
 121                         'set rule/rotate 10',
 122                         'set rule/ifempty notifempty',
 123                 ],
 124         }
 125         file { '/etc/logrotate.d/ulogd':
 126                 ensure  => absent,
 127         }
 128         file { '/etc/logrotate.d/ulogd.dpkg-bak':
 129                 ensure  => absent,
 130         }
 131         file { '/etc/logrotate.d/ulogd.dpkg-dist':
 132                 ensure  => absent,
 133         }
 134
 135 }