3rdparty/modules/cinder/manifests/backend/iscsi.pp

   1 #
   2 # Define: cinder::backend::iscsi
   3 # Parameters:
   4 #
   5 # [*volume_backend_name*]
   6 #   (optional) Allows for the volume_backend_name to be separate of $name.
   7 #   Defaults to: $name
   8 #
   9 #
  10 define cinder::backend::iscsi (
  11   $iscsi_ip_address,
  12   $volume_backend_name = $name,
  13   $volume_driver       = 'cinder.volume.drivers.lvm.LVMISCSIDriver',
  14   $volume_group        = 'cinder-volumes',
  15   $iscsi_helper        = $::cinder::params::iscsi_helper,
  16 ) {
  17
  18   include cinder::params
  19
  20   cinder_config {
  21     "${name}/volume_backend_name":  value => $volume_backend_name;
  22     "${name}/volume_driver":        value => $volume_driver;
  23     "${name}/iscsi_ip_address":     value => $iscsi_ip_address;
  24     "${name}/iscsi_helper":         value => $iscsi_helper;
  25     "${name}/volume_group":         value => $volume_group;
  26   }
  27
  28   case $iscsi_helper {
  29     'tgtadm': {
  30       package { 'tgt':
  31         ensure => present,
  32         name   => $::cinder::params::tgt_package_name,
  33       }
  34
  35       if($::osfamily == 'RedHat') {
  36         file_line { 'cinder include':
  37           path    => '/etc/tgt/targets.conf',
  38           line    => 'include /etc/cinder/volumes/*',
  39           match   => '#?include /',
  40           require => Package['tgt'],
  41           notify  => Service['tgtd'],
  42         }
  43       }
  44
  45       service { 'tgtd':
  46         ensure  => running,
  47         name    => $::cinder::params::tgt_service_name,
  48         enable  => true,
  49         require => Class['cinder::volume'],
  50       }
  51     }
  52
  53     'lioadm': {
  54       service { 'target':
  55         ensure  => running,
  56         enable  => true,
  57         require => Package['targetcli'],
  58       }
  59
  60       package { 'targetcli':
  61         ensure => present,
  62         name   => $::cinder::params::lio_package_name,
  63       }
  64     }
  65
  66     default: {
  67       fail("Unsupported iscsi helper: ${iscsi_helper}.")
  68     }
  69   }
  70
  71 }