modules/roles/manifests/snapshot_web.pp

   1 class roles::snapshot_web {
   2         include apache2
   3         include apache2::rewrite
   4
   5         # snapshot abusers
   6         #  61.69.254.110 - 20180705, mirroring with wget
   7         # 20180821 large amount of requests way too fast from some amazon AWS instances
   8         #  18.185.157.46
   9         #  18.194.174.202
  10         #  18.184.181.169
  11         #  18.184.5.230
  12         #  18.194.137.96
  13         #  18.197.147.183
  14         #  3.120.39.137
  15         #  3.120.41.69
  16         #  35.158.129.130
  17         #  52.59.199.25
  18         #  52.59.228.158
  19         #  52.59.245.42
  20         #  52.59.253.41
  21         #  52.59.71.13
  22         # 20180821 mirroring
  23         #  99.137.191.34
  24         @ferm::rule { 'dsa-snapshot-abusers':
  25                 prio  => "000",
  26                 rule  => "saddr (61.69.254.110 18.128.0.0/9 3.120.0.0/14 35.156.0.0/14 52.58.0.0/15 99.137.191.34) DROP",
  27         }
  28
  29         ensure_packages ( [
  30                 "libapache2-mod-wsgi",
  31                 ], {
  32                 ensure => 'installed',
  33         })
  34
  35         apache2::site { '020-snapshot.debian.org':
  36                 site   => 'snapshot.debian.org',
  37                 content => template('roles/snapshot/snapshot.debian.org.conf.erb')
  38         }
  39
  40         case $::hostname {
  41                 'lw07': {
  42                         $ipv4addr        = '185.17.185.185'
  43                         $ipv6addr        = '2001:1af8:4020:b030:deb::185'
  44                         $ipv6addr_apache = '2001:1af8:4020:b030:deb::187'
  45                 }
  46                 'sallinen': {
  47                         $ipv4addr        = '193.62.202.27'
  48                         $ipv6addr        = '2001:630:206:4000:1a1a:0:c13e:ca1b'
  49                         $ipv6addr_apache = '2001:630:206:4000:1a1a:0:c13e:ca1a'
  50                 }
  51                 default: {
  52                         fail ( "unknown host $::hostname for snapshot_web." )
  53                 }
  54         }
  55
  56         # varnish cache
  57         ###############
  58         @ferm::rule { 'dsa-nat-snapshot-varnish-v4':
  59                 table => 'nat',
  60                 chain => 'PREROUTING',
  61                 rule  => "proto tcp daddr ${ipv4addr} dport 80 REDIRECT to-ports 6081",
  62         }
  63
  64         varnish::config { 'default':
  65                 listen  => [
  66                         ':6081',
  67                         "[$ipv6addr]:80"
  68                         ],
  69                 backend => 'file,/var/lib/varnish/varnish_storage.bin,8G',
  70                 content => template('roles/snapshot/snapshot.debian.org.vcl.erb'),
  71         }
  72
  73         # the ipv6 port 80 is owned by varnish
  74         file { '/etc/apache2/ports.conf':
  75                 content  => @("EOF"),
  76                         Listen 0.0.0.0:80
  77                         Listen [$ipv6addr_apache]:80
  78                         | EOF
  79                 require => Package['apache2'],
  80                 notify  => Service['apache2'],
  81         }
  82
  83         # haproxy ssl termination
  84         #########################
  85         include haproxy
  86         file { '/etc/haproxy/haproxy.cfg':
  87                 content => template('roles/snapshot/haproxy.cfg.erb'),
  88                 require => Package['haproxy'],
  89                 notify  => Service['haproxy'],
  90         }
  91         ssl::service { 'snapshot.debian.org':
  92                 notify  => Service['haproxy'],
  93                 key => true,
  94         }
  95 }