modules/roles/manifests/snapshot_web.pp

   1 class roles::snapshot_web {
   2         include apache2
   3         include apache2::rewrite
   4
   5         # snapshot abusers
   6         #  61.69.254.110 - 20180705, mirroring with wget
   7         # 20180821 large amount of requests way too fast from some amazon AWS instances
   8         #  18.185.157.46
   9         #  18.194.174.202
  10         #  18.184.181.169
  11         #  18.184.5.230
  12         #  18.194.137.96
  13         #  18.197.147.183
  14         #  3.120.39.137
  15         #  3.120.41.69
  16         #  35.158.129.130
  17         #  52.59.199.25
  18         #  52.59.228.158
  19         #  52.59.245.42
  20         #  52.59.253.41
  21         #  52.59.71.13
  22         # 20180821 mirroring
  23         #  99.137.191.34
  24         # 20181110 crawler
  25         #  51.15.215.91
  26         # 20181222, excessive number of requests
  27         #  208.91.68.213
  28         # 198.11.128.0/18
  29         # running jugdo against snapshot
  30         #  159.226.95.0/24
  31         #  84.204.194.0/24
  32         #  211.13.205.0/24
  33         # 20190512 tens of thousands of queries
  34         #  63.32.0.0/14
  35         #  54.72.0.0/15
  36         #  95.115.66.23
  37         #  52.192.0.0/11
  38         #  54.72.0.0/15
  39         @ferm::rule { 'dsa-snapshot-abusers':
  40                 prio  => "005",
  41                 rule  => "saddr (61.69.254.110 18.128.0.0/9 3.120.0.0/14 35.156.0.0/14 52.58.0.0/15 99.137.191.34 51.15.215.91 208.91.68.213 198.11.128.0/18 159.226.95.0/24 84.204.194.0/24 211.13.205.0/24 63.32.0.0/14 54.72.0.0/15 95.115.66.23 52.192.0.0/11 54.72.0.0/15) DROP",
  42         }
  43
  44         ensure_packages ( [
  45                 "libapache2-mod-wsgi",
  46                 ], {
  47                 ensure => 'installed',
  48         })
  49
  50         apache2::site { '020-snapshot.debian.org':
  51                 site   => 'snapshot.debian.org',
  52                 content => template('roles/snapshot/snapshot.debian.org.conf.erb')
  53         }
  54
  55         case $::hostname {
  56                 'lw07': {
  57                         $ipv4addr        = '185.17.185.185'
  58                         $ipv6addr        = '2001:1af8:4020:b030:deb::185'
  59                         $ipv6addr_apache = '2001:1af8:4020:b030:deb::187'
  60                 }
  61                 'sallinen': {
  62                         $ipv4addr        = '193.62.202.27'
  63                         $ipv6addr        = '2001:630:206:4000:1a1a:0:c13e:ca1b'
  64                         $ipv6addr_apache = '2001:630:206:4000:1a1a:0:c13e:ca1a'
  65                 }
  66                 default: {
  67                         fail ( "unknown host $::hostname for snapshot_web." )
  68                 }
  69         }
  70
  71         @ferm::rule { 'dsa-snapshot-connlimit':
  72                 domain => '(ip ip6)',
  73                 prio  => "005",
  74                 rule  => "proto tcp mod state state (NEW) interface ! lo daddr (${ipv4addr} ${ipv6addr})  mod multiport destination-ports (80 443) mod connlimit connlimit-above 3 DROP;
  75                           proto tcp mod state state (NEW) interface ! lo                                                dport 6081                 mod connlimit connlimit-above 3 DROP
  76                            ",
  77         }
  78
  79         # varnish cache
  80         ###############
  81         @ferm::rule { 'dsa-nat-snapshot-varnish-v4':
  82                 table => 'nat',
  83                 chain => 'PREROUTING',
  84                 rule  => "proto tcp daddr ${ipv4addr} dport 80 REDIRECT to-ports 6081",
  85         }
  86
  87         varnish::config { 'default':
  88                 listen  => [
  89                         ':6081',
  90                         "[$ipv6addr]:80"
  91                         ],
  92                 backend => 'file,/var/lib/varnish/varnish_storage.bin,8G',
  93                 content => template('roles/snapshot/snapshot.debian.org.vcl.erb'),
  94         }
  95
  96         # the ipv6 port 80 is owned by varnish
  97         file { '/etc/apache2/ports.conf':
  98                 content  => @("EOF"),
  99                         Listen 0.0.0.0:80
 100                         Listen [$ipv6addr_apache]:80
 101                         | EOF
 102                 require => Package['apache2'],
 103                 notify  => Service['apache2'],
 104         }
 105
 106         # haproxy ssl termination
 107         #########################
 108         include haproxy
 109         file { '/etc/haproxy/haproxy.cfg':
 110                 content => template('roles/snapshot/haproxy.cfg.erb'),
 111                 require => Package['haproxy'],
 112                 notify  => Service['haproxy'],
 113         }
 114         ssl::service { 'snapshot.debian.org':
 115                 notify  => Service['haproxy'],
 116                 key => true,
 117         }
 118 }