dsa-nagios-checks/checks/dsa-check-hpssacli

   1 #!/usr/bin/perl -w
   2
   3 # check _physical_ disk status of disks on HP smart array controllers
   4 # requires hpssacli
   5 #
   6 # does _not_ check raid status.  use arrayprobe for that.
   7
   8 # Copyright (c) 2008,2009,2010,2011 Peter Palfrader <peter@palfrader.org>
   9 #
  10 # Permission is hereby granted, free of charge, to any person obtaining
  11 # a copy of this software and associated documentation files (the
  12 # "Software"), to deal in the Software without restriction, including
  13 # without limitation the rights to use, copy, modify, merge, publish,
  14 # distribute, sublicense, and/or sell copies of the Software, and to
  15 # permit persons to whom the Software is furnished to do so, subject to
  16 # the following conditions:
  17 #
  18 # The above copyright notice and this permission notice shall be
  19 # included in all copies or substantial portions of the Software.
  20 #
  21 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  22 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  23 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  24 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
  25 # LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
  26 # OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
  27 # WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  28
  29 use strict;
  30 use English;
  31 use Getopt::Long;
  32
  33 # nagios exit codes
  34 my %CODE = (
  35         'OK'            => 0,
  36         'WARNING'       => 1,
  37         'CRITICAL'      => 2,
  38         'UNKNOWN'       => 3
  39 );
  40
  41 my $EXITCODE = 'OK';
  42
  43 $SIG{'__DIE__'} = sub {
  44         print @_;
  45         exit $CODE{'UNKNOWN'};
  46 };
  47
  48 sub runcmd($) {
  49         my ($cmd) = @_;
  50         $cmd = "sudo hpssacli $cmd";
  51         open(FH, $cmd."|") or die ("Cannot run $cmd: $!");
  52         my @lines = <FH>;
  53         close FH;
  54         die ("no results from $cmd\n") if (scalar @lines == 0);
  55         return \@lines;
  56 }
  57
  58 sub record($) {
  59         my ($newexit) = @_;
  60         die "code $newexit not defined\n" unless defined $CODE{$newexit};
  61
  62         if ($CODE{$newexit} > $CODE{$EXITCODE}) {
  63                 $EXITCODE = $newexit;
  64         };
  65 }
  66
  67 my $usage = "$PROGRAM_NAME: Usage: $PROGRAM_NAME [--no-battery] [--ignore-controller=<regex>] [--no-controller-ok] [--ignore-transfer-speed=<pd> [--ignore-transfer-speed=<pd> ...]]\n";
  68 my $params;
  69 Getopt::Long::Configure('bundling');
  70 if (!GetOptions (
  71         '--help'                      => \$params->{'help'},
  72         '--no-battery'                => \$params->{'no-battery'},
  73         '--no-controller-ok'          => \$params->{'no-controller-ok'},
  74         '--ignore-controller=s'       => \$params->{'ignore-controller'},
  75         '--ignore-transfer-speed=s@'  => \$params->{'ignore-transfer-speed'},
  76         )) {
  77         die ($usage);
  78 };
  79 if ($params->{'help'}) {
  80         print $usage;
  81         exit (0);
  82 };
  83 die ($usage) unless (scalar @ARGV == 0);
  84
  85 my $ctrlallshow = runcmd("controller all show");
  86 my @controllers;
  87 for (@$ctrlallshow) {
  88         chomp;
  89         next if /^$/;
  90         next if ($params->{'ignore-controller'} && /$params->{'ignore-controller'}/);
  91         if (/in Slot ([0-9a-z]+)/) {
  92                 push @controllers, $1;
  93                 next;
  94         };
  95         die ("Cannot read line '$_' gotten from hpssacli controller all show\n");
  96 };
  97
  98 if (scalar @controllers == 0) {
  99         if ($params->{'no-controller-ok'}) {
 100                 print "No smartarray controllers found with hpssacli\n";
 101                 exit $CODE{'OK'}
 102         } else {
 103                 print "UNKNOWN: No smartarray controllers found with hpssacli\n";
 104                 exit $CODE{'UNKNOWN'}
 105         }
 106 };
 107
 108 my @resultstr;
 109
 110 for my $slot (sort @controllers) {
 111         my @drives;
 112         my $nodrives = 0;
 113         my %status;
 114
 115         my $ldallshow = runcmd("controller slot=$slot ld all show");
 116         my @logicaldrives;
 117         for (@$ldallshow) {
 118                 chomp;
 119                 next if /^$/;
 120                 next if (/^\S.*in Slot $slot/);
 121                 next if /^ *array [A-Z]$/;
 122                 if (/logicaldrive ([0-9a-z]+)/) {
 123                         push @logicaldrives, $1;
 124                         next;
 125                 } elsif (/^Error: The specified device does not have any logical drives.$/) {
 126                         $nodrives = 1;
 127                 } else {
 128                         die ("Cannot read line '$_' gotten from hpssacli controller slot = $slot logicaldrive all show\n");
 129                 }
 130         };
 131
 132         # check logicaldrives
 133         for my $logicaldrive (sort @logicaldrives) {
 134                 my $lds = runcmd("controller slot=$slot ld $logicaldrive show");
 135                 for (@$lds) {
 136                         chomp;
 137                         next if /^$/;
 138                         if (/^ *Parity Initialization Status: (Initialization Completed|Initialization Failed|Rebuilding)$/) {
 139                                 my $status = $1;
 140                                 if ($status eq 'Initialization Completed') {
 141                                         push @{$status{'OK'}}, "Parity LD$logicaldrive";
 142                                 } elsif ($status eq 'Rebuilding') {
 143                                         push @{$status{'Failed'}}, "Parity LD$logicaldrive";
 144                                         record('WARNING');
 145                                 } elsif ($status eq 'Initialization Failed') {
 146                                         push @{$status{'Failed'}}, "Parity LD$logicaldrive";
 147                                         record('CRITICAL');
 148                                 } else {
 149                                         record('UNKNOWN');
 150                                 }
 151                         }
 152                 }
 153         }
 154
 155         if (!$nodrives && scalar @logicaldrives == 0) {
 156                 push @resultstr, "Slot $slot: unexpectedly, found no logical drives in list.";
 157                 record('UNKNOWN');
 158         } elsif ($nodrives && scalar keys %status > 0) {
 159                 push @resultstr, "Slot $slot: have no logical drives but status results?";
 160                 record('UNKNOWN');
 161                 next;
 162         } elsif ($nodrives) {
 163                 push @resultstr, "Slot $slot: no logical drives";
 164         };
 165
 166
 167         my $pds = runcmd("controller slot=$slot pd all show");
 168         for (@$pds) {
 169                 chomp;
 170                 next if /^$/;
 171                 next if (/^\S.*in Slot $slot/);
 172                 next if /^ *array [A-Z]$/;
 173                 next if /^ *unassigned/;
 174                 if (/^ *(array [A-Z]) \(Failed\)$/) {
 175                         record('CRITICAL');
 176                         push @{$status{'Failed'}}, $1;
 177                 } elsif (/^Error: The specified controller does not have any physical drives on it.$/) {
 178                         $nodrives = 1;
 179                 } elsif (/^ *physicaldrive (\S+) .* (OK|Predictive Failure|Failed|Rebuilding)(?:, (?:active )?spare)?\)$/) {
 180                         my $drive = $1;
 181                         my $status = $2;
 182                         push @{$status{$status}}, $drive;
 183                         if ($status eq 'OK') {
 184                         } elsif ($status eq 'Predictive Failure' ||
 185                                  $status eq 'Rebuilding') {
 186                                 record('WARNING');
 187                         } elsif ($status eq 'Failed') {
 188                                 record('CRITICAL');
 189                         } else {
 190                                 record('UNKNOWN');
 191                         };
 192                         push @drives, $drive;
 193                 } else {
 194                         die ("Cannot read line '$_' gotten from hpssacli controller slot=$slot pd all show\n");
 195                 };
 196         };
 197
 198         # Check that all drives have the proper transfer speed.
 199         # sometimes stuff breaks and they fall back to 10mb/sec.
 200         for my $drive (@drives) {
 201                 # skip drives that are known to have failed
 202                 next if (exists $status{'Failed'} && grep {$drive eq $_} @{$status{'Failed'}});
 203                 my $type;
 204                 if ($drive =~ /^[0-9]+:[0-9]+$/) { # scsi drives
 205                         $type = 'SCSI';
 206                 } elsif ($drive =~ /^[0-9]+[EI]:[0-9]+:[0-9]+$/) { # SAS
 207                         $type = 'SAS';
 208                 } elsif ($drive =~ /^[0-9]+[C]:[0-9]+:[0-9]+$/) { # New 6GBPS SAS
 209                         $type = 'SAS+';
 210                 } else {
 211                         # I'm not going to run pass arguments of unknown form to the shell..
 212                         warn ("Unknown diskdrive ID $drive\n");
 213                         next;
 214                 }
 215
 216                 my $pd = runcmd("controller slot=$slot pd $drive show");
 217                 while (defined $pd->[0] && !($pd->[0] =~ /physicaldrive/)) {
 218                         shift @$pd;
 219                 };
 220                 shift @$pd;
 221                 my %value;
 222                 for (@$pd) {
 223                         if (m/^\s*(.*?):\s*(.*?)\s*$/) {
 224                                 $value{$1} = $2;
 225                         }
 226                 }
 227
 228                 my $key;
 229                 my $expected;
 230                 if ($type eq 'SCSI') {
 231                         $key = 'Transfer Speed';
 232                         if (!defined $value{'Transfer Mode'}) {
 233                                 record('WARNING');
 234                                 push @{$status{'unknown transfer mode'}}, $drive;
 235                                 next;
 236                         } elsif ($value{'Transfer Mode'} eq 'Ultra 3 Wide') {
 237                                 $expected = '160 MB/Sec';
 238                         } elsif ($value{'Transfer Mode'} eq 'Ultra 320 Wide') {
 239                                 $expected = '320 MB/Sec';
 240                         } else {
 241                                 record('WARNING');
 242                                 push @{$status{'unknown transfer mode'}}, $drive."(".$value{'Transfer Mode'}.")";
 243                                 next;
 244                         };
 245                 } elsif ($type eq 'SAS' || $type eq 'SAS+') {
 246                         $key = 'PHY Transfer Rate';
 247                         if ($value{'Interface Type'} eq 'SATA') {
 248                                 $expected = [ '1.5Gbps', '3.0Gbps', '6.0Gbps' ];
 249                         } elsif ($value{'PHY Count'} eq '2') {
 250                                 if (defined($value{'Redundant Path(s)'})) {
 251                                         $expected = [ '3.0GBPS, 3.0GBPS', '6.0GBPS, 6.0GBPS',
 252                                                       '12.0GBPS, 12.0GBPS' ];
 253                                 } else {
 254                                         $expected = [ '3.0GBPS, Unknown', 'Unknown, 3.0GBPS',
 255                                                       '6.0GBPS, Unknown', 'Unknown, 6.0GBPS',
 256                                                       '12.0GBPS, Unknown', 'Unknown, 12.0GBPS' ];
 257                                 }
 258                         } else {
 259                                 $expected = [ '3.0GBPS', '6.0GBPS', '12.0GBPS' ];
 260                         }
 261                 } else {
 262                         warn "Should not be here.  Do not know what to do with type '$type'\n";
 263                         next;
 264                 }
 265
 266                 if ($params->{'ignore-transfer-speed'}) {
 267                         if (grep { $drive eq $_ } @{$params->{'ignore-transfer-speed'}}) {
 268                                 push @{$status{'ignored transfer speed'}}, $drive."(".$value{$key}.")";
 269                                 next;
 270                         };
 271                 };
 272                 if (!defined $value{$key}) {
 273                         record('WARNING');
 274                         push @{$status{'unknown transfer speed'}}, $drive;
 275                 } elsif (ref($expected) eq 'ARRAY') {
 276                         if (scalar(grep { uc($value{$key}) eq uc($_) } @$expected) == 0) {
 277                                 record('WARNING');
 278                                 push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
 279                         };
 280                 } elsif (uc($value{$key}) ne uc($expected)) {
 281                         record('WARNING');
 282                         push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
 283                 };
 284         };
 285
 286         if ($nodrives && scalar keys %status > 0) {
 287                 push @resultstr, "Slot $slot: have no drives but status results?";
 288                 record('UNKNOWN');
 289                 next;
 290         } elsif ($nodrives) {
 291                 push @resultstr, "Slot $slot: no drives";
 292                 next;
 293         };
 294
 295         my $cst = runcmd("controller slot=$slot show status");
 296         for (@$cst) {
 297                 chomp;
 298                 next if /^$/;
 299                 next if (/^\S.*in Slot $slot/);
 300                 if (/^ *(.*) Status: (.*)$/) {
 301                         my $system = $1;
 302                         my $status = $2;
 303                         push @{$status{$status}}, $system;
 304                         if ($status ne 'OK') {
 305                                 next if ($params->{'no-battery'} && $system eq 'Cache');
 306                                 next if ($params->{'no-battery'} && $system eq 'Battery/Capacitor');
 307                                 record('WARNING');
 308                         };
 309                 } else {
 310                         die ("Cannot read line '$_' gotten from hpssacli controller slot=$slot show status\n");
 311                 };
 312         };
 313
 314         my $status = join(" - ", (map { $_.": ".join(", ", @{$status{$_}}) } keys %status));
 315         push @resultstr, "Slot $slot: $status";
 316 };
 317
 318 print "$EXITCODE: ", join(" --- ", @resultstr), "\n";
 319 exit $CODE{$EXITCODE};