modules/debian-org/manifests/init.pp

   1 # == Class: debian-org
   2 #
   3 # Stuff common to all debian.org servers
   4 #
   5 class debian-org {
   6         include debian-org::apt
   7
   8         if $systemd {
   9                 include systemd
  10                 $servicefiles = 'present'
  11         } else {
  12                 $servicefiles = 'absent'
  13         }
  14
  15         $debianadmin = [
  16                 'debian-archive-debian-samhain-reports@master.debian.org',
  17                 'debian-admin@ftbfs.de',
  18                 'weasel@debian.org',
  19                 'steve@lobefin.net',
  20                 'zumbi@oron.es'
  21         ]
  22
  23         package { [
  24                         'klogd',
  25                         'sysklogd',
  26                         'rsyslog',
  27                         'os-prober',
  28                         'apt-listchanges',
  29                 ]:
  30                 ensure => purged,
  31         }
  32         package { [
  33                         'debian.org',
  34                         'dsa-munin-plugins',
  35                 ]:
  36                 ensure => installed,
  37                 tag    => extra_repo,
  38         }
  39         file { '/etc/ssh/ssh_known_hosts':
  40                 ensure  => present,
  41                 replace => false,
  42                 mode    => '0644',
  43                 source  => 'puppet:///modules/debian-org/basic-ssh_known_hosts'
  44         }
  45
  46         if ($::lsbmajdistrelease >= 8) {
  47                 $rubyfs_package = 'ruby-filesystem'
  48         } else {
  49                 $rubyfs_package = 'libfilesystem-ruby1.9'
  50         }
  51         package { [
  52                         'apt-utils',
  53                         'bash-completion',
  54                         'dnsutils',
  55                         'less',
  56                         'lsb-release',
  57                         $rubyfs_package,
  58                         'mtr-tiny',
  59                         'nload',
  60                         'pciutils',
  61                 ]:
  62                 ensure => installed,
  63         }
  64
  65         munin::check { [
  66                         'cpu',
  67                         'entropy',
  68                         'forks',
  69                         'interrupts',
  70                         'iostat',
  71                         'irqstats',
  72                         'load',
  73                         'memory',
  74                         'ntp_offset',
  75                         'ntp_states',
  76                         'open_files',
  77                         'open_inodes',
  78                         'processes',
  79                         'swap',
  80                         'uptime',
  81                         'vmstat',
  82                 ]:
  83         }
  84
  85         if getfromhash($site::nodeinfo, 'broken-rtc') {
  86                 package { 'fake-hwclock':
  87                         ensure => installed,
  88                         tag    => extra_repo,
  89                 }
  90         }
  91
  92         package { 'molly-guard':
  93                 ensure => installed,
  94         }
  95         file { '/etc/molly-guard/run.d/10-check-kvm':
  96                 mode    => '0755',
  97                 source  => 'puppet:///modules/debian-org/molly-guard/10-check-kvm',
  98                 require => Package['molly-guard'],
  99         }
 100         file { '/etc/molly-guard/run.d/15-acquire-reboot-lock':
 101                 mode    => '0755',
 102                 source  => 'puppet:///modules/debian-org/molly-guard/15-acquire-reboot-lock',
 103                 require => Package['molly-guard'],
 104         }
 105
 106         augeas { 'inittab_replicate':
 107                 context => '/files/etc/inittab',
 108                 changes => [
 109                         'set ud/runlevels 2345',
 110                         'set ud/action respawn',
 111                         'set ud/process "/usr/bin/ud-replicated -d"',
 112                 ],
 113                 notify  => Exec['init q'],
 114         }
 115
 116
 117         file { '/etc/facter':
 118                 ensure  => directory,
 119                 purge   => true,
 120                 force   => true,
 121                 recurse => true,
 122                 source  => 'puppet:///files/empty/',
 123         }
 124         file { '/etc/facter/facts.d':
 125                 ensure => directory,
 126         }
 127         file { '/etc/facter/facts.d/debian_facts.yaml':
 128                 content => template('debian-org/debian_facts.yaml.erb')
 129         }
 130         file { '/etc/timezone':
 131                 source => 'puppet:///modules/debian-org/timezone',
 132                 notify => Exec['dpkg-reconfigure tzdata -pcritical -fnoninteractive'],
 133         }
 134         if $::hostname == handel {
 135                 include puppetmaster::db
 136                 $dbpassword = $puppetmaster::db::password
 137         }
 138         file { '/etc/puppet/puppet.conf':
 139                 content => template('debian-org/puppet.conf.erb'),
 140         }
 141         file { '/etc/default/puppet':
 142                 source => 'puppet:///modules/debian-org/puppet.default',
 143         }
 144         file { '/etc/systemd':
 145                 ensure  => directory,
 146                 mode => 0755,
 147         }
 148         file { '/etc/systemd/system':
 149                 ensure  => directory,
 150                 mode => 0755,
 151         }
 152         file { '/etc/systemd/system/ud-replicated.service':
 153                 ensure => $servicefiles,
 154                 source => 'puppet:///modules/debian-org/ud-replicated.service',
 155                 notify => Exec['systemctl daemon-reload'],
 156         }
 157         if $systemd {
 158                 file { '/etc/systemd/system/multi-user.target.wants/ud-replicated.service':
 159                         ensure => 'link',
 160                         target => '../ud-replicated.service',
 161                         notify => Exec['systemctl daemon-reload'],
 162                 }
 163         }
 164         file { '/etc/systemd/system/puppet.service':
 165                 ensure => 'link',
 166                 target => '/dev/null',
 167                 notify => Exec['systemctl daemon-reload'],
 168         }
 169         file { '/etc/systemd/system/proc-sys-fs-binfmt_misc.automount':
 170                 ensure => 'link',
 171                 target => '/dev/null',
 172                 notify => Exec['systemctl daemon-reload'],
 173         }
 174
 175         file { '/etc/cron.d/dsa-puppet-stuff':
 176                 content => template('debian-org/dsa-puppet-stuff.cron.erb'),
 177                 require => Package['debian.org'],
 178         }
 179         file { '/etc/ldap/ldap.conf':
 180                 require => Package['debian.org'],
 181                 content  => template('debian-org/ldap.conf.erb'),
 182         }
 183         file { '/etc/pam.d/common-session':
 184                 require => Package['debian.org'],
 185                 content => template('debian-org/pam.common-session.erb'),
 186         }
 187         file { '/etc/pam.d/common-session-noninteractive':
 188                 require => Package['debian.org'],
 189                 content => template('debian-org/pam.common-session-noninteractive.erb'),
 190         }
 191         file { '/etc/rc.local':
 192                 mode   => '0755',
 193                 content => template('debian-org/rc.local.erb'),
 194                 notify => Exec['service rc.local start'],
 195         }
 196         file { '/etc/dsa':
 197                 ensure => directory,
 198                 mode   => '0755',
 199         }
 200         file { '/etc/dsa/cron.ignore.dsa-puppet-stuff':
 201                 source  => 'puppet:///modules/debian-org/dsa-puppet-stuff.cron.ignore',
 202                 require => Package['debian.org']
 203         }
 204         file { '/etc/nsswitch.conf':
 205                 mode   => '0755',
 206                 source => 'puppet:///modules/debian-org/nsswitch.conf',
 207         }
 208
 209         file { '/etc/profile.d/timeout.sh':
 210                 mode   => '0555',
 211                 source => 'puppet:///modules/debian-org/etc.profile.d/timeout.sh',
 212         }
 213         file { '/etc/zsh':
 214                 ensure => directory,
 215         }
 216         file { '/etc/zsh/zprofile':
 217                 mode   => '0444',
 218                 source => 'puppet:///modules/debian-org/etc.zsh/zprofile',
 219         }
 220
 221         # set mmap_min_addr to 4096 to mitigate
 222         # Linux NULL-pointer dereference exploits
 223         site::sysctl { 'mmap_min_addr':
 224                 ensure => absent
 225         }
 226         site::sysctl { 'perf_event_paranoid':
 227                 key   => 'kernel.perf_event_paranoid',
 228                 value => '2',
 229         }
 230         site::alternative { 'editor':
 231                 linkto => '/usr/bin/vim.basic',
 232         }
 233         site::alternative { 'view':
 234                 linkto => '/usr/bin/vim.basic',
 235         }
 236         mailalias { 'samhain-reports':
 237                 ensure    => present,
 238                 recipient => $debianadmin,
 239                 require   => Package['debian.org']
 240         }
 241
 242         file { '/usr/local/bin/check_for_updates':
 243                 source => 'puppet:///modules/debian-org/check_for_updates',
 244                 mode   => '0755',
 245                 owner  => root,
 246                 group  => root,
 247         }
 248
 249         exec { 'dpkg-reconfigure tzdata -pcritical -fnoninteractive':
 250                 path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 251                 refreshonly => true
 252         }
 253         exec { 'service puppetmaster restart':
 254                 refreshonly => true
 255         }
 256         exec { 'service rc.local start':
 257                 refreshonly => true
 258         }
 259         exec { 'init q':
 260                 refreshonly => true
 261         }
 262
 263         exec { 'systemctl daemon-reload':
 264                 refreshonly => true,
 265                 onlyif  => "test -x /bin/systemctl"
 266         }
 267
 268         exec { 'systemd-tmpfiles --create --exclude-prefix=/dev':
 269                 refreshonly => true,
 270                 onlyif  => "test -x /bin/systemd-tmpfiles"
 271         }
 272
 273         tidy { '/var/lib/puppet/clientbucket/':
 274                 age      => '2w',
 275                 recurse  => 9,
 276                 type     => ctime,
 277                 matches  => [ 'paths', 'contents' ],
 278                 schedule => weekly
 279         }
 280
 281         file { '/root/.bashrc':
 282                 source => 'puppet:///modules/debian-org/root-dotfiles/bashrc',
 283         }
 284         file { '/root/.profile':
 285                 source => 'puppet:///modules/debian-org/root-dotfiles/profile',
 286         }
 287         file { '/root/.selected_editor':
 288                 source => 'puppet:///modules/debian-org/root-dotfiles/selected_editor',
 289         }
 290         file { '/root/.screenrc':
 291                 source => 'puppet:///modules/debian-org/root-dotfiles/screenrc',
 292         }
 293         file { '/root/.vimrc':
 294                 source => 'puppet:///modules/debian-org/root-dotfiles/vimrc',
 295         }
 296 }