dsa-nagios-checks/dsa-check-dabackup

   1 #!/usr/bin/perl -w
   2
   3 # Check the status of da-backup backups
   4 # Copyright 2007 Stephen Gran <sgran@debian.org>
   5 # Copyright 2008 Peter Palfrader
   6 #
   7 # Permission is hereby granted, free of charge, to any person obtaining
   8 # a copy of this software and associated documentation files (the
   9 # "Software"), to deal in the Software without restriction, including
  10 # without limitation the rights to use, copy, modify, merge, publish,
  11 # distribute, sublicense, and/or sell copies of the Software, and to
  12 # permit persons to whom the Software is furnished to do so, subject to
  13 # the following conditions:
  14 #
  15 # The above copyright notice and this permission notice shall be
  16 # included in all copies or substantial portions of the Software.
  17 #
  18 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  19 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  20 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  21 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
  22 # LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
  23 # OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
  24 # WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  25
  26 use strict;
  27 use warnings;
  28 use English;
  29 use Getopt::Long;
  30 use Fcntl qw(:seek);
  31
  32 my $DABACKUP_CONF = '/etc/da-backup.conf';
  33 my $MAX_AGE = 30*60*60;
  34 my $TOO_FRESH = 5*60;
  35 my %CODE = (
  36         'UNDEF'         => -1,
  37         'OK'            => 0,
  38         'WARNING'       => 1,
  39         'CRITICAL'      => 2,
  40         'UNKNOWN'       => 3
  41 );
  42 $SIG{__DIE__ } = sub() {
  43         print shift;
  44         exit $CODE{'UNKNOWN'};
  45 };
  46
  47
  48 my $EXITCODE = 'UNDEF';
  49 my %MESSAGE = ();
  50
  51 sub problem($$$) {
  52         my ($code, $msg, $resource) = @_;
  53         $MESSAGE{$msg} = [] unless defined $MESSAGE{$msg};
  54         push @{$MESSAGE{$msg}}, $resource;
  55         $EXITCODE = ($CODE{$code} > $CODE{$EXITCODE}) ? $code : $EXITCODE;
  56 };
  57
  58
  59 sub help($$) {
  60         my ($exitcode, $fd) = @_;
  61         version ($fd, 0);
  62         print $fd "Usage: $PROGRAM_NAME --help\n";
  63         print $fd "Usage: $PROGRAM_NAME";
  64         exit $exitcode
  65 };
  66
  67 my $params = {};
  68
  69 Getopt::Long::config('bundling');
  70 if (!GetOptions (
  71         'h|help'        =>  \$params->{'help'},
  72         )) {
  73         die ("$PROGRAM_NAME: Usage: $PROGRAM_NAME [-fwhv]\n");
  74 };
  75
  76 help(0, *STDOUT) if $params->{'help'};
  77 help(1, *STDERR) if scalar @ARGV > 0;
  78
  79
  80 unless (-e $DABACKUP_CONF) {
  81         if (-e '/etc/da-backup') {
  82                 print "WARNING: No $DABACKUP_CONF, but we have /etc/da-backup/\n";
  83                 exit $CODE{'WARNING'};
  84         };
  85         if (-e '/var/log/da-backup') {
  86                 print "WARNING: No $DABACKUP_CONF, but we have /var/log/da-backup/\n";
  87                 exit $CODE{'WARNING'};
  88         };
  89         print "OK: da-backup not installed\n";
  90         exit $CODE{'OK'};
  91 };
  92
  93 my $confdir;
  94 my $logdir;
  95
  96 open (FH, "< $DABACKUP_CONF") or die ("Cannot open $DABACKUP_CONF: $!\n");
  97 while (<FH>) {
  98         if (/confdir=(.*)/) {
  99                 $confdir = $1;
 100         } elsif (/logdir=(.*)/) {
 101                 $logdir = $1;
 102         };
 103 };
 104
 105 die ("No confdir found in $DABACKUP_CONF") unless defined $confdir;
 106 die ("No logdir found in $DABACKUP_CONF") unless defined $logdir;
 107
 108 opendir(DIR, $confdir) or die ("Cannot opendir $confdir: $!\n");
 109 my %conffiles = map {$_ => 1} grep { !/^\./ && !/\.bak$/} readdir(DIR);
 110 closedir(DIR);
 111
 112 opendir(DIR, $logdir) or die ("Cannot opendir $logdir: $!\n");
 113 my %logfiles = map {$_ => 1} grep { !/^\./ && !/\.[0-9]+(\.gz)?$/} readdir(DIR);
 114 closedir(DIR);
 115
 116 if (scalar keys %conffiles == 0) {
 117         print "WARNING: da-backup installed but no backups configured\n";
 118         exit $CODE{'WARNING'};
 119 };
 120
 121 for my $f (keys %conffiles) {
 122         unless (exists $logfiles{$f}) {
 123                 problem('WARNING', 'no log', $f);
 124         }
 125 }
 126
 127 FILE:
 128 for my $f (sort {$a cmp $b} keys %logfiles) {
 129         unless (exists $conffiles{$f}) {
 130                 problem('WARNING', 'no config', $f);
 131                 next;
 132         }
 133
 134         my @stat = stat("$logdir/$f") or die ("Cannot stat $logdir/$f: $!\n");
 135         my $age = time - $stat[10];
 136
 137         if ($age < $TOO_FRESH) { # File is too new, let's use the old one
 138                 if (-e "$logdir/$f.0") {
 139                         $f .= ".0";
 140                         my @stat = stat("$logdir/$f") or die ("Cannot stat $logdir/$f: $!\n");
 141                         $age = time - $stat[10];
 142                 };
 143         };
 144
 145         if ($age < 0) {
 146                 problem('WARNING', 'future timestamp', $f);
 147                 next;
 148         } elsif ($age > $MAX_AGE) {
 149                 my $hage;
 150
 151                 if ($age > 48 * 3600) {
 152                         $hage = sprintf("%d days", $age / 24 / 3600);
 153                 } else {
 154                         $hage = sprintf("%d hours", $age /  3600);
 155                 };
 156                 problem('WARNING', 'old', "$f ($hage)");
 157                 next;
 158         };
 159
 160         open(FH, "< $logdir/$f") or die ("Cannot open $logdir/$f: $!\n");
 161         sysseek(FH, -1024, SEEK_END); # just try it - doesn't matter if it fails
 162         my $last2 = '';
 163         my $last = '';
 164         while (<FH>) {
 165                 chomp;
 166                 if (/^sent\s+\d+\s+bytes\s+received\s+\d+\s+bytes\s+[\d\.]+\s+bytes\/sec$/) {
 167                         problem('OK', 'probably ok', $f);
 168                         close(FH);
 169                         next FILE;
 170                 };
 171                 $last2 = $last;
 172                 $last = $_;
 173         };
 174         problem('CRITICAL', 'FAILED', "$f ($last2 $last)");
 175 };
 176
 177 my $msg = join("; ", map {"$_: ".join(', ', @{$MESSAGE{$_}}) } (sort {$a cmp $b} keys %MESSAGE));
 178 print $EXITCODE, ": ", $msg, "\n";
 179 exit $CODE{$EXITCODE};