modules/bacula/manifests/storage.pp

   1 # the bacula storage node
   2 class bacula::storage inherits bacula {
   3   package { 'bacula-sd':
   4     ensure => installed
   5   }
   6
   7   service { 'bacula-sd':
   8     ensure    => running,
   9     enable    => true,
  10     hasstatus => true,
  11   }
  12   dsa_systemd::override { 'bacula-sd':
  13     content => @(EOT)
  14       [Service]
  15       Group=bacula
  16       SupplementaryGroups=ssl-cert
  17       | EOT
  18   }
  19
  20   exec { 'bacula-sd restart-when-idle':
  21     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
  22     command     => "sh -c 'setsid /usr/local/sbin/bacula-idle-restart ${bacula::bacula_storage_port} bacula-sd &'",
  23     refreshonly => true,
  24     subscribe   => File[$bacula::bacula_ssl_server_cert],
  25     require     => File['/usr/local/sbin/bacula-idle-restart'],
  26   }
  27
  28
  29   file { '/etc/bacula/bacula-sd.conf':
  30     content => template('bacula/bacula-sd.conf.erb'),
  31     mode    => '0640',
  32     group   => bacula,
  33     notify  => Exec['bacula-sd restart-when-idle']
  34   }
  35
  36   file { '/etc/bacula/storage-conf.d':
  37     ensure  => directory,
  38     mode    => '0755',
  39     group   => bacula,
  40     purge   => true,
  41     force   => true,
  42     recurse => true,
  43     source  => 'puppet:///files/empty/',
  44     notify  => Exec['bacula-sd restart-when-idle']
  45   }
  46
  47   # allow access from director and fds
  48   ferm::rule::simple { 'dsa-bacula-sd':
  49     description => 'Access to the bacula-storage',
  50     port        => $bacula::bacula_storage_port,
  51     target      => 'bacula-sd',
  52   }
  53   Ferm::Rule::Simple <<| tag == "bacula::director-to-storage::${bacula::bacula_director_address}" |>>;
  54   Ferm::Rule::Simple <<| tag == "bacula::fd-to-storage::${::fqdn}" |>>;
  55
  56   file { '/etc/bacula/storage-conf.d/empty.conf':
  57     content => '',
  58     mode    => '0440',
  59     group   => bacula,
  60     notify  => Exec['bacula-sd restart-when-idle']
  61   }
  62
  63   file { "${bacula::bacula_backup_path}/Catalog":
  64     ensure => directory,
  65     mode   => '0755',
  66     owner  => bacula,
  67     group  => bacula,
  68     ;
  69   }
  70
  71   package { 'python3-psycopg2': ensure => installed }
  72   file { '/usr/local/bin/bacula-unlink-removed-volumes':
  73     source => 'puppet:///modules/bacula/bacula-unlink-removed-volumes',
  74     mode   => '0555',
  75   }
  76   file { '/etc/cron.d/puppet-bacula-storage-stuff': ensure => absent, }
  77   concat::fragment { 'puppet-crontab--bacula-storage':
  78     target  => '/etc/cron.d/puppet-crontab',
  79     content => @(EOF)
  80       @daily bacula chronic /usr/local/bin/bacula-unlink-removed-volumes -v
  81       | EOF
  82   }
  83
  84   Bacula::Storage_per_node<<| |>>
  85 }