modules/bacula/manifests/storage.pp

   1 # the bacula storage node
   2 #
   3 # @param backup_path      directory where backups should be stored
   4 # @param filestor_device  storage device name prefix
   5 # @param filestor_name    storage device media type name prefix
   6 # @param port_sd          port for the sd to listen on
   7 # @param storage_name     bacula name of this sd instance
   8 # @param storage_address  address of this sd instance that other instances should connect to (dns name)
   9 class bacula::storage (
  10   String $backup_path     = '/srv/bacula',
  11   String $filestor_device = 'FileStorage',
  12   String $filestor_name   = 'File',
  13   Integer $port_sd        = 9103,
  14   String $storage_name    = "${::fqdn}-sd",
  15   Stdlib::Host $storage_address = $::fqdn,
  16 ) inherits bacula {
  17
  18   package { 'bacula-sd':
  19     ensure => installed
  20   }
  21
  22   service { 'bacula-sd':
  23     ensure    => running,
  24     enable    => true,
  25     hasstatus => true,
  26   }
  27   dsa_systemd::override { 'bacula-sd':
  28     content => @(EOT)
  29       [Service]
  30       Group=bacula
  31       SupplementaryGroups=ssl-cert
  32       | EOT
  33   }
  34
  35   exec { 'bacula-sd restart-when-idle':
  36     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
  37     command     => "sh -c 'setsid /usr/local/sbin/bacula-idle-restart ${port_sd} bacula-sd &'",
  38     refreshonly => true,
  39     subscribe   => File[$bacula::bacula_ssl_server_cert],
  40     require     => File['/usr/local/sbin/bacula-idle-restart'],
  41   }
  42
  43
  44   file { '/etc/bacula/bacula-sd.conf':
  45     content => template('bacula/bacula-sd.conf.erb'),
  46     mode    => '0640',
  47     group   => bacula,
  48     notify  => Exec['bacula-sd restart-when-idle']
  49   }
  50
  51   file { '/etc/bacula/storage-conf.d':
  52     ensure  => directory,
  53     mode    => '0755',
  54     group   => bacula,
  55     purge   => true,
  56     force   => true,
  57     recurse => true,
  58     notify  => Exec['bacula-sd restart-when-idle']
  59   }
  60
  61   # allow access from director and fds
  62   ferm::rule::simple { 'dsa-bacula-sd':
  63     description => 'Access to the bacula-storage',
  64     port        => $port_sd,
  65     target      => 'bacula-sd',
  66   }
  67   Ferm::Rule::Simple <<| tag == 'bacula::director-to-storage' |>>;
  68   Ferm::Rule::Simple <<| tag == "bacula::fd-to-storage::${::fqdn}" |>>;
  69
  70   file { '/etc/bacula/storage-conf.d/empty.conf':
  71     content => '',
  72     mode    => '0440',
  73     group   => bacula,
  74     notify  => Exec['bacula-sd restart-when-idle']
  75   }
  76
  77   package { 'python3-psycopg2': ensure => installed }
  78   file { '/usr/local/bin/bacula-unlink-removed-volumes':
  79     source => 'puppet:///modules/bacula/bacula-unlink-removed-volumes',
  80     mode   => '0555',
  81   }
  82   file { '/etc/cron.d/puppet-bacula-storage-stuff': ensure => absent, }
  83   concat::fragment { 'puppet-crontab--bacula-storage':
  84     target  => '/etc/cron.d/puppet-crontab',
  85     content => @(EOF)
  86       @daily bacula chronic /usr/local/bin/bacula-unlink-removed-volumes -v
  87       | EOF
  88   }
  89
  90   Bacula::Storage::Director<<| tag == 'bacula::to-storage' |>>
  91   Bacula::Storage::Client<<| tag == "bacula::to-storage::${::fqdn}" |>>
  92 }