modules/debian-org/manifests/init.pp

   1 # == Class: debian-org
   2 #
   3 # Stuff common to all debian.org servers
   4 #
   5 class debian-org {
   6         include debian-org::apt
   7
   8         if $systemd {
   9                 include systemd
  10                 $servicefiles = 'present'
  11         } else {
  12                 $servicefiles = 'absent'
  13         }
  14
  15         $debianadmin = [
  16                 'debian-archive-debian-samhain-reports@master.debian.org',
  17                 'debian-admin@ftbfs.de',
  18                 'weasel@debian.org',
  19                 'steve@lobefin.net',
  20                 'zumbi@oron.es'
  21         ]
  22
  23         package { [
  24                         'klogd',
  25                         'sysklogd',
  26                         'rsyslog',
  27                         'os-prober',
  28                         'apt-listchanges',
  29                 ]:
  30                 ensure => purged,
  31         }
  32         package { [
  33                         'debian.org',
  34                         'dsa-munin-plugins',
  35                 ]:
  36                 ensure => installed,
  37                 tag    => extra_repo,
  38         }
  39         file { '/etc/ssh/ssh_known_hosts':
  40                 ensure  => present,
  41                 replace => false,
  42                 mode    => '0644',
  43                 source  => 'puppet:///modules/debian-org/basic-ssh_known_hosts'
  44         }
  45
  46         if ($::lsbmajdistrelease >= 8) {
  47                 $rubyfs_package = 'ruby-filesystem'
  48         } else {
  49                 $rubyfs_package = 'libfilesystem-ruby1.9'
  50         }
  51         package { [
  52                         'apt-utils',
  53                         'bash-completion',
  54                         'dnsutils',
  55                         'less',
  56                         'lsb-release',
  57                         $rubyfs_package,
  58                         'mtr-tiny',
  59                         'nload',
  60                         'pciutils',
  61                 ]:
  62                 ensure => installed,
  63         }
  64
  65         munin::check { [
  66                         'cpu',
  67                         'entropy',
  68                         'forks',
  69                         'interrupts',
  70                         'iostat',
  71                         'irqstats',
  72                         'load',
  73                         'memory',
  74                         'ntp_offset',
  75                         'ntp_states',
  76                         'open_files',
  77                         'open_inodes',
  78                         'processes',
  79                         'swap',
  80                         'uptime',
  81                         'vmstat',
  82                 ]:
  83         }
  84
  85         if getfromhash($site::nodeinfo, 'broken-rtc') {
  86                 package { 'fake-hwclock':
  87                         ensure => installed,
  88                         tag    => extra_repo,
  89                 }
  90         }
  91
  92         package { 'molly-guard':
  93                 ensure => installed,
  94         }
  95         file { '/etc/molly-guard/run.d/10-check-kvm':
  96                 mode    => '0755',
  97                 source  => 'puppet:///modules/debian-org/molly-guard/10-check-kvm',
  98                 require => Package['molly-guard'],
  99         }
 100         file { '/etc/molly-guard/run.d/15-acquire-reboot-lock':
 101                 mode    => '0755',
 102                 source  => 'puppet:///modules/debian-org/molly-guard/15-acquire-reboot-lock',
 103                 require => Package['molly-guard'],
 104         }
 105
 106         augeas { 'inittab_replicate':
 107                 context => '/files/etc/inittab',
 108                 changes => [
 109                         'set ud/runlevels 2345',
 110                         'set ud/action respawn',
 111                         'set ud/process "/usr/bin/ud-replicated -d"',
 112                 ],
 113                 notify  => Exec['init q'],
 114         }
 115
 116
 117         file { '/etc/facter':
 118                 ensure  => directory,
 119                 purge   => true,
 120                 force   => true,
 121                 recurse => true,
 122                 source  => 'puppet:///files/empty/',
 123         }
 124         file { '/etc/facter/facts.d':
 125                 ensure => directory,
 126         }
 127         file { '/etc/facter/facts.d/debian_facts.yaml':
 128                 content => template('debian-org/debian_facts.yaml.erb')
 129         }
 130         file { '/etc/timezone':
 131                 source => 'puppet:///modules/debian-org/timezone',
 132                 notify => Exec['dpkg-reconfigure tzdata -pcritical -fnoninteractive'],
 133         }
 134         if $::hostname == handel {
 135                 include puppetmaster::db
 136                 $dbpassword = $puppetmaster::db::password
 137         }
 138         file { '/etc/puppet/puppet.conf':
 139                 content => template('debian-org/puppet.conf.erb'),
 140                 mode => 0440,
 141                 group => 'puppet',
 142         }
 143         file { '/etc/default/puppet':
 144                 source => 'puppet:///modules/debian-org/puppet.default',
 145         }
 146         file { '/etc/systemd':
 147                 ensure  => directory,
 148                 mode => 0755,
 149         }
 150         file { '/etc/systemd/system':
 151                 ensure  => directory,
 152                 mode => 0755,
 153         }
 154         file { '/etc/systemd/system/ud-replicated.service':
 155                 ensure => $servicefiles,
 156                 source => 'puppet:///modules/debian-org/ud-replicated.service',
 157                 notify => Exec['systemctl daemon-reload'],
 158         }
 159         if $systemd {
 160                 file { '/etc/systemd/system/multi-user.target.wants/ud-replicated.service':
 161                         ensure => 'link',
 162                         target => '../ud-replicated.service',
 163                         notify => Exec['systemctl daemon-reload'],
 164                 }
 165         }
 166         file { '/etc/systemd/system/puppet.service':
 167                 ensure => 'link',
 168                 target => '/dev/null',
 169                 notify => Exec['systemctl daemon-reload'],
 170         }
 171         file { '/etc/systemd/system/proc-sys-fs-binfmt_misc.automount':
 172                 ensure => 'link',
 173                 target => '/dev/null',
 174                 notify => Exec['systemctl daemon-reload'],
 175         }
 176
 177         file { '/etc/cron.d/dsa-puppet-stuff':
 178                 content => template('debian-org/dsa-puppet-stuff.cron.erb'),
 179                 require => Package['debian.org'],
 180         }
 181         file { '/etc/ldap/ldap.conf':
 182                 require => Package['debian.org'],
 183                 content  => template('debian-org/ldap.conf.erb'),
 184         }
 185         file { '/etc/pam.d/common-session':
 186                 require => Package['debian.org'],
 187                 content => template('debian-org/pam.common-session.erb'),
 188         }
 189         file { '/etc/pam.d/common-session-noninteractive':
 190                 require => Package['debian.org'],
 191                 content => template('debian-org/pam.common-session-noninteractive.erb'),
 192         }
 193         file { '/etc/rc.local':
 194                 mode   => '0755',
 195                 content => template('debian-org/rc.local.erb'),
 196                 notify => Exec['service rc.local start'],
 197         }
 198         file { '/etc/dsa':
 199                 ensure => directory,
 200                 mode   => '0755',
 201         }
 202         file { '/etc/dsa/cron.ignore.dsa-puppet-stuff':
 203                 source  => 'puppet:///modules/debian-org/dsa-puppet-stuff.cron.ignore',
 204                 require => Package['debian.org']
 205         }
 206         file { '/etc/nsswitch.conf':
 207                 mode   => '0755',
 208                 source => 'puppet:///modules/debian-org/nsswitch.conf',
 209         }
 210
 211         file { '/etc/profile.d/timeout.sh':
 212                 mode   => '0555',
 213                 source => 'puppet:///modules/debian-org/etc.profile.d/timeout.sh',
 214         }
 215         file { '/etc/zsh':
 216                 ensure => directory,
 217         }
 218         file { '/etc/zsh/zprofile':
 219                 mode   => '0444',
 220                 source => 'puppet:///modules/debian-org/etc.zsh/zprofile',
 221         }
 222
 223         # set mmap_min_addr to 4096 to mitigate
 224         # Linux NULL-pointer dereference exploits
 225         site::sysctl { 'mmap_min_addr':
 226                 ensure => absent
 227         }
 228         site::sysctl { 'perf_event_paranoid':
 229                 key   => 'kernel.perf_event_paranoid',
 230                 value => '2',
 231         }
 232         site::alternative { 'editor':
 233                 linkto => '/usr/bin/vim.basic',
 234         }
 235         site::alternative { 'view':
 236                 linkto => '/usr/bin/vim.basic',
 237         }
 238         mailalias { 'samhain-reports':
 239                 ensure    => present,
 240                 recipient => $debianadmin,
 241                 require   => Package['debian.org']
 242         }
 243
 244         file { '/usr/local/bin/check_for_updates':
 245                 source => 'puppet:///modules/debian-org/check_for_updates',
 246                 mode   => '0755',
 247                 owner  => root,
 248                 group  => root,
 249         }
 250
 251         exec { 'dpkg-reconfigure tzdata -pcritical -fnoninteractive':
 252                 path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 253                 refreshonly => true
 254         }
 255         exec { 'service puppetmaster restart':
 256                 refreshonly => true
 257         }
 258         exec { 'service rc.local start':
 259                 refreshonly => true
 260         }
 261         exec { 'init q':
 262                 refreshonly => true
 263         }
 264
 265         exec { 'systemctl daemon-reload':
 266                 refreshonly => true,
 267                 onlyif  => "test -x /bin/systemctl"
 268         }
 269
 270         exec { 'systemd-tmpfiles --create --exclude-prefix=/dev':
 271                 refreshonly => true,
 272                 onlyif  => "test -x /bin/systemd-tmpfiles"
 273         }
 274
 275         tidy { '/var/lib/puppet/clientbucket/':
 276                 age      => '2w',
 277                 recurse  => 9,
 278                 type     => ctime,
 279                 matches  => [ 'paths', 'contents' ],
 280                 schedule => weekly
 281         }
 282
 283         file { '/root/.bashrc':
 284                 source => 'puppet:///modules/debian-org/root-dotfiles/bashrc',
 285         }
 286         file { '/root/.profile':
 287                 source => 'puppet:///modules/debian-org/root-dotfiles/profile',
 288         }
 289         file { '/root/.selected_editor':
 290                 source => 'puppet:///modules/debian-org/root-dotfiles/selected_editor',
 291         }
 292         file { '/root/.screenrc':
 293                 source => 'puppet:///modules/debian-org/root-dotfiles/screenrc',
 294         }
 295         file { '/root/.tmux.conf':
 296                 source => 'puppet:///modules/debian-org/root-dotfiles/tmux.conf',
 297         }
 298         file { '/root/.vimrc':
 299                 source => 'puppet:///modules/debian-org/root-dotfiles/vimrc',
 300         }
 301 }