8ae712101b79afac7034cdd70d80a9083d82fa25
[mirror/dsa-nagios.git] / dsa-nagios-checks / checks / dsa-check-hpssacli
1 #!/usr/bin/perl -w
2
3 # check _physical_ disk status of disks on HP smart array controllers
4 # requires hpssacli
5 #
6 # does _not_ check raid status.  use arrayprobe for that.
7
8 # Copyright (c) 2008,2009,2010,2011 Peter Palfrader <peter@palfrader.org>
9 #
10 # Permission is hereby granted, free of charge, to any person obtaining
11 # a copy of this software and associated documentation files (the
12 # "Software"), to deal in the Software without restriction, including
13 # without limitation the rights to use, copy, modify, merge, publish,
14 # distribute, sublicense, and/or sell copies of the Software, and to
15 # permit persons to whom the Software is furnished to do so, subject to
16 # the following conditions:
17 #
18 # The above copyright notice and this permission notice shall be
19 # included in all copies or substantial portions of the Software.
20 #
21 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
22 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
23 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
24 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
25 # LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
26 # OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
27 # WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
28
29 use strict;
30 use English;
31 use Getopt::Long;
32
33 # nagios exit codes
34 my %CODE = (
35         'OK'            => 0,
36         'WARNING'       => 1,
37         'CRITICAL'      => 2,
38         'UNKNOWN'       => 3
39 );
40
41 my $EXITCODE = 'OK';
42
43 $SIG{'__DIE__'} = sub {
44         print @_;
45         exit $CODE{'UNKNOWN'};
46 };
47
48 sub runcmd($) {
49         my ($cmd) = @_;
50         $cmd = "sudo hpssacli $cmd";
51         open(FH, $cmd."|") or die ("Cannot run $cmd: $!");
52         my @lines = <FH>;
53         close FH;
54         die ("no results from $cmd\n") if (scalar @lines == 0);
55         return \@lines;
56 }
57
58 sub record($) {
59         my ($newexit) = @_;
60         die "code $newexit not defined\n" unless defined $CODE{$newexit};
61
62         if ($CODE{$newexit} > $CODE{$EXITCODE}) {
63                 $EXITCODE = $newexit;
64         };
65 }
66
67 my $usage = "$PROGRAM_NAME: Usage: $PROGRAM_NAME [--no-battery] [--ignore-controller=<regex>] [--no-controller-ok] [--ignore-transfer-speed=<pd> [--ignore-transfer-speed=<pd> ...]]\n";
68 my $params;
69 Getopt::Long::Configure('bundling');
70 if (!GetOptions (
71         '--help'                      => \$params->{'help'},
72         '--no-battery'                => \$params->{'no-battery'},
73         '--no-controller-ok'          => \$params->{'no-controller-ok'},
74         '--ignore-controller=s'       => \$params->{'ignore-controller'},
75         '--ignore-transfer-speed=s@'  => \$params->{'ignore-transfer-speed'},
76         )) {
77         die ($usage);
78 };
79 if ($params->{'help'}) {
80         print $usage;
81         exit (0);
82 };
83 die ($usage) unless (scalar @ARGV == 0);
84
85 my $ctrlallshow = runcmd("controller all show");
86 my @controllers;
87 for (@$ctrlallshow) {
88         chomp;
89         next if /^$/;
90         next if ($params->{'ignore-controller'} && /$params->{'ignore-controller'}/);
91         if (/in Slot ([0-9a-z]+)/) {
92                 push @controllers, $1;
93                 next;
94         };
95         die ("Cannot read line '$_' gotten from hpssacli controller all show\n");
96 };
97
98 if (scalar @controllers == 0) {
99         if ($params->{'no-controller-ok'}) {
100                 print "No smartarray controllers found with hpssacli\n";
101                 exit $CODE{'OK'}
102         } else {
103                 print "UNKNOWN: No smartarray controllers found with hpssacli\n";
104                 exit $CODE{'UNKNOWN'}
105         }
106 };
107
108 my @resultstr;
109
110 for my $slot (sort @controllers) {
111         my @drives;
112         my $nodrives = 0;
113         my %status;
114         my @freetext;
115
116         my $ldallshow = runcmd("controller slot=$slot ld all show");
117         my @logicaldrives;
118         for (@$ldallshow) {
119                 chomp;
120                 next if /^$/;
121                 next if (/^\S.*in Slot $slot/);
122                 next if /^ *array [A-Z]$/;
123                 if (/logicaldrive ([0-9a-z]+)/) {
124                         push @logicaldrives, $1;
125                         next;
126                 } elsif (/^Error: The specified device does not have any logical drives.$/) {
127                         $nodrives = 1;
128                 } else {
129                         die ("Cannot read line '$_' gotten from hpssacli controller slot = $slot logicaldrive all show\n");
130                 }
131         };
132
133         # check logicaldrives
134         for my $logicaldrive (sort @logicaldrives) {
135                 my $lds = runcmd("controller slot=$slot ld $logicaldrive show");
136                 for (@$lds) {
137                         chomp;
138                         next if /^$/;
139                         if (/^ *Parity Initialization Status: (Initialization Completed|Initialization Failed|Rebuilding)$/) {
140                                 my $status = $1;
141                                 if ($status eq 'Initialization Completed') {
142                                         push @{$status{'OK'}}, "Parity LD$logicaldrive";
143                                 } elsif ($status eq 'Rebuilding') {
144                                         push @{$status{'Failed'}}, "Parity LD$logicaldrive";
145                                         record('WARNING');
146                                 } elsif ($status eq 'Initialization Failed') {
147                                         push @{$status{'Failed'}}, "Parity LD$logicaldrive";
148                                         record('CRITICAL');
149                                 } else {
150                                         record('UNKNOWN');
151                                 }
152                         }
153                         if (/^ *LD Acceleration Method: (.*)$/) {
154                                 my $status = $1;
155                                 # can at least be "Controller Cache" or HP SSD Smart Path", both OK
156                                 if ($status eq 'All disabled') {
157                                         push @{$status{'Acceleration method'}}, "LD$logicaldrive disabled";
158                                         record('WARNING');
159                                 }
160                         }
161                 }
162         }
163
164         if (!$nodrives && scalar @logicaldrives == 0) {
165                 push @resultstr, "Slot $slot: unexpectedly, found no logical drives in list.";
166                 record('UNKNOWN');
167         } elsif ($nodrives && scalar keys %status > 0) {
168                 push @resultstr, "Slot $slot: have no logical drives but status results?";
169                 record('UNKNOWN');
170                 next;
171         } elsif ($nodrives) {
172                 push @resultstr, "Slot $slot: no logical drives";
173         };
174
175
176         my $pds = runcmd("controller slot=$slot pd all show");
177         for (@$pds) {
178                 chomp;
179                 next if /^$/;
180                 next if (/^\S.*in Slot $slot/);
181                 next if /^ *array [A-Z]$/;
182                 next if /^ *unassigned/;
183                 if (/^ *(array [A-Z]) \(Failed\)$/) {
184                         record('CRITICAL');
185                         push @{$status{'Failed'}}, $1;
186                 } elsif (/^Error: The specified controller does not have any physical drives on it.$/) {
187                         $nodrives = 1;
188                 } elsif (/^ *physicaldrive (\S+) .* (OK|Predictive Failure|Failed|Rebuilding)(?:, (?:active )?spare)?\)$/) {
189                         my $drive = $1;
190                         my $status = $2;
191                         push @{$status{$status}}, $drive;
192                         if ($status eq 'OK') {
193                         } elsif ($status eq 'Predictive Failure' ||
194                                  $status eq 'Rebuilding') {
195                                 record('WARNING');
196                         } elsif ($status eq 'Failed') {
197                                 record('CRITICAL');
198                         } else {
199                                 record('UNKNOWN');
200                         };      
201                         push @drives, $drive;
202                 } else {
203                         die ("Cannot read line '$_' gotten from hpssacli controller slot=$slot pd all show\n");
204                 };
205         };
206
207         # Check that all drives have the proper transfer speed.
208         # sometimes stuff breaks and they fall back to 10mb/sec.
209         for my $drive (@drives) {
210                 # skip drives that are known to have failed
211                 next if (exists $status{'Failed'} && grep {$drive eq $_} @{$status{'Failed'}});
212                 my $type;
213                 if ($drive =~ /^[0-9]+:[0-9]+$/) { # scsi drives
214                         $type = 'SCSI';
215                 } elsif ($drive =~ /^[0-9]+[EI]:[0-9]+:[0-9]+$/) { # SAS
216                         $type = 'SAS';
217                 } elsif ($drive =~ /^[0-9]+[C]:[0-9]+:[0-9]+$/) { # New 6GBPS SAS
218                         $type = 'SAS+';
219                 } else {
220                         # I'm not going to run pass arguments of unknown form to the shell..
221                         warn ("Unknown diskdrive ID $drive\n");
222                         next;
223                 }
224
225                 my $pd = runcmd("controller slot=$slot pd $drive show");
226                 while (defined $pd->[0] && !($pd->[0] =~ /physicaldrive/)) {
227                         shift @$pd;
228                 };
229                 shift @$pd;
230                 my %value;
231                 for (@$pd) {
232                         if (m/^\s*(.*?):\s*(.*?)\s*$/) {
233                                 $value{$1} = $2;
234                         }
235                 }
236
237                 my $key;
238                 my $expected;
239                 if ($type eq 'SCSI') {
240                         $key = 'Transfer Speed';
241                         if (!defined $value{'Transfer Mode'}) {
242                                 record('WARNING');
243                                 push @{$status{'unknown transfer mode'}}, $drive;
244                                 next;
245                         } elsif ($value{'Transfer Mode'} eq 'Ultra 3 Wide') {
246                                 $expected = '160 MB/Sec';
247                         } elsif ($value{'Transfer Mode'} eq 'Ultra 320 Wide') {
248                                 $expected = '320 MB/Sec';
249                         } else {
250                                 record('WARNING');
251                                 push @{$status{'unknown transfer mode'}}, $drive."(".$value{'Transfer Mode'}.")";
252                                 next;
253                         };
254                 } elsif ($type eq 'SAS' || $type eq 'SAS+') {
255                         $key = 'PHY Transfer Rate';
256                         if ($value{'Interface Type'} eq 'SATA') {
257                                 $expected = [ '1.5Gbps', '3.0Gbps', '6.0Gbps' ];
258                         } elsif ($value{'PHY Count'} eq '2') {
259                                 if (defined($value{'Redundant Path(s)'})) {
260                                         $expected = [ '3.0GBPS, 3.0GBPS', '6.0GBPS, 6.0GBPS',
261                                                       '12.0GBPS, 12.0GBPS' ];
262                                 } else {
263                                         $expected = [ '3.0GBPS, Unknown', 'Unknown, 3.0GBPS',
264                                                       '6.0GBPS, Unknown', 'Unknown, 6.0GBPS',
265                                                       '12.0GBPS, Unknown', 'Unknown, 12.0GBPS' ];
266                                 }
267                         } else {
268                                 $expected = [ '3.0GBPS', '6.0GBPS', '12.0GBPS' ];
269                         }
270                 } else {
271                         warn "Should not be here.  Do not know what to do with type '$type'\n";
272                         next;
273                 }
274
275                 if ($params->{'ignore-transfer-speed'}) {
276                         if (grep { $drive eq $_ } @{$params->{'ignore-transfer-speed'}}) {
277                                 push @{$status{'ignored transfer speed'}}, $drive."(".$value{$key}.")";
278                                 next;
279                         };
280                 };
281                 if (!defined $value{$key}) {
282                         record('WARNING');
283                         push @{$status{'unknown transfer speed'}}, $drive;
284                 } elsif (ref($expected) eq 'ARRAY') {
285                         if (scalar(grep { uc($value{$key}) eq uc($_) } @$expected) == 0) {
286                                 record('WARNING');
287                                 push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
288                         };
289                 } elsif (uc($value{$key}) ne uc($expected)) {
290                         record('WARNING');
291                         push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
292                 };
293         };
294
295         if ($nodrives && scalar keys %status > 0) {
296                 push @resultstr, "Slot $slot: have no drives but status results?";
297                 record('UNKNOWN');
298                 next;
299         } elsif ($nodrives) {
300                 push @resultstr, "Slot $slot: no drives";
301                 next;
302         };
303
304         my $cst = runcmd("controller slot=$slot show detail");
305         for (@$cst) {
306                 chomp;
307                 next if /^$/;
308                 next if (/^\S.*in Slot $slot/);
309                 if (/^ *(Controller|Cache|Battery\/Capacitor) Status: (.*)$/) {
310                         my $system = $1;
311                         my $status = $2;
312
313                         if ($system eq 'Cache') {
314                                 # Can be:
315                                 # - 'OK'
316                                 # - 'Not Configured' (for e.g. HP SSD Smart Path)
317                                 # - 'Permanently Disabled'
318                                 # - ...?
319                                 next if $status =~ /^(OK|Not Configured)$/;
320                         }
321
322                         push @freetext, "$system: $status";
323                         if ($status ne 'OK') {
324                                 next if ($params->{'no-battery'} && $system eq 'Battery/Capacitor');
325                                 record('WARNING');
326                         };
327                 } elsif (/^ *(Cache Status Details): (Cable Error)/) {
328                         push @freetext, $2;
329                         record('CRITICAL');
330                 } elsif (/^ *(Battery\/Capacitor Count): (.*)/) {
331                         next if $params->{'no-battery'} || int($2) > 0;
332                         push @freetext, "Battery count: $2";
333                         record('CRITICAL');
334                 };
335         };
336
337         my $status = join(" - ", ((map { $_.": ".join(", ", @{$status{$_}}) } keys %status), @freetext));
338
339         push @resultstr, "Slot $slot: $status";
340 };
341
342 print "$EXITCODE: ", join(" --- ", @resultstr), "\n";
343 exit $CODE{$EXITCODE};