modules/exim/manifests/init.pp

   1 class exim {
   2
   3         include exim::vdomain::setup
   4
   5         munin::check { 'ps_exim4': script => 'ps_' }
   6         munin::check { 'exim_mailqueue': }
   7         munin::check { 'exim_mailstats': }
   8
   9         munin::check { 'postfix_mailqueue':  ensure => absent }
  10         munin::check { 'postfix_mailstats':  ensure => absent }
  11         munin::check { 'postfix_mailvolume': ensure => absent }
  12
  13         package { 'exim4-daemon-heavy': ensure => installed }
  14
  15         Package['exim4-daemon-heavy']->Mailalias<| |>
  16
  17         concat::fragment { 'virtual_domain_template':
  18                 target  => '/etc/exim4/virtualdomains',
  19                 content => template('exim/virtualdomains.erb'),
  20                 order   => 05,
  21         }
  22
  23         service { 'exim4':
  24                 ensure  => running,
  25                 require => [
  26                         File['/etc/exim4/exim4.conf'],
  27                         Package['exim4-daemon-heavy'],
  28                 ]
  29         }
  30
  31         file { '/etc/exim4/':
  32                 ensure  => directory,
  33                 mode    => '0755',
  34                 require => Package['exim4-daemon-heavy'],
  35                 purge   => true,
  36         }
  37         file { '/etc/exim4/Git':
  38                 ensure  => absent,
  39                 force   => true,
  40         }
  41         file { '/etc/exim4/conf.d':
  42                 ensure  => directory,
  43                 purge   => true,
  44                 force   => true,
  45                 recurse => true,
  46                 source  => 'puppet:///files/empty/',
  47         }
  48         file { '/etc/exim4/ssl':
  49                 ensure  => directory,
  50                 group   => Debian-exim,
  51                 mode    => '0750',
  52                 purge   => true,
  53         }
  54         file { '/etc/exim4/exim4.conf':
  55                 content => template('exim/eximconf.erb'),
  56                 require => File['/etc/exim4/ssl/thishost.crt'],
  57                 notify  => Service['exim4'],
  58         }
  59         file { '/etc/mailname':
  60                 content => template('exim/mailname.erb'),
  61         }
  62         file { '/etc/exim4/manualroute':
  63                 content => template('exim/manualroute.erb')
  64         }
  65         file { '/etc/exim4/locals':
  66                 content => template('exim/locals.erb')
  67         }
  68         file { '/etc/exim4/submission-domains':
  69                 content => template('exim/submission-domains.erb'),
  70         }
  71         file { '/etc/exim4/host_blacklist':
  72                 source => 'puppet:///modules/exim/common/host_blacklist',
  73         }
  74         file { '/etc/exim4/blacklist':
  75                 source => 'puppet:///modules/exim/common/blacklist',
  76         }
  77         file { '/etc/exim4/callout_users':
  78                 source => 'puppet:///modules/exim/common/callout_users',
  79         }
  80         file { '/etc/exim4/grey_users':
  81                 source => 'puppet:///modules/exim/common/grey_users',
  82         }
  83         file { '/etc/exim4/helo-check':
  84                 source => 'puppet:///modules/exim/common/helo-check',
  85         }
  86         file { '/etc/exim4/localusers':
  87                 source => 'puppet:///modules/exim/common/localusers',
  88         }
  89         file { '/etc/exim4/rbllist':
  90                 source => 'puppet:///modules/exim/common/rbllist',
  91         }
  92         file { '/etc/exim4/rhsbllist':
  93                 source => 'puppet:///modules/exim/common/rhsbllist',
  94         }
  95         file { '/etc/exim4/whitelist':
  96                 source => 'puppet:///modules/exim/common/whitelist',
  97         }
  98         file { '/etc/logrotate.d/exim4-base':
  99                 source => 'puppet:///modules/exim/common/logrotate-exim4-base',
 100         }
 101         file { '/etc/logrotate.d/exim4-paniclog':
 102                 source => 'puppet:///modules/exim/common/logrotate-exim4-paniclog'
 103         }
 104         file { '/etc/exim4/ssl/thishost.crt':
 105                 source  => "puppet:///modules/exim/certs/${::fqdn}.crt",
 106                 group   => Debian-exim,
 107                 mode    => '0640',
 108         }
 109         file { '/etc/exim4/ssl/thishost.key':
 110                 source  => "puppet:///modules/exim/certs/${::fqdn}.key",
 111                 group   => Debian-exim,
 112                 mode    => '0640',
 113         }
 114         file { '/etc/exim4/ssl/ca.crt':
 115                 source  => 'puppet:///modules/exim/certs/ca.crt',
 116                 group   => Debian-exim,
 117                 mode    => '0640',
 118         }
 119         file { '/etc/exim4/ssl/ca.crl':
 120                 source  => 'puppet:///modules/exim/certs/ca.crl',
 121                 group   => Debian-exim,
 122                 mode    => '0640',
 123         }
 124         file { '/var/log/exim4':
 125                 ensure  => directory,
 126                 mode    => '2750',
 127                 owner   => Debian-exim,
 128                 group   => maillog,
 129         }
 130
 131         case getfromhash($site::nodeinfo, 'mail_port') {
 132                 /^(\d+)$/: { $mail_port = $1 }
 133                 default: { $mail_port = '25' }
 134         }
 135
 136         @ferm::rule { 'dsa-exim':
 137                 description => 'Allow SMTP',
 138                 rule        => "&SERVICE_RANGE(tcp, $mail_port, \$SMTP_SOURCES)"
 139         }
 140
 141         @ferm::rule { 'dsa-exim-v6':
 142                 description => 'Allow SMTP',
 143                 domain      => 'ip6',
 144                 rule        => "&SERVICE_RANGE(tcp, $mail_port, \$SMTP_V6_SOURCES)"
 145         }
 146         dnsextras::tlsa_record{ 'tlsa-mailport':
 147                 zone     => 'debian.org',
 148                 certfile => "/etc/puppet/modules/exim/files/certs/${::fqdn}.crt",
 149                 port     => $mail_port,
 150                 hostname => $::fqdn,
 151         }
 152
 153         # Do we actually want this?  I'm only doing it because it's harmless
 154         # and makes the logs quiet.  There are better ways of making logs quiet,
 155         # though.
 156         @ferm::rule { 'dsa-ident':
 157                 domain      => '(ip ip6)',
 158                 description => 'Allow ident access',
 159                 rule        => '&SERVICE(tcp, 113)'
 160         }
 161
 162         # These only affect the alias @$fqdn, not say, @debian.org
 163
 164         mailalias { [
 165                 'postmaster',
 166                 'hostmaster',
 167                 'usenet',
 168                 'webmaster',
 169                 'abuse',
 170                 'noc',
 171                 'security',
 172         ]:
 173                 ensure => absent
 174         }
 175 }