modules/roles/manifests/ports_mirror.pp

   1 class roles::ports_mirror {
   2         include roles::archvsync_base
   3
   4         $mirror_basedir_prefix = hiera('role_config__mirrors.mirror_basedir_prefix')
   5         $archive_root = "${mirror_basedir_prefix}debian-ports"
   6         $archive_cd_root = "${mirror_basedir_prefix}debian-ports-cd"
   7
   8         $vhost_listen = $::hostname ? {
   9                 klecker    => '130.89.148.14:80 [2001:610:1908:b000::148:14]:80 [2001:67c:2564:a119::148:14]:80',
  10                 mirror-isc => '149.20.4.15:80 [2001:4f8:1:c::15]:80',
  11                 default => '*:80',
  12         }
  13         $onion_v4_addr = $::hostname ? {
  14                 klecker    => '130.89.148.14',
  15                 mirror-isc => '149.20.4.15',
  16                 default    => undef,
  17         }
  18
  19         apache2::site { '010-ftp.ports.debian.org':
  20                 site   => 'ftp.ports.debian.org',
  21                 content => template('roles/apache-ftp.ports.debian.org.erb'),
  22         }
  23
  24         if has_role('static_mirror_onion') {
  25                 if ! $onion_v4_addr {
  26                         fail("Do not have an onion_v4_addr set for $::hostname.")
  27                 }
  28
  29                 onion::service { 'ftp.ports.debian.org':
  30                         port => 80,
  31                         target_port => 80,
  32                         target_address => $onion_v4_addr,
  33                 }
  34         }
  35 }