modules/roles/manifests/snapshot_web.pp

   1 class roles::snapshot_web {
   2         include apache2
   3         include apache2::rewrite
   4
   5         # snapshot abusers
   6         #  61.69.254.110 - 20180705, mirroring with wget
   7         # 20180821 large amount of requests way too fast from some amazon AWS instances
   8         #  18.185.157.46
   9         #  18.194.174.202
  10         #  18.184.181.169
  11         #  18.184.5.230
  12         #  18.194.137.96
  13         #  18.197.147.183
  14         #  3.120.39.137
  15         #  3.120.41.69
  16         #  35.158.129.130
  17         #  52.59.199.25
  18         #  52.59.228.158
  19         #  52.59.245.42
  20         #  52.59.253.41
  21         #  52.59.71.13
  22         # 20180821 mirroring
  23         #  99.137.191.34
  24         # 20181110 crawler
  25         #  51.15.215.91
  26         # 20181222, excessive number of requests
  27         #  208.91.68.213
  28         # 198.11.128.0/18
  29         # running jugdo against snapshot
  30         #  159.226.95.0/24
  31         #  84.204.194.0/24
  32         #  211.13.205.0/24
  33         @ferm::rule { 'dsa-snapshot-abusers':
  34                 prio  => "005",
  35                 rule  => "saddr (61.69.254.110 18.128.0.0/9 3.120.0.0/14 35.156.0.0/14 52.58.0.0/15 99.137.191.34 51.15.215.91 208.91.68.213 198.11.128.0/18 159.226.95.0/24 84.204.194.0/24 211.13.205.0/24) DROP",
  36         }
  37
  38         ensure_packages ( [
  39                 "libapache2-mod-wsgi",
  40                 ], {
  41                 ensure => 'installed',
  42         })
  43
  44         apache2::site { '020-snapshot.debian.org':
  45                 site   => 'snapshot.debian.org',
  46                 content => template('roles/snapshot/snapshot.debian.org.conf.erb')
  47         }
  48
  49         case $::hostname {
  50                 'lw07': {
  51                         $ipv4addr        = '185.17.185.185'
  52                         $ipv6addr        = '2001:1af8:4020:b030:deb::185'
  53                         $ipv6addr_apache = '2001:1af8:4020:b030:deb::187'
  54                 }
  55                 'sallinen': {
  56                         $ipv4addr        = '193.62.202.27'
  57                         $ipv6addr        = '2001:630:206:4000:1a1a:0:c13e:ca1b'
  58                         $ipv6addr_apache = '2001:630:206:4000:1a1a:0:c13e:ca1a'
  59                 }
  60                 default: {
  61                         fail ( "unknown host $::hostname for snapshot_web." )
  62                 }
  63         }
  64
  65         @ferm::rule { 'dsa-snapshot-connlimit':
  66                 domain => '(ip ip6)',
  67                 prio  => "005",
  68                 rule  => "proto tcp mod state state (NEW) interface ! lo daddr (${ipv4addr} ${ipv6addr})  mod multiport destination-ports (80 443) mod connlimit connlimit-above 3 DROP;
  69                           proto tcp mod state state (NEW) interface ! lo                                                dport 6081                 mod connlimit connlimit-above 3 DROP
  70                            ",
  71         }
  72
  73         # varnish cache
  74         ###############
  75         @ferm::rule { 'dsa-nat-snapshot-varnish-v4':
  76                 table => 'nat',
  77                 chain => 'PREROUTING',
  78                 rule  => "proto tcp daddr ${ipv4addr} dport 80 REDIRECT to-ports 6081",
  79         }
  80
  81         varnish::config { 'default':
  82                 listen  => [
  83                         ':6081',
  84                         "[$ipv6addr]:80"
  85                         ],
  86                 backend => 'file,/var/lib/varnish/varnish_storage.bin,8G',
  87                 content => template('roles/snapshot/snapshot.debian.org.vcl.erb'),
  88         }
  89
  90         # the ipv6 port 80 is owned by varnish
  91         file { '/etc/apache2/ports.conf':
  92                 content  => @("EOF"),
  93                         Listen 0.0.0.0:80
  94                         Listen [$ipv6addr_apache]:80
  95                         | EOF
  96                 require => Package['apache2'],
  97                 notify  => Service['apache2'],
  98         }
  99
 100         # haproxy ssl termination
 101         #########################
 102         include haproxy
 103         file { '/etc/haproxy/haproxy.cfg':
 104                 content => template('roles/snapshot/haproxy.cfg.erb'),
 105                 require => Package['haproxy'],
 106                 notify  => Service['haproxy'],
 107         }
 108         ssl::service { 'snapshot.debian.org':
 109                 notify  => Service['haproxy'],
 110                 key => true,
 111         }
 112 }