modules/postgres/manifests/backup_server.pp

   1 #
   2 class postgres::backup_server::globals {
   3         $make_base_backups = '/usr/local/bin/postgres-make-base-backups'
   4         $pgpassfile = '/home/debbackup/.pgpass'
   5         $sshkeys_sources = '/etc/dsa/postgresql-backup/sshkeys-sources'
   6
   7         $tag_base_backup = "postgresql::server::backup-source-make-base-backup-entry"
   8         $tag_source_sshkey = "postgresql::server::backup-source-sshkey"
   9         $tag_source_pgpassline = "postgresql::server::backup-source-pgpassline"
  10 }
  11
  12 class postgres::backup_server {
  13         include postgres::backup_server::globals
  14
  15         package { 'postgresql-client-9.1':
  16                 ensure => installed
  17         }
  18         package { 'postgresql-client-9.4':
  19                 ensure => installed
  20         }
  21
  22         concat { $postgres::backup_server::globals::make_base_backups:
  23                 mode => '0555',
  24         }
  25         concat::fragment { 'make-base-backups-header':
  26                 target => $postgres::backup_server::globals::make_base_backups,
  27                 content => template('postgres/backup_server/postgres-make-base-backups.erb'),
  28                 order  => '00',
  29         }
  30         Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_base_backup |>>
  31         concat::fragment { 'make-base-backups-tail':
  32                 target => $postgres::backup_server::globals::make_base_backups,
  33                 content  => @(EOTEMPLATE),
  34                                 # EOF by make-base-backups-tail fragment
  35                                 EOF
  36                                 | EOTEMPLATE
  37                 order  => '99',
  38         }
  39         if $::hostname in [backuphost] {
  40                 file { '/etc/cron.d/puppet-postgres-make-base-backups':
  41                         content  => "20 1 * * 0 debbackup chronic ${$postgres::backup_server::globals::make_base_backups}\n",
  42                 }
  43         } else  {
  44                 file { '/etc/cron.d/puppet-postgres-make-base-backups':
  45                         content  => "20 0 * * 6 debbackup chronic ${$postgres::backup_server::globals::make_base_backups}\n",
  46                 }
  47         }
  48
  49         # Maintain authorized_keys file on backup servers for WAL shipping
  50         #
  51         # do not let other hosts directly build our authorized_keys file,
  52         # instead go via a script that somewhat validates intput
  53         file { '/etc/dsa/postgresql-backup':
  54                 ensure => 'directory',
  55         }
  56         file { '/usr/local/bin/postgres-make-backup-sshauthkeys':
  57                 content => template('postgres/backup_server/postgres-make-backup-sshauthkeys.erb'),
  58                 mode   => '0555',
  59                 notify  => Exec['postgres-make-backup-sshauthkeys'],
  60         }
  61         file { '/etc/dsa/postgresql-backup/sshkeys-manual':
  62                 content => template('postgres/backup_server/sshkeys-manual.erb'),
  63                 notify  => Exec['postgres-make-backup-sshauthkeys'],
  64         }
  65         concat { $postgres::backup_server::globals::sshkeys_sources:
  66                 notify  => Exec['postgres-make-backup-sshauthkeys'],
  67         }
  68         concat::fragment { 'postgresql-backup/source-sshkeys-header':
  69                 target => $postgres::backup_server::globals::sshkeys_sources ,
  70                 content  => @(EOF),
  71                                 # <name> <ip addresses> <key>
  72                                 | EOF
  73                 order  => '00',
  74         }
  75         Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_sshkey |>>
  76         exec { "postgres-make-backup-sshauthkeys":
  77                 command => "/usr/local/bin/postgres-make-backup-sshauthkeys",
  78                 refreshonly => true,
  79         }
  80
  81         # Maintain .pgpass file on backup servers
  82         concat { $postgres::backup_server::globals::pgpassfile:
  83                 owner => 'debbackup',
  84                 group => 'debbackup',
  85                 mode  => '0400'
  86         }
  87         concat::fragment{ 'pgpass-local':
  88                 target => $postgres::backup_server::globals::pgpassfile,
  89                 source => '/home/debbackup/.pgpass-local',
  90                 order  => '00'
  91         }
  92         Concat::Fragment <<| tag == $postgres::backup_server::globals::tag_source_pgpassline |>>
  93 }
  94
  95 define postgres::backup_server::register_backup_clienthost (
  96         $sshpubkey = $::postgresql_key,
  97         $ipaddrlist = join(getfromhash($site::nodeinfo, 'ldap', 'ipHostNumber'), ","),
  98         $hostname = $::hostname,
  99 ) {
 100         include postgres::backup_server::globals
 101
 102         if $sshpubkey {
 103                 $addr = assert_type(String[1], $ipaddrlist)
 104                 @@concat::fragment { "postgresql::server::backup-source-clienthost::$name::$fqdn":
 105                         target => $postgres::backup_server::globals::sshkeys_sources ,
 106                         content  => @("EOF"),
 107                                         ${hostname} ${addr} ${sshpubkey}
 108                                         | EOF
 109                         tag     => $postgres::backup_server::globals::tag_source_sshkey,
 110                 }
 111         }
 112 }
 113
 114 define postgres::backup_server::register_backup_cluster (
 115         $hostname = $::fqdn,
 116         $pg_port,
 117         $pg_role,
 118         $pg_password,
 119         $pg_cluster,
 120         $pg_version,
 121 ) {
 122         include postgres::backup_server::globals
 123
 124         # foobar.debian.org:5432:*:debian-backup:swordfish
 125         @@concat::fragment { "postgresql::server::backup-source-pgpassline::$hostname::$pg_port::$pg_role":
 126                 target => $postgres::backup_server::globals::pgpassfile,
 127                 content => @("EOF"),
 128                                 ${hostname}:${pg_port}:*:${pg_role}:${pg_password}
 129                                 | EOF
 130                 tag     => $postgres::backup_server::globals::tag_source_pgpassline,
 131         }
 132         #
 133         # vittoria.debian.org   5432    debian-backup           main            9.6
 134         @@concat::fragment { "postgresql::server::backup-source-make-base-backup-entry::$hostname::$pg_port::$pg_role":
 135                 target => $postgres::backup_server::globals::make_base_backups,
 136                 content => @("EOF"),
 137                                 ${hostname}     ${pg_port}      ${pg_role}      ${pg_cluster}   ${pg_version}
 138                                 | EOF
 139                 tag     => $postgres::backup_server::globals::tag_base_backup,
 140         }
 141 }