modules/roles/manifests/keyring.pp

   1 class roles::keyring {
   2   rsync::site { 'keyring':
   3     source  => 'puppet:///modules/roles/keyring/rsyncd.conf',
   4     sslname => 'keyring.debian.org',
   5   }
   6
   7   ssl::service { 'keyring.debian.org':
   8     notify   => Exec['service apache2 reload'],
   9     key      => true,
  10     tlsaport => [443, 1873],
  11   }
  12
  13   include named::authoritative
  14
  15   $notify_address_bind = join(getfromhash($deprecated::allnodeinfo, 'denis.debian.org', 'ipHostNumber'), '; ')
  16
  17   ferm::rule { '01-dsa-bind':
  18     domain      => '(ip ip6)',
  19     description => 'Allow nameserver access',
  20     rule        => '&TCP_UDP_SERVICE_RANGE(53, ( $HOST_NAGIOS $HOST_DNSPRIMARY ) )',
  21   }
  22
  23   concat::fragment { 'dsa-named-conf-puppet-misc---openpgpkey-zone':
  24     target  => '/etc/bind/named.conf.puppet-misc',
  25     order   => '020',
  26     content => @("EOF"),
  27       zone "_openpgpkey.debian.org" {
  28         type master;
  29         file "/srv/keyring.debian.org/_openpgpkey.debian.org.zone";
  30         allow-query { any; };
  31         allow-transfer {
  32           key tsig-denis.debian.org-kaufmann.debian.org ;
  33           127.0.0.1;
  34         };
  35         also-notify {
  36           ${notify_address_bind};
  37         };
  38       };
  39       | EOF
  40   }
  41
  42 }