modules/bacula/manifests/director.pp

   1 # our bacula director
   2 #
   3 # @param bacula_db_address hostname of the postgres server for the catalog DB
   4 # @param bacula_db_port    port of the postgres server for the catalog DB
   5 class bacula::director(
   6   String  $bacula_db_address = 'postgresql-manda-01.debian.org',
   7   Integer $bacula_db_port    = 5432,
   8 ) inherits bacula {
   9
  10   ensure_packages ( [
  11     'bacula-director-pgsql',
  12     'bacula-common',
  13     'bacula-common-pgsql'
  14   ], {
  15     ensure => 'installed',
  16   })
  17
  18   service { 'bacula-director':
  19     ensure    => running,
  20     enable    => true,
  21     hasstatus => true,
  22     require   => Package['bacula-director-pgsql']
  23   }
  24   dsa_systemd::override { 'bacula-director':
  25     content => @(EOT)
  26       [Unit]
  27       After=unbound.service
  28       | EOT
  29   }
  30
  31   exec { 'bacula-director reload':
  32     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
  33     command     => 'service bacula-director reload',
  34     refreshonly => true,
  35   }
  36
  37   file { '/etc/bacula/conf.d':
  38     ensure  => directory,
  39     mode    => '0755',
  40     group   => bacula,
  41     purge   => true,
  42     force   => true,
  43     recurse => true,
  44     source  => 'puppet:///files/empty/',
  45     notify  => Exec['bacula-director reload']
  46   }
  47
  48   file { '/etc/bacula/bacula-dir.conf':
  49     content => template('bacula/bacula-dir.conf.erb'),
  50     mode    => '0440',
  51     group   => bacula,
  52     require => Package['bacula-director-pgsql'],
  53     notify  => Exec['bacula-director reload']
  54   }
  55
  56   file { '/etc/bacula/conf.d/empty.conf':
  57     content => '',
  58     mode    => '0440',
  59     group   => bacula,
  60     require => Package['bacula-director-pgsql'],
  61     notify  => Exec['bacula-director reload']
  62   }
  63
  64   Bacula::Node<<| |>>
  65
  66   package { 'bacula-console':
  67     ensure => installed;
  68   }
  69
  70   file { '/etc/bacula/bconsole.conf':
  71     content => template('bacula/bconsole.conf.erb'),
  72     mode    => '0640',
  73     group   => bacula,
  74     require => Package['bacula-console']
  75   }
  76
  77   package { 'python3-psycopg2': ensure => installed }
  78   file { '/etc/bacula/scripts/volume-purge-action':
  79     mode   => '0555',
  80     source => 'puppet:///modules/bacula/volume-purge-action',
  81     ;
  82   }
  83   file { '/etc/bacula/scripts/volumes-delete-old':
  84     mode   => '0555',
  85     source => 'puppet:///modules/bacula/volumes-delete-old',
  86     ;
  87   }
  88   file { '/etc/bacula/storages-list.d':
  89     ensure  => directory,
  90     mode    => '0755',
  91     group   => bacula,
  92     purge   => true,
  93     force   => true,
  94     recurse => true,
  95     source  => 'puppet:///files/empty/',
  96   }
  97   file { '/usr/local/sbin/dsa-bacula-scheduler':
  98     source => 'puppet:///modules/bacula/dsa-bacula-scheduler',
  99     mode   => '0555',
 100   }
 101
 102   file { '/etc/cron.d/puppet-bacula-stuff': ensure => absent, }
 103   concat::fragment { 'puppet-crontab--bacula-director':
 104     target  => '/etc/cron.d/puppet-crontab',
 105     content => @(EOF)
 106       @daily root chronic /etc/bacula/scripts/volume-purge-action -v
 107       @daily root chronic /etc/bacula/scripts/volumes-delete-old -v
 108       */3 * * * * root sleep $(( $RANDOM \% 60 )); flock -w 0 -e /usr/local/sbin/dsa-bacula-scheduler /usr/local/sbin/dsa-bacula-scheduler
 109       | EOF
 110   }
 111
 112   concat { $bacula::bacula_dsa_client_list:
 113   }
 114   concat::fragment { 'bacula-dsa-client-list::header' :
 115     target  => $bacula::bacula_dsa_client_list,
 116     content => '',
 117     order   => '00',
 118   }
 119   Concat::Fragment <<| tag == $bacula::tag_bacula_dsa_client_list |>>
 120
 121   @@ferm::rule::simple { "bacula::director-to-fd::${::fqdn}":
 122     tag         => "bacula::director-to-fd::${::fqdn}",
 123     description => 'Allow bacula-fd from the bacula-director',
 124     port        => '7', # overridden on collecting
 125     saddr       => $bacula::public_addresses,
 126   }
 127   @@ferm::rule::simple { "bacula::director-to-storage::${::fqdn}":
 128     tag         => "bacula::director-to-storage::${::fqdn}",
 129     description => 'Allow bacula-storage access from the bacula-director',
 130     chain       => 'bacula-sd',
 131     saddr       => $bacula::public_addresses,
 132   }
 133 }