modules/roles/manifests/snapshot_web.pp

   1 class roles::snapshot_web {
   2         include apache2
   3         include apache2::rewrite
   4
   5         # snapshot abusers
   6         #  61.69.254.110 - 20180705, mirroring with wget
   7         # 20180821 large amount of requests way too fast from some amazon AWS instances
   8         #  18.185.157.46
   9         #  18.194.174.202
  10         #  18.184.181.169
  11         #  18.184.5.230
  12         #  18.194.137.96
  13         #  18.197.147.183
  14         #  3.120.39.137
  15         #  3.120.41.69
  16         #  35.158.129.130
  17         #  52.59.199.25
  18         #  52.59.228.158
  19         #  52.59.245.42
  20         #  52.59.253.41
  21         #  52.59.71.13
  22         # 20180821 mirroring
  23         #  99.137.191.34
  24         # 20181110 crawler
  25         #  51.15.215.91
  26         # 20181222, excessive number of requests
  27         #  208.91.68.213
  28         @ferm::rule { 'dsa-snapshot-abusers':
  29                 prio  => "005",
  30                 rule  => "saddr (61.69.254.110 18.128.0.0/9 3.120.0.0/14 35.156.0.0/14 52.58.0.0/15 99.137.191.34 51.15.215.91 208.91.68.213) DROP",
  31         }
  32
  33         ensure_packages ( [
  34                 "libapache2-mod-wsgi",
  35                 ], {
  36                 ensure => 'installed',
  37         })
  38
  39         apache2::site { '020-snapshot.debian.org':
  40                 site   => 'snapshot.debian.org',
  41                 content => template('roles/snapshot/snapshot.debian.org.conf.erb')
  42         }
  43
  44         case $::hostname {
  45                 'lw07': {
  46                         $ipv4addr        = '185.17.185.185'
  47                         $ipv6addr        = '2001:1af8:4020:b030:deb::185'
  48                         $ipv6addr_apache = '2001:1af8:4020:b030:deb::187'
  49                 }
  50                 'sallinen': {
  51                         $ipv4addr        = '193.62.202.27'
  52                         $ipv6addr        = '2001:630:206:4000:1a1a:0:c13e:ca1b'
  53                         $ipv6addr_apache = '2001:630:206:4000:1a1a:0:c13e:ca1a'
  54                 }
  55                 default: {
  56                         fail ( "unknown host $::hostname for snapshot_web." )
  57                 }
  58         }
  59
  60         @ferm::rule { 'dsa-snapshot-connlimit':
  61                 domain => '(ip ip6)',
  62                 prio  => "005",
  63                 rule  => "proto tcp mod state state (NEW) daddr (${ipv4addr} ${ipv6addr})  mod multiport destination-ports (80 443) mod connlimit connlimit-above 3 DROP;
  64                           proto tcp mod state state (NEW)                                                dport 6081                 mod connlimit connlimit-above 3 DROP
  65                            ",
  66         }
  67
  68         # varnish cache
  69         ###############
  70         @ferm::rule { 'dsa-nat-snapshot-varnish-v4':
  71                 table => 'nat',
  72                 chain => 'PREROUTING',
  73                 rule  => "proto tcp daddr ${ipv4addr} dport 80 REDIRECT to-ports 6081",
  74         }
  75
  76         varnish::config { 'default':
  77                 listen  => [
  78                         ':6081',
  79                         "[$ipv6addr]:80"
  80                         ],
  81                 backend => 'file,/var/lib/varnish/varnish_storage.bin,8G',
  82                 content => template('roles/snapshot/snapshot.debian.org.vcl.erb'),
  83         }
  84
  85         # the ipv6 port 80 is owned by varnish
  86         file { '/etc/apache2/ports.conf':
  87                 content  => @("EOF"),
  88                         Listen 0.0.0.0:80
  89                         Listen [$ipv6addr_apache]:80
  90                         | EOF
  91                 require => Package['apache2'],
  92                 notify  => Service['apache2'],
  93         }
  94
  95         # haproxy ssl termination
  96         #########################
  97         include haproxy
  98         file { '/etc/haproxy/haproxy.cfg':
  99                 content => template('roles/snapshot/haproxy.cfg.erb'),
 100                 require => Package['haproxy'],
 101                 notify  => Service['haproxy'],
 102         }
 103         ssl::service { 'snapshot.debian.org':
 104                 notify  => Service['haproxy'],
 105                 key => true,
 106         }
 107 }