modules/bacula/manifests/storage.pp

   1 # the bacula storage node
   2 #
   3 # @param backup_path      directory where backups should be stored
   4 # @param filestor_device  storage device name prefix
   5 # @param filestor_name    storage device media type name prefix
   6 # @param port_sd          port for the sd to listen on
   7 # @param storage_name     bacula name of this sd instance
   8 # @param storage_address  address of this sd instance that other instances should connect to (dns name)
   9 # @param has_ipv4         SD should listen on ipv4
  10 # @param has_ipv6         SD should listen on ipv6
  11 class bacula::storage (
  12   String $backup_path     = '/srv/bacula',
  13   String $filestor_device = 'FileStorage',
  14   String $filestor_name   = 'File',
  15   Integer $port_sd        = 9103,
  16   String $storage_name    = "${::fqdn}-sd",
  17   Stdlib::Host $storage_address = $::fqdn,
  18   Boolean $has_ipv4        = $bacula::public_addresses.any |$addr| { $addr =~ Stdlib::IP::Address::V4 },
  19   Boolean $has_ipv6        = $bacula::public_addresses.any |$addr| { $addr =~ Stdlib::IP::Address::V6 },
  20 ) inherits bacula {
  21
  22   package { 'bacula-sd':
  23     ensure => installed
  24   }
  25
  26   service { 'bacula-sd':
  27     ensure    => running,
  28     enable    => true,
  29     hasstatus => true,
  30   }
  31   dsa_systemd::override { 'bacula-sd':
  32     content => @(EOT)
  33       [Service]
  34       Group=bacula
  35       SupplementaryGroups=ssl-cert
  36       | EOT
  37   }
  38
  39   exec { 'bacula-sd restart-when-idle':
  40     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
  41     command     => "sh -c 'setsid /usr/local/sbin/bacula-idle-restart ${port_sd} bacula-sd &'",
  42     refreshonly => true,
  43     subscribe   => File[$bacula::bacula_ssl_server_cert],
  44     require     => File['/usr/local/sbin/bacula-idle-restart'],
  45   }
  46
  47
  48   file { '/etc/bacula/bacula-sd.conf':
  49     content => template('bacula/bacula-sd.conf.erb'),
  50     mode    => '0640',
  51     group   => bacula,
  52     notify  => Exec['bacula-sd restart-when-idle']
  53   }
  54
  55   file { '/etc/bacula/storage-conf.d':
  56     ensure  => directory,
  57     mode    => '0755',
  58     group   => bacula,
  59     purge   => true,
  60     force   => true,
  61     recurse => true,
  62     source  => 'puppet:///files/empty/',
  63     notify  => Exec['bacula-sd restart-when-idle']
  64   }
  65
  66   # allow access from director and fds
  67   ferm::rule::simple { 'dsa-bacula-sd':
  68     description => 'Access to the bacula-storage',
  69     port        => $port_sd,
  70     target      => 'bacula-sd',
  71   }
  72   Ferm::Rule::Simple <<| tag == 'bacula::director-to-storage' |>>;
  73   Ferm::Rule::Simple <<| tag == "bacula::fd-to-storage::${::fqdn}" |>>;
  74
  75   file { '/etc/bacula/storage-conf.d/empty.conf':
  76     content => '',
  77     mode    => '0440',
  78     group   => bacula,
  79     notify  => Exec['bacula-sd restart-when-idle']
  80   }
  81
  82   package { 'python3-psycopg2': ensure => installed }
  83   file { '/usr/local/bin/bacula-unlink-removed-volumes':
  84     source => 'puppet:///modules/bacula/bacula-unlink-removed-volumes',
  85     mode   => '0555',
  86   }
  87   file { '/etc/cron.d/puppet-bacula-storage-stuff': ensure => absent, }
  88   concat::fragment { 'puppet-crontab--bacula-storage':
  89     target  => '/etc/cron.d/puppet-crontab',
  90     content => @(EOF)
  91       @daily bacula chronic /usr/local/bin/bacula-unlink-removed-volumes -v
  92       | EOF
  93   }
  94
  95   Bacula::Storage::Director<<| tag == 'bacula::to-storage' |>>
  96   Bacula::Storage::Client<<| tag == "bacula::to-storage::${::fqdn}" |>>
  97 }