modules/exim/manifests/vdomain.pp

   1 # add an exim virtualdomain entry on this host
   2 #
   3 # @param mail_user  User to run the virtual email domain's pipe jobs and deliveries as
   4 # @param mail_group Group to run the virtual email domain's pipe jobs and deliveries as
   5 # @param owner      User to own the directories and files
   6 # @param group      Group to own the directories and files
   7 # @param domain     email domain (defaults to $name)
   8 # @param maildir    Mail directory, usually and defaults to /srv/$name/mail
   9 define exim::vdomain (
  10   String $domain = $name,
  11   String $maildir = "/srv/${name}/mail",
  12   String $owner = 'root',
  13   String $group = 'root',
  14   String $mail_user = $owner,
  15   String $mail_group = $group,
  16 ) {
  17   file { $maildir:
  18     ensure => directory,
  19     mode   => '2755',
  20     owner  => $owner,
  21     group  => $group,
  22   }
  23
  24   file { [
  25     "${maildir}/aliases",
  26     "${maildir}/callout_users",
  27     "${maildir}/grey_users",
  28     "${maildir}/neversenders",
  29     "${maildir}/rbllist",
  30     "${maildir}/rhsbllist",
  31     ] :
  32     mode  => '0644',
  33     owner => $owner,
  34     group => $group,
  35   }
  36
  37   concat::fragment { "virtualdomain_${domain}":
  38     target  => '/etc/exim4/virtualdomains',
  39     content => "${domain}: user=${mail_user} group=${mail_group} directory=${maildir}\n",
  40   }
  41 }