modules/roles/manifests/snapshot_web.pp

   1 class roles::snapshot_web {
   2         include apache2
   3         include apache2::rewrite
   4
   5         # snapshot abusers
   6         #  61.69.254.110 - 20180705, mirroring with wget
   7         # 20180821 large amount of requests way too fast from some amazon AWS instances
   8         #  18.185.157.46
   9         #  18.194.174.202
  10         #  18.184.181.169
  11         #  18.184.5.230
  12         #  18.194.137.96
  13         #  18.197.147.183
  14         #  3.120.39.137
  15         #  3.120.41.69
  16         #  35.158.129.130
  17         #  52.59.199.25
  18         #  52.59.228.158
  19         #  52.59.245.42
  20         #  52.59.253.41
  21         #  52.59.71.13
  22         # 20180821 mirroring
  23         #  99.137.191.34
  24         # 20181110 crawler
  25         #  51.15.215.91
  26         # 20181222, excessive number of requests
  27         #  208.91.68.213
  28         # 198.11.128.0/18
  29         # running jugdo against snapshot
  30         #  159.226.95.0/24
  31         @ferm::rule { 'dsa-snapshot-abusers':
  32                 prio  => "005",
  33                 rule  => "saddr (61.69.254.110 18.128.0.0/9 3.120.0.0/14 35.156.0.0/14 52.58.0.0/15 99.137.191.34 51.15.215.91 208.91.68.213 198.11.128.0/18 159.226.95.0/24) DROP",
  34         }
  35
  36         ensure_packages ( [
  37                 "libapache2-mod-wsgi",
  38                 ], {
  39                 ensure => 'installed',
  40         })
  41
  42         apache2::site { '020-snapshot.debian.org':
  43                 site   => 'snapshot.debian.org',
  44                 content => template('roles/snapshot/snapshot.debian.org.conf.erb')
  45         }
  46
  47         case $::hostname {
  48                 'lw07': {
  49                         $ipv4addr        = '185.17.185.185'
  50                         $ipv6addr        = '2001:1af8:4020:b030:deb::185'
  51                         $ipv6addr_apache = '2001:1af8:4020:b030:deb::187'
  52                 }
  53                 'sallinen': {
  54                         $ipv4addr        = '193.62.202.27'
  55                         $ipv6addr        = '2001:630:206:4000:1a1a:0:c13e:ca1b'
  56                         $ipv6addr_apache = '2001:630:206:4000:1a1a:0:c13e:ca1a'
  57                 }
  58                 default: {
  59                         fail ( "unknown host $::hostname for snapshot_web." )
  60                 }
  61         }
  62
  63         @ferm::rule { 'dsa-snapshot-connlimit':
  64                 domain => '(ip ip6)',
  65                 prio  => "005",
  66                 rule  => "proto tcp mod state state (NEW) interface ! lo daddr (${ipv4addr} ${ipv6addr})  mod multiport destination-ports (80 443) mod connlimit connlimit-above 3 DROP;
  67                           proto tcp mod state state (NEW) interface ! lo                                                dport 6081                 mod connlimit connlimit-above 3 DROP
  68                            ",
  69         }
  70
  71         # varnish cache
  72         ###############
  73         @ferm::rule { 'dsa-nat-snapshot-varnish-v4':
  74                 table => 'nat',
  75                 chain => 'PREROUTING',
  76                 rule  => "proto tcp daddr ${ipv4addr} dport 80 REDIRECT to-ports 6081",
  77         }
  78
  79         varnish::config { 'default':
  80                 listen  => [
  81                         ':6081',
  82                         "[$ipv6addr]:80"
  83                         ],
  84                 backend => 'file,/var/lib/varnish/varnish_storage.bin,8G',
  85                 content => template('roles/snapshot/snapshot.debian.org.vcl.erb'),
  86         }
  87
  88         # the ipv6 port 80 is owned by varnish
  89         file { '/etc/apache2/ports.conf':
  90                 content  => @("EOF"),
  91                         Listen 0.0.0.0:80
  92                         Listen [$ipv6addr_apache]:80
  93                         | EOF
  94                 require => Package['apache2'],
  95                 notify  => Service['apache2'],
  96         }
  97
  98         # haproxy ssl termination
  99         #########################
 100         include haproxy
 101         file { '/etc/haproxy/haproxy.cfg':
 102                 content => template('roles/snapshot/haproxy.cfg.erb'),
 103                 require => Package['haproxy'],
 104                 notify  => Service['haproxy'],
 105         }
 106         ssl::service { 'snapshot.debian.org':
 107                 notify  => Service['haproxy'],
 108                 key => true,
 109         }
 110 }