modules/onion/manifests/balance.pp

   1 class onion::balance {
   2         include onion
   3
   4         package { 'onionbalance':
   5                 ensure => installed,
   6         }
   7         service { 'onionbalance':
   8                 ensure => running,
   9                 require => Package['onionbalance'],
  10         }
  11
  12         file { '/usr/local/bin/tor-onion-name':
  13                 mode    => '0555',
  14                 source  => 'puppet:///modules/onion/tor-onion-name',
  15         }
  16         file { '/usr/local/bin/create-onionbalance-config':
  17                 mode    => '0555',
  18                 source  => 'puppet:///modules/onion/create-onionbalance-config',
  19                 notify  => Exec['create-onionbalance-config'],
  20         }
  21
  22         concat::fragment { 'onion::torrc_control_header':
  23                 target  => "/etc/tor/torrc",
  24                 order   => '10',
  25                 content => "ControlPort 9051\n\n",
  26         }
  27
  28         @@concat::fragment { "onion::balance::onionbalance-services.yaml":
  29                 target  => "/srv/puppet.debian.org/puppet-facts/onionbalance-services.yaml",
  30                 content => "${onion_balance_service_hostname}\n",
  31                 tag     => "onionbalance-services.yaml",
  32         }
  33
  34         concat { '/etc/onionbalance/config-dsa-snippet.yaml':
  35                 notify  => Exec['create-onionbalance-config'],
  36                 require => File['/usr/local/bin/create-onionbalance-config']
  37         }
  38         Concat::Fragment <<| tag == "onion::balance::dsa-snippet" |>>
  39
  40         exec { "create-onionbalance-config":
  41                 command => "/usr/local/bin/create-onionbalance-config",
  42                 refreshonly => true,
  43                 require => [ File['/usr/local/bin/create-onionbalance-config'], Package['onionbalance'] ],
  44                 notify  => Service['onionbalance'],
  45         }
  46 }