modules/nagios/manifests/client.pp

   1 class nagios::client inherits nagios {
   2   package { 'dsa-nagios-nrpe-config':
   3     ensure => purged
   4   }
   5   package { 'dsa-nagios-checks':
   6     ensure => installed,
   7     tag    => extra_repo,
   8   }
   9
  10   service { 'nagios-nrpe-server':
  11     ensure    => running,
  12     hasstatus => false,
  13     pattern   => 'nrpe',
  14   }
  15
  16   Ferm::Rule::Simple <<| tag == 'nagios-nrpe::server' |>>
  17
  18   file { '/etc/default/nagios-nrpe-server':
  19     source  => 'puppet:///modules/nagios/common/default',
  20     require => Package['nagios-nrpe-server'],
  21     notify  => Service['nagios-nrpe-server'],
  22   }
  23   file { '/etc/default/nagios-nrpe':
  24     ensure => absent,
  25     notify => Service['nagios-nrpe-server'],
  26   }
  27   file { '/etc/nagios/':
  28     ensure  => directory,
  29     recurse => remote,
  30     source  => 'puppet:///files/empty/',
  31     require => Package['nagios-nrpe-server'],
  32     notify  => Service['nagios-nrpe-server'],
  33   }
  34   file { '/etc/nagios/nrpe.cfg':
  35     content => template('nagios/nrpe.cfg.erb'),
  36     notify  => Service['nagios-nrpe-server'],
  37   }
  38   file { '/etc/nagios/nrpe.d':
  39     ensure  => directory,
  40     recurse => remote,
  41     source  => 'puppet:///files/empty/',
  42     notify  => Service['nagios-nrpe-server'],
  43   }
  44
  45   concat { '/etc/nagios/nrpe.d/debianorg.cfg':
  46     ensure_newline => true,
  47     warn           => '# This file is maintained with puppet',
  48     notify         => Service['nagios-nrpe-server'],
  49     mode           => '0444',
  50   }
  51   concat { 'nrpe-debian-staticchecks':
  52     target  => '/etc/nagios/nrpe.d/debianorg.cfg',
  53     content => template('nagios/inc-debian.org.erb'),
  54   }
  55   Concat::Fragment <<| tag == 'nagios-nrpe::server::debianorg.cfg' |>>
  56
  57   file { '/etc/nagios/nrpe.d/nrpe_dsa.cfg':
  58     source => 'puppet:///modules/nagios/dsa-nagios/generated/nrpe_dsa.cfg',
  59     notify => Service['nagios-nrpe-server'],
  60   }
  61   file { '/etc/nagios/obsolete-packages-ignore':
  62     source  => 'puppet:///modules/nagios/common/obsolete-packages-ignore',
  63     require => Package['dsa-nagios-checks'],
  64   }
  65   file { '/etc/nagios/check-libs.conf':
  66     source  => 'puppet:///modules/nagios/common/check-libs.conf',
  67     require => Package['dsa-nagios-checks'],
  68   }
  69   file { '/etc/nagios/obsolete-packages-ignore.d/hostspecific':
  70     content => template('nagios/obsolete-packages-ignore.d-hostspecific.erb'),
  71     require => Package['dsa-nagios-checks'],
  72   }
  73   file { '/usr/local/sbin/dsa-check-libs':
  74     ensure => absent,
  75   }
  76
  77   file { '/etc/cron.d/puppet-nagios-wraps': ensure => absent, }
  78   concat::fragment { 'puppet-crontab--nagios--dsa-check-puppet-agent':
  79     target  => '/etc/cron.d/puppet-crontab',
  80     order   => '010',
  81     content => @(EOF)
  82       47 * * * * root dsa-wrap-nagios-check -s puppet-agent dsa-check-puppet_agent -d0 -c 28800 -w 18000
  83       | EOF
  84   }
  85 }