3rdparty/modules/postgresql/manifests/repo/apt_postgresql_org.pp

   1 # PRIVATE CLASS: do not use directly
   2 class postgresql::repo::apt_postgresql_org inherits postgresql::repo {
   3   include ::apt
   4
   5   # Here we have tried to replicate the instructions on the PostgreSQL site:
   6   #
   7   # http://www.postgresql.org/download/linux/debian/
   8   #
   9   $default_baseurl = 'https://apt.postgresql.org/pub/repos/apt/'
  10
  11   $_baseurl = pick($postgresql::repo::baseurl, $default_baseurl)
  12
  13   apt::pin { 'apt_postgresql_org':
  14     originator => 'apt.postgresql.org',
  15     priority   => 500,
  16   }
  17   -> apt::source { 'apt.postgresql.org':
  18     location => $_baseurl,
  19     release  => "${::lsbdistcodename}-pgdg",
  20     repos    => "main ${postgresql::repo::version}",
  21     key      => {
  22       id     => 'B97B0AFCAA1A47F044F244A07FCC7D46ACCC4CF8',
  23       source => 'https://www.postgresql.org/media/keys/ACCC4CF8.asc',
  24     },
  25     include  => {
  26       src => false,
  27     },
  28   }
  29
  30   Apt::Source['apt.postgresql.org']->Package<|tag == 'postgresql'|>
  31   Class['Apt::Update'] -> Package<|tag == 'postgresql'|>
  32 }