modules/bacula/manifests/storage.pp

   1 # the bacula storage node
   2 #
   3 # @param backup_path      directory where backups should be stored
   4 # @param filestor_device  storage device name prefix
   5 # @param filestor_name    storage device media type name prefix
   6 # @param port_sd          port for the sd to listen on
   7 # @param storage_name     bacula name of this sd instance
   8 # @param storage_address  address of this sd instance that other instances should connect to (dns name)
   9 class bacula::storage (
  10   String $backup_path     = '/srv/bacula',
  11   String $filestor_device = 'FileStorage',
  12   String $filestor_name   = 'File',
  13   Integer $port_sd        = 9103,
  14   String $storage_name    = "${::fqdn}-sd",
  15   Stdlib::Host $storage_address = $::fqdn,
  16 ) inherits bacula {
  17
  18   package { 'bacula-sd':
  19     ensure => installed
  20   }
  21
  22   service { 'bacula-sd':
  23     ensure    => running,
  24     enable    => true,
  25     hasstatus => true,
  26   }
  27   dsa_systemd::override { 'bacula-sd':
  28     content => @(EOT)
  29       [Unit]
  30       After=network-online.target
  31       [Service]
  32       Group=bacula
  33       SupplementaryGroups=ssl-cert
  34       | EOT
  35   }
  36
  37   exec { 'bacula-sd restart-when-idle':
  38     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
  39     command     => "sh -c 'setsid /usr/local/sbin/bacula-idle-restart ${port_sd} bacula-sd &'",
  40     refreshonly => true,
  41     subscribe   => File[$bacula::bacula_ssl_server_cert],
  42     require     => File['/usr/local/sbin/bacula-idle-restart'],
  43   }
  44
  45
  46   file { '/etc/bacula/bacula-sd.conf':
  47     content => template('bacula/bacula-sd.conf.erb'),
  48     mode    => '0640',
  49     group   => bacula,
  50     notify  => Exec['bacula-sd restart-when-idle']
  51   }
  52
  53   file { '/etc/bacula/storage-conf.d':
  54     ensure  => directory,
  55     mode    => '0755',
  56     group   => bacula,
  57     purge   => true,
  58     force   => true,
  59     recurse => true,
  60     notify  => Exec['bacula-sd restart-when-idle']
  61   }
  62
  63   # allow access from director and fds
  64   ferm::rule::simple { 'dsa-bacula-sd':
  65     description => 'Access to the bacula-storage',
  66     port        => $port_sd,
  67     target      => 'bacula-sd',
  68   }
  69   Ferm::Rule::Simple <<| tag == 'bacula::director-to-storage' |>>;
  70   Ferm::Rule::Simple <<| tag == "bacula::fd-to-storage::${::fqdn}" |>>;
  71
  72   file { '/etc/bacula/storage-conf.d/empty.conf':
  73     content => '',
  74     mode    => '0440',
  75     group   => bacula,
  76     notify  => Exec['bacula-sd restart-when-idle']
  77   }
  78
  79   package { 'python3-psycopg2': ensure => installed }
  80   file { '/usr/local/bin/bacula-unlink-removed-volumes':
  81     source => 'puppet:///modules/bacula/bacula-unlink-removed-volumes',
  82     mode   => '0555',
  83   }
  84   file { '/etc/cron.d/puppet-bacula-storage-stuff': ensure => absent, }
  85   concat::fragment { 'puppet-crontab--bacula-storage':
  86     target  => '/etc/cron.d/puppet-crontab',
  87     content => @(EOF)
  88       @daily bacula chronic /usr/local/bin/bacula-unlink-removed-volumes -v
  89       | EOF
  90   }
  91
  92   Bacula::Storage::Director<<| tag == 'bacula::to-storage' |>>
  93   Bacula::Storage::Client<<| tag == "bacula::to-storage::${::fqdn}" |>>
  94 }