modules/exim/manifests/init.pp

   1 class exim {
   2
   3         include exim::vdomain::setup
   4
   5         munin::check { 'ps_exim4': script => 'ps_' }
   6         munin::check { 'exim_mailqueue': }
   7         munin::check { 'exim_mailstats': }
   8
   9         munin::check { 'postfix_mailqueue':  ensure => absent }
  10         munin::check { 'postfix_mailstats':  ensure => absent }
  11         munin::check { 'postfix_mailvolume': ensure => absent }
  12
  13         package { 'exim4-daemon-heavy': ensure => installed }
  14
  15         Package['exim4-daemon-heavy']->Mailalias<| |>
  16
  17         concat::fragment { 'virtual_domain_template':
  18                 target  => '/etc/exim4/virtualdomains',
  19                 content => template('exim/virtualdomains.erb'),
  20                 order   => 05,
  21         }
  22
  23         service { 'exim4':
  24                 ensure  => running,
  25                 require => [
  26                         File['/etc/exim4/exim4.conf'],
  27                         Package['exim4-daemon-heavy'],
  28                 ]
  29         }
  30
  31         file { '/etc/exim4/':
  32                 ensure  => directory,
  33                 mode    => '0755',
  34                 require => Package['exim4-daemon-heavy'],
  35                 purge   => true,
  36         }
  37         file { '/etc/exim4/Git':
  38                 ensure  => absent,
  39         }
  40         # git checkouts through puppet.  yummy.
  41         file { '/etc/exim4/email-virtualdomains':
  42                 recurse => true,
  43                 source => 'puppet:///modules/exim/email-virtualdomains',
  44                 purge  => true,
  45                 ignore => '.git',
  46         }
  47         file { '/etc/exim4/conf.d':
  48                 ensure  => directory,
  49                 purge   => true,
  50                 force   => true,
  51                 recurse => true,
  52                 source  => 'puppet:///files/empty/',
  53         }
  54         file { '/etc/exim4/ssl':
  55                 ensure  => directory,
  56                 group   => Debian-exim,
  57                 mode    => '0750',
  58                 purge   => true,
  59         }
  60         file { '/etc/exim4/exim4.conf':
  61                 content => template('exim/eximconf.erb'),
  62                 require => File['/etc/exim4/ssl/thishost.crt'],
  63                 notify  => Service['exim4'],
  64         }
  65         file { '/etc/mailname':
  66                 content => template('exim/mailname.erb'),
  67         }
  68         file { '/etc/exim4/manualroute':
  69                 content => template('exim/manualroute.erb')
  70         }
  71         file { '/etc/exim4/locals':
  72                 content => template('exim/locals.erb')
  73         }
  74         file { '/etc/exim4/submission-domains':
  75                 content => template('exim/submission-domains.erb'),
  76         }
  77         file { '/etc/exim4/host_blacklist':
  78                 source => 'puppet:///modules/exim/common/host_blacklist',
  79         }
  80         file { '/etc/exim4/blacklist':
  81                 source => 'puppet:///modules/exim/common/blacklist',
  82         }
  83         file { '/etc/exim4/callout_users':
  84                 source => 'puppet:///modules/exim/common/callout_users',
  85         }
  86         file { '/etc/exim4/grey_users':
  87                 source => 'puppet:///modules/exim/common/grey_users',
  88         }
  89         file { '/etc/exim4/helo-check':
  90                 source => 'puppet:///modules/exim/common/helo-check',
  91         }
  92         file { '/etc/exim4/localusers':
  93                 source => 'puppet:///modules/exim/common/localusers',
  94         }
  95         file { '/etc/exim4/rbllist':
  96                 source => 'puppet:///modules/exim/common/rbllist',
  97         }
  98         file { '/etc/exim4/rhsbllist':
  99                 source => 'puppet:///modules/exim/common/rhsbllist',
 100         }
 101         file { '/etc/exim4/whitelist':
 102                 source => 'puppet:///modules/exim/common/whitelist',
 103         }
 104         file { '/etc/logrotate.d/exim4-base':
 105                 source => 'puppet:///modules/exim/common/logrotate-exim4-base',
 106         }
 107         file { '/etc/logrotate.d/exim4-paniclog':
 108                 source => 'puppet:///modules/exim/common/logrotate-exim4-paniclog'
 109         }
 110         file { '/etc/exim4/ssl/thishost.crt':
 111                 source  => "puppet:///modules/exim/certs/${::fqdn}.crt",
 112                 group   => Debian-exim,
 113                 mode    => '0640',
 114         }
 115         file { '/etc/exim4/ssl/thishost.key':
 116                 source  => "puppet:///modules/exim/certs/${::fqdn}.key",
 117                 group   => Debian-exim,
 118                 mode    => '0640',
 119         }
 120         file { '/etc/exim4/ssl/ca.crt':
 121                 source  => 'puppet:///modules/exim/certs/ca.crt',
 122                 group   => Debian-exim,
 123                 mode    => '0640',
 124         }
 125         file { '/etc/exim4/ssl/ca.crl':
 126                 source  => 'puppet:///modules/exim/certs/ca.crl',
 127                 group   => Debian-exim,
 128                 mode    => '0640',
 129         }
 130         file { '/var/log/exim4':
 131                 ensure  => directory,
 132                 mode    => '2750',
 133                 owner   => Debian-exim,
 134                 group   => maillog,
 135         }
 136
 137         case getfromhash($site::nodeinfo, 'mail_port') {
 138                 /^(\d+)$/: { $mail_port = $1 }
 139                 default: { $mail_port = '25' }
 140         }
 141
 142         @ferm::rule { 'dsa-exim':
 143                 description => 'Allow SMTP',
 144                 rule        => "&SERVICE_RANGE(tcp, $mail_port, \$SMTP_SOURCES)"
 145         }
 146
 147         @ferm::rule { 'dsa-exim-v6':
 148                 description => 'Allow SMTP',
 149                 domain      => 'ip6',
 150                 rule        => "&SERVICE_RANGE(tcp, $mail_port, \$SMTP_V6_SOURCES)"
 151         }
 152         dnsextras::tlsa_record{ "tlsa-mailport":
 153                 zone => 'debian.org',
 154                 certfile => "/etc/puppet/modules/exim/files/certs/${::fqdn}.crt",
 155                 port => "$mail_port",
 156                 hostname => "$::fqdn",
 157         }
 158
 159         # Do we actually want this?  I'm only doing it because it's harmless
 160         # and makes the logs quiet.  There are better ways of making logs quiet,
 161         # though.
 162         @ferm::rule { 'dsa-ident':
 163                 domain      => '(ip ip6)',
 164                 description => 'Allow ident access',
 165                 rule        => '&SERVICE(tcp, 113)'
 166         }
 167
 168 }