modules/debian-org/manifests/init.pp

   1 # == Class: debian-org
   2 #
   3 # Stuff common to all debian.org servers
   4 #
   5 class debian-org {
   6         if getfromhash($site::nodeinfo, 'hoster', 'mirror-debian') {
   7                 $mirror = getfromhash($site::nodeinfo, 'hoster', 'mirror-debian')
   8         } else {
   9                 #$mirror = 'http://ftp.debian.org/debian/'
  10                 if $::lsbmajdistrelease <= 8 {
  11                         $mirror = 'http://cdn-fastly.deb.debian.org/debian/'
  12                 } else {
  13                         $mirror = 'http://deb.debian.org/debian/'
  14                 }
  15         }
  16
  17         if $::lsbmajdistrelease <= 7 {
  18                 $mungedcodename = $::lsbdistcodename
  19         } elsif ($::debarchitecture in ['kfreebsd-amd64', 'kfreebsd-i386']) {
  20                 $mungedcodename = "${::lsbdistcodename}-kfreebsd"
  21         } else {
  22                 $mungedcodename = $::lsbdistcodename
  23         }
  24
  25         if $systemd {
  26                 include systemd
  27                 $servicefiles = 'present'
  28         } else {
  29                 $servicefiles = 'absent'
  30         }
  31
  32         $debianadmin = [
  33                 'debian-archive-debian-samhain-reports@master.debian.org',
  34                 'debian-admin@ftbfs.de',
  35                 'weasel@debian.org',
  36                 'steve@lobefin.net',
  37                 'zumbi@oron.es'
  38         ]
  39
  40         package { [
  41                         'klogd',
  42                         'sysklogd',
  43                         'rsyslog',
  44                         'os-prober',
  45                         'apt-listchanges',
  46                 ]:
  47                 ensure => purged,
  48         }
  49         package { [
  50                         'debian.org',
  51                         'dsa-munin-plugins',
  52                 ]:
  53                 ensure => installed,
  54                 tag    => extra_repo,
  55         }
  56         file { '/etc/ssh/ssh_known_hosts':
  57                 ensure  => present,
  58                 replace => false,
  59                 mode    => '0644',
  60                 source  => 'puppet:///modules/debian-org/basic-ssh_known_hosts'
  61         }
  62
  63         if ($::lsbmajdistrelease >= 8) {
  64                 $rubyfs_package = 'ruby-filesystem'
  65         } else {
  66                 $rubyfs_package = 'libfilesystem-ruby1.9'
  67         }
  68         package { [
  69                         'apt-utils',
  70                         'bash-completion',
  71                         'dnsutils',
  72                         'less',
  73                         'lsb-release',
  74                         $rubyfs_package,
  75                         'mtr-tiny',
  76                         'nload',
  77                         'pciutils',
  78                 ]:
  79                 ensure => installed,
  80         }
  81
  82         munin::check { [
  83                         'cpu',
  84                         'entropy',
  85                         'forks',
  86                         'interrupts',
  87                         'iostat',
  88                         'irqstats',
  89                         'load',
  90                         'memory',
  91                         'ntp_offset',
  92                         'ntp_states',
  93                         'open_files',
  94                         'open_inodes',
  95                         'processes',
  96                         'swap',
  97                         'uptime',
  98                         'vmstat',
  99                 ]:
 100         }
 101
 102         if getfromhash($site::nodeinfo, 'broken-rtc') {
 103                 package { 'fake-hwclock':
 104                         ensure => installed,
 105                         tag    => extra_repo,
 106                 }
 107         }
 108
 109         package { 'molly-guard':
 110                 ensure => installed,
 111         }
 112         file { '/etc/molly-guard/run.d/10-check-kvm':
 113                 mode    => '0755',
 114                 source  => 'puppet:///modules/debian-org/molly-guard/10-check-kvm',
 115                 require => Package['molly-guard'],
 116         }
 117         file { '/etc/molly-guard/run.d/15-acquire-reboot-lock':
 118                 mode    => '0755',
 119                 source  => 'puppet:///modules/debian-org/molly-guard/15-acquire-reboot-lock',
 120                 require => Package['molly-guard'],
 121         }
 122
 123         file { '/etc/apt/trusted-keys.d':
 124                 ensure => absent,
 125                 force  => true,
 126         }
 127
 128         file { '/etc/apt/trusted.gpg':
 129                 mode    => '0600',
 130                 content => "",
 131         }
 132
 133         if ($::lsbmajdistrelease >= 8) {
 134                 site::aptrepo { 'security':
 135                         url        => 'http://security-cdn.debian.org/',
 136                         suite      => "${mungedcodename}/updates",
 137                         components => ['main','contrib','non-free']
 138                 }
 139         } else {
 140                 site::aptrepo { 'security':
 141                         ensure => absent,
 142                 }
 143         }
 144         site::aptrepo { 'debian-lts':
 145                 ensure => absent,
 146         }
 147
 148         site::aptrepo { 'backports.debian.org':
 149                 url        => $mirror,
 150                 suite      => "${::lsbdistcodename}-backports",
 151                 components => ['main','contrib','non-free']
 152         }
 153
 154         site::aptrepo { 'volatile':
 155                 url        => $mirror,
 156                 suite      => "${::lsbdistcodename}-updates",
 157                 components => ['main','contrib','non-free']
 158         }
 159
 160         if ($::hostname in [] or $::debarchitecture in ['kfreebsd-amd64', 'kfreebsd-i386']) {
 161                 site::aptrepo { 'proposed-updates':
 162                         url        => $mirror,
 163                         suite      => "${mungedcodename}-proposed-updates",
 164                         components => ['main','contrib','non-free']
 165                 }
 166         } else {
 167                 site::aptrepo { 'proposed-updates':
 168                         ensure => absent,
 169                 }
 170         }
 171
 172         site::aptrepo { 'debian.org':
 173                 ensure => absent,
 174         }
 175
 176         site::aptrepo { 'db.debian.org':
 177                 url        => 'http://db.debian.org/debian-admin',
 178                 suite      => 'debian-all',
 179                 components => 'main',
 180                 key        => 'puppet:///modules/debian-org/db.debian.org.gpg',
 181         }
 182         site::aptrepo { 'db.debian.org-suite':
 183                 url        => 'http://db.debian.org/debian-admin',
 184                 suite      => $::lsbdistcodename,
 185                 components => 'main',
 186         }
 187
 188         augeas { 'inittab_replicate':
 189                 context => '/files/etc/inittab',
 190                 changes => [
 191                         'set ud/runlevels 2345',
 192                         'set ud/action respawn',
 193                         'set ud/process "/usr/bin/ud-replicated -d"',
 194                 ],
 195                 notify  => Exec['init q'],
 196         }
 197
 198         if getfromhash($site::nodeinfo, 'hoster', 'mirror-debian') {
 199                 site::aptrepo { 'debian':
 200                         url        => getfromhash($site::nodeinfo, 'hoster', 'mirror-debian'),
 201                         suite      => $mungedcodename,
 202                         components => ['main','contrib','non-free']
 203                 }
 204         }
 205         site::aptrepo { 'debian-cdn':
 206                 ensure => absent,
 207         }
 208
 209         site::aptrepo { 'debian2':
 210                 url        => "http://cdn-fastly.deb.debian.org/debian",
 211                 suite      => $mungedcodename,
 212                 components => ['main','contrib','non-free']
 213         }
 214
 215         file { '/etc/facter':
 216                 ensure  => directory,
 217                 purge   => true,
 218                 force   => true,
 219                 recurse => true,
 220                 source  => 'puppet:///files/empty/',
 221         }
 222         file { '/etc/facter/facts.d':
 223                 ensure => directory,
 224         }
 225         file { '/etc/facter/facts.d/debian_facts.yaml':
 226                 content => template('debian-org/debian_facts.yaml.erb')
 227         }
 228         file { '/etc/apt/preferences':
 229                 source => 'puppet:///modules/debian-org/apt.preferences',
 230         }
 231         file { '/etc/apt/apt.conf.d/local-compression':
 232                 source => 'puppet:///modules/debian-org/apt.conf.d/local-compression',
 233         }
 234         file { '/etc/apt/apt.conf.d/local-recommends':
 235                 source => 'puppet:///modules/debian-org/apt.conf.d/local-recommends',
 236         }
 237         file { '/etc/apt/apt.conf.d/local-pdiffs':
 238                 source => 'puppet:///modules/debian-org/apt.conf.d/local-pdiffs',
 239         }
 240         file { '/etc/apt/apt.conf.d/local-langs':
 241                 source => 'puppet:///modules/debian-org/apt.conf.d/local-langs',
 242         }
 243         file { '/etc/timezone':
 244                 source => 'puppet:///modules/debian-org/timezone',
 245                 notify => Exec['dpkg-reconfigure tzdata -pcritical -fnoninteractive'],
 246         }
 247         if $::hostname == handel {
 248                 include puppetmaster::db
 249                 $dbpassword = $puppetmaster::db::password
 250         }
 251         file { '/etc/puppet/puppet.conf':
 252                 content => template('debian-org/puppet.conf.erb'),
 253         }
 254         file { '/etc/default/puppet':
 255                 source => 'puppet:///modules/debian-org/puppet.default',
 256         }
 257         file { '/etc/systemd':
 258                 ensure  => directory,
 259                 mode => 0755,
 260         }
 261         file { '/etc/systemd/system':
 262                 ensure  => directory,
 263                 mode => 0755,
 264         }
 265         file { '/etc/systemd/system/ud-replicated.service':
 266                 ensure => $servicefiles,
 267                 source => 'puppet:///modules/debian-org/ud-replicated.service',
 268                 notify => Exec['systemctl daemon-reload'],
 269         }
 270         if $systemd {
 271                 file { '/etc/systemd/system/multi-user.target.wants/ud-replicated.service':
 272                         ensure => 'link',
 273                         target => '../ud-replicated.service',
 274                         notify => Exec['systemctl daemon-reload'],
 275                 }
 276         }
 277         file { '/etc/systemd/system/puppet.service':
 278                 ensure => 'link',
 279                 target => '/dev/null',
 280                 notify => Exec['systemctl daemon-reload'],
 281         }
 282
 283         file { '/etc/cron.d/dsa-puppet-stuff':
 284                 content => template('debian-org/dsa-puppet-stuff.cron.erb'),
 285                 require => Package['debian.org'],
 286         }
 287         file { '/etc/ldap/ldap.conf':
 288                 require => Package['debian.org'],
 289                 content  => template('debian-org/ldap.conf.erb'),
 290         }
 291         file { '/etc/pam.d/common-session':
 292                 require => Package['debian.org'],
 293                 content => template('debian-org/pam.common-session.erb'),
 294         }
 295         file { '/etc/pam.d/common-session-noninteractive':
 296                 require => Package['debian.org'],
 297                 content => template('debian-org/pam.common-session-noninteractive.erb'),
 298         }
 299         file { '/etc/rc.local':
 300                 mode   => '0755',
 301                 content => template('debian-org/rc.local.erb'),
 302                 notify => Exec['service rc.local start'],
 303         }
 304         file { '/etc/dsa':
 305                 ensure => directory,
 306                 mode   => '0755',
 307         }
 308         file { '/etc/dsa/cron.ignore.dsa-puppet-stuff':
 309                 source  => 'puppet:///modules/debian-org/dsa-puppet-stuff.cron.ignore',
 310                 require => Package['debian.org']
 311         }
 312         file { '/etc/nsswitch.conf':
 313                 mode   => '0755',
 314                 source => 'puppet:///modules/debian-org/nsswitch.conf',
 315         }
 316
 317         file { '/etc/profile.d/timeout.sh':
 318                 mode   => '0555',
 319                 source => 'puppet:///modules/debian-org/etc.profile.d/timeout.sh',
 320         }
 321         file { '/etc/zsh':
 322                 ensure => directory,
 323         }
 324         file { '/etc/zsh/zprofile':
 325                 mode   => '0444',
 326                 source => 'puppet:///modules/debian-org/etc.zsh/zprofile',
 327         }
 328
 329         # set mmap_min_addr to 4096 to mitigate
 330         # Linux NULL-pointer dereference exploits
 331         site::sysctl { 'mmap_min_addr':
 332                 ensure => absent
 333         }
 334         site::sysctl { 'perf_event_paranoid':
 335                 key   => 'kernel.perf_event_paranoid',
 336                 value => '2',
 337         }
 338         site::alternative { 'editor':
 339                 linkto => '/usr/bin/vim.basic',
 340         }
 341         site::alternative { 'view':
 342                 linkto => '/usr/bin/vim.basic',
 343         }
 344         mailalias { 'samhain-reports':
 345                 ensure    => present,
 346                 recipient => $debianadmin,
 347                 require   => Package['debian.org']
 348         }
 349
 350         file { '/usr/local/bin/check_for_updates':
 351                 source => 'puppet:///modules/debian-org/check_for_updates',
 352                 mode   => '0755',
 353                 owner  => root,
 354                 group  => root,
 355         }
 356
 357         exec { 'apt-get update':
 358                 path    => '/usr/bin:/usr/sbin:/bin:/sbin',
 359                 onlyif  => '/usr/local/bin/check_for_updates',
 360                 require => File['/usr/local/bin/check_for_updates']
 361         }
 362         Exec['apt-get update']->Package<| tag == extra_repo |>
 363
 364         exec { 'dpkg-reconfigure tzdata -pcritical -fnoninteractive':
 365                 path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 366                 refreshonly => true
 367         }
 368         exec { 'service puppetmaster restart':
 369                 refreshonly => true
 370         }
 371         exec { 'service rc.local start':
 372                 refreshonly => true
 373         }
 374         exec { 'init q':
 375                 refreshonly => true
 376         }
 377
 378         exec { 'systemctl daemon-reload':
 379                 refreshonly => true,
 380                 onlyif  => "test -x /bin/systemctl"
 381         }
 382
 383         exec { 'systemd-tmpfiles --create --exclude-prefix=/dev':
 384                 refreshonly => true,
 385                 onlyif  => "test -x /bin/systemd-tmpfiles"
 386         }
 387
 388         tidy { '/var/lib/puppet/clientbucket/':
 389                 age      => '2w',
 390                 recurse  => 9,
 391                 type     => ctime,
 392                 matches  => [ 'paths', 'contents' ],
 393                 schedule => weekly
 394         }
 395
 396         file { '/root/.bashrc':
 397                 source => 'puppet:///modules/debian-org/root-dotfiles/bashrc',
 398         }
 399         file { '/root/.profile':
 400                 source => 'puppet:///modules/debian-org/root-dotfiles/profile',
 401         }
 402         file { '/root/.screenrc':
 403                 source => 'puppet:///modules/debian-org/root-dotfiles/screenrc',
 404         }
 405         file { '/root/.vimrc':
 406                 source => 'puppet:///modules/debian-org/root-dotfiles/vimrc',
 407         }
 408 }