modules/bacula/manifests/storage.pp

   1 # the bacula storage node
   2 class bacula::storage inherits bacula {
   3   package { 'bacula-sd':
   4     ensure => installed
   5   }
   6
   7   service { 'bacula-sd':
   8     ensure    => running,
   9     enable    => true,
  10     hasstatus => true,
  11   }
  12   dsa_systemd::override { 'bacula-sd':
  13     content => @(EOT)
  14       [Service]
  15       Group=bacula
  16       SupplementaryGroups=ssl-cert
  17       | EOT
  18   }
  19
  20   exec { 'bacula-sd restart-when-idle':
  21     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
  22     command     => 'sh -c "setsid /usr/local/sbin/bacula-idle-restart sd &"',
  23     refreshonly => true,
  24     subscribe   => File[$bacula::bacula_ssl_server_cert],
  25     require     => File['/usr/local/sbin/bacula-idle-restart'],
  26   }
  27
  28
  29   file { '/etc/bacula/bacula-sd.conf':
  30     content => template('bacula/bacula-sd.conf.erb'),
  31     mode    => '0640',
  32     group   => bacula,
  33     notify  => Exec['bacula-sd restart-when-idle']
  34   }
  35
  36   file { '/etc/bacula/storage-conf.d':
  37     ensure  => directory,
  38     mode    => '0755',
  39     group   => bacula,
  40     purge   => true,
  41     force   => true,
  42     recurse => true,
  43     source  => 'puppet:///files/empty/',
  44     notify  => Exec['bacula-sd restart-when-idle']
  45   }
  46
  47   ferm::rule { 'dsa-bacula-sd':
  48     domain      => '(ip ip6)',
  49     description => 'Allow bacula-sd access from director and clients (i.e. all of Debian)',
  50     rule        => 'proto tcp mod state state (NEW) dport (bacula-sd) @subchain \'bacula-sd\' { saddr ($HOST_DEBIAN) ACCEPT; }',
  51     notarule    => true,
  52   }
  53   # allow access from director
  54   Ferm::Rule::Simple <<| tag == "bacula::director-to-storage::${bacula::bacula_director_address}" |>> {
  55     port => $bacula::bacula_storage_port,
  56   }
  57
  58   file { '/etc/bacula/storage-conf.d/empty.conf':
  59     content => '',
  60     mode    => '0440',
  61     group   => bacula,
  62     notify  => Exec['bacula-sd restart-when-idle']
  63   }
  64
  65   file { "${bacula::bacula_backup_path}/Catalog":
  66     ensure => directory,
  67     mode   => '0755',
  68     owner  => bacula,
  69     group  => bacula,
  70     ;
  71   }
  72
  73   package { 'python3-psycopg2': ensure => installed }
  74   file { '/usr/local/bin/bacula-unlink-removed-volumes':
  75     source => 'puppet:///modules/bacula/bacula-unlink-removed-volumes',
  76     mode   => '0555',
  77   }
  78   file { '/etc/cron.d/puppet-bacula-storage-stuff': ensure => absent, }
  79   concat::fragment { 'puppet-crontab--bacula-storage':
  80     target  => '/etc/cron.d/puppet-crontab',
  81     content => @(EOF)
  82       @daily bacula chronic /usr/local/bin/bacula-unlink-removed-volumes -v
  83       | EOF
  84   }
  85
  86   Bacula::Storage_per_node<<| |>>
  87 }