modules/buildd/manifests/init.pp

   1 class buildd ($ensure=present) {
   2         # Do nothing until we get the buildd user from ldap
   3         if $::buildd_user_exists {
   4                 #
   5                 # home directory
   6                 #
   7                 file { '/home/buildd':
   8                         ensure  => directory,
   9                         mode    => '2755',
  10                         group   => buildd,
  11                         owner   => buildd,
  12                 }
  13
  14
  15                 #
  16                 # sbuild configuration, including chroots
  17                 #
  18                 include schroot
  19
  20                 package { 'sbuild':
  21                         ensure => installed,
  22                         tag    => extra_repo,
  23                 }
  24                 package { 'libsbuild-perl':
  25                         ensure => installed,
  26                         tag    => extra_repo,
  27                         before => Package['sbuild']
  28                 }
  29                 file { '/etc/sbuild/sbuild.conf':
  30                         source  => 'puppet:///modules/buildd/sbuild.conf',
  31                         require => Package['sbuild'],
  32                 }
  33                 if $has_srv_buildd {
  34                         concat::fragment { 'dsa-puppet-stuff--buildd-update-schroots':
  35                                 target => '/etc/cron.d/dsa-puppet-stuff',
  36                                 content  => @(EOF)
  37                                         13 22 * * 0,3 root PATH=/sbin:/usr/sbin:/bin:/usr/bin:/usr/local/sbin:/usr/local/bin setup-all-dchroots buildd
  38                                         | EOF
  39                         }
  40                 }
  41                 exec { 'add-buildd-user-to-sbuild':
  42                         command => 'adduser buildd sbuild',
  43                         onlyif  => "getent group sbuild > /dev/null && ! getent group sbuild | grep '\\<buildd\\>' > /dev/null"
  44                 }
  45
  46
  47                 #
  48                 # dupload configuration
  49                 #
  50                 package { 'dupload':
  51                         ensure => installed,
  52                 }
  53                 file { '/etc/dupload.conf':
  54                         source  => 'puppet:///modules/buildd/dupload.conf',
  55                         require => Package['dupload'],
  56                 }
  57                 include ferm::ftp_conntrack
  58
  59
  60                 #
  61                 # Aptitude killer
  62                 #
  63                 package { 'python-psutil':
  64                         ensure => installed,
  65                 }
  66                 file { '/usr/local/sbin/buildd-schroot-aptitude-kill':
  67                         source  => 'puppet:///modules/buildd/buildd-schroot-aptitude-kill',
  68                         mode    => '0555',
  69                 }
  70
  71                 concat::fragment { 'dsa-puppet-stuff--buildd-aptitude-killer':
  72                         target => '/etc/cron.d/dsa-puppet-stuff',
  73                         content  => @(EOF)
  74                                 */5 * * * * root /usr/local/sbin/buildd-schroot-aptitude-kill
  75                                 | EOF
  76                 }
  77
  78
  79                 #
  80                 # GPG/SSH key generation
  81                 #
  82                 file { '/home/buildd/.gnupg':
  83                         ensure  => directory,
  84                         mode    => '700',
  85                         group   => buildd,
  86                         owner   => buildd,
  87                 }
  88                 file { '/home/buildd/.gnupg/gpg.conf':
  89                         content  => "personal-digest-preferences SHA512\n",
  90                         group   => buildd,
  91                         owner   => buildd,
  92                 }
  93
  94                 if ! $::buildd_key {
  95                         exec { 'create-buildd-key':
  96                                 command => '/bin/su - buildd -c \'mkdir -p -m 02700 .ssh && ssh-keygen -C "`whoami`@`hostname` (`date +%Y-%m-%d`)" -P "" -f .ssh/id_rsa -q\'',
  97                                 onlyif  => '/usr/bin/getent passwd buildd > /dev/null && ! [ -e /home/buildd/.ssh/id_rsa ]'
  98                         }
  99                 }
 100
 101                 #
 102                 # buildd/pybuildd configuration
 103                 #
 104                 if $::hostname in [x86-bm-01,x86-grnet-01,zani] {
 105                         #
 106                         # pybuildd configuration
 107                         #
 108                         package { 'buildd':
 109                                 ensure => purged,
 110                         }
 111
 112                         package { ['python3-retrying', 'python3-yaml']:
 113                                 ensure => installed,
 114                         }
 115                         file { '/home/buildd/.profile':
 116                                 content  => @(EOT),
 117                                         export XDG_RUNTIME_DIR="/run/user/$(id -u)"
 118                                         export DBUS_SESSION_BUS_ADDRESS="unix:path=${XDG_RUNTIME_DIR}/bus"
 119                                         | EOT
 120                                 group   => buildd,
 121                                 owner   => buildd,
 122                         }
 123                         file { '/home/buildd/logs':
 124                                 ensure  => directory,
 125                                 mode    => '2750',
 126                                 group   => buildd,
 127                                 owner   => buildd,
 128                         }
 129                         file { '/var/lib/systemd/linger':
 130                                 ensure  => directory,
 131                                 mode    => '755',
 132                         }
 133                         file { "/var/lib/systemd/linger/buildd":
 134                                 ensure => present,
 135                         }
 136                         file { '/etc/systemd/journald.conf.d':
 137                                 ensure  => directory,
 138                                 mode    => '755',
 139                         }
 140                         file { '/etc/systemd/journald.conf.d/persistency.conf':
 141                                 source => 'puppet:///modules/systemd/persistency.conf',
 142                         }
 143                 } else {
 144                         #
 145                         # buildd configuration
 146                         #
 147                         file { '/home/buildd/build':
 148                                 ensure  => directory,
 149                                 mode    => '2750',
 150                                 group   => buildd,
 151                                 owner   => buildd,
 152                         }
 153                         file { '/home/buildd/logs':
 154                                 ensure  => directory,
 155                                 mode    => '2750',
 156                                 group   => buildd,
 157                                 owner   => buildd,
 158                         }
 159                         file { '/home/buildd/old-logs':
 160                                 ensure  => directory,
 161                                 mode    => '2750',
 162                                 group   => buildd,
 163                                 owner   => buildd,
 164                         }
 165                         file { '/home/buildd/upload-security':
 166                                 ensure  => directory,
 167                                 mode    => '2750',
 168                                 group   => buildd,
 169                                 owner   => buildd,
 170                         }
 171                         file { '/home/buildd/stats':
 172                                 ensure  => directory,
 173                                 mode    => '2755',
 174                                 group   => buildd,
 175                                 owner   => buildd,
 176                         }
 177                         file { '/home/buildd/stats/graphs':
 178                                 ensure  => directory,
 179                                 mode    => '2755',
 180                                 group   => buildd,
 181                                 owner   => buildd,
 182                         }
 183                         file { '/home/buildd/upload':
 184                                 ensure  => directory,
 185                                 mode    => '2755',
 186                                 group   => buildd,
 187                                 owner   => buildd,
 188                         }
 189                         file { '/home/buildd/.forward':
 190                                 content  => "|/usr/bin/buildd-mail\n",
 191                                 group   => buildd,
 192                                 owner   => buildd,
 193                         }
 194
 195                         package { 'buildd':
 196                                 ensure => installed,
 197                         }
 198                         file { '/etc/buildd/buildd.conf':
 199                                 source  => 'puppet:///modules/buildd/buildd.conf',
 200                                 require => Package['buildd'],
 201                         }
 202
 203                         if (versioncmp($::lsbmajdistrelease, '9') >= 0) {
 204                                 site::aptrepo { 'buildd.debian.org':
 205                                         ensure => absent,
 206                                 }
 207                                 file { '/etc/apt/apt.conf.d/puppet-https-buildd':
 208                                         ensure => absent,
 209                                 }
 210                         } else {
 211                                 package { 'apt-transport-https':
 212                                         ensure => installed,
 213                                 }
 214                                 site::aptrepo { 'buildd.debian.org':
 215                                         key        => 'puppet:///modules/buildd/buildd.debian.org.gpg',
 216                                         url        => 'https://apt.buildd.debian.org/',
 217                                         suite      => 'jessie',
 218                                         components => 'main',
 219                                         require    => Package['apt-transport-https'],
 220                                 }
 221                                 file { '/etc/apt/apt.conf.d/puppet-https-buildd':
 222                                         content => "Acquire::https::apt.buildd.debian.org::CaInfo \"/etc/ssl/ca-debian/ca-certificates.crt\";\n",
 223                                 }
 224                         }
 225
 226                         concat::fragment { 'dsa-puppet-stuff--buildd':
 227                                 target => '/etc/cron.d/dsa-puppet-stuff',
 228                                 source  => 'puppet:///modules/buildd/cron.d-dsa-buildd',
 229                                 require => Package['debian.org']
 230                         }
 231                         service { 'buildd':
 232                                 enable => false,
 233                                 ensure => 'stopped',
 234                         }
 235                 }
 236         }
 237 }