modules/bacula/manifests/director.pp

   1 # our bacula director
   2 #
   3 # @param pool_name      A token to be used in pool names
   4 # @param db_address     hostname of the postgres server for the catalog DB
   5 # @param db_port        port of the postgres server for the catalog DB
   6 # @param db_name        DB name for the catalog DB
   7 # @param db_user        username for the postgres server for the catalog DB
   8 # @param port_dir       Port that the director should listen on
   9 # @param db_sslca       SSL CA store for DB access
  10 # @param director_name  bacula name of this dir instance
  11 class bacula::director(
  12   String  $db_address,
  13   Integer $db_port,
  14   String  $db_name = 'bacula',
  15   String  $db_user = 'bacula',
  16   String  $pool_name = 'bacula',
  17   Integer $port_dir = 9101,
  18   Optional[String] $db_sslca = undef,
  19   #String $director_name    = "${::fqdn}-dir",
  20   String $director_name = $bacula::bacula_director_name,
  21 ) inherits bacula {
  22
  23   # used by e.g. bconsole
  24   $director_secret = hkdf('/etc/puppet/secret', "bacula-dir-${::fqdn}")
  25   # the RestoreFiles Job needs a Pool.  Any valid pool.
  26   $some_pool_name = "poolfull-${pool_name}-${bacula::bacula_director_address}"
  27
  28   ensure_packages ( [
  29     'bacula-director-pgsql',
  30     'bacula-common',
  31     'bacula-common-pgsql'
  32   ], {
  33     ensure => 'installed',
  34   })
  35
  36   service { 'bacula-director':
  37     ensure    => running,
  38     enable    => true,
  39     hasstatus => true,
  40     require   => Package['bacula-director-pgsql']
  41   }
  42   dsa_systemd::override { 'bacula-director':
  43     content => @(EOT)
  44       [Unit]
  45       After=unbound.service
  46       | EOT
  47   }
  48
  49   exec { 'bacula-director reload':
  50     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
  51     command     => 'service bacula-director reload',
  52     refreshonly => true,
  53   }
  54
  55   file { '/etc/bacula/conf.d':
  56     ensure  => directory,
  57     mode    => '0755',
  58     group   => bacula,
  59     purge   => true,
  60     force   => true,
  61     recurse => true,
  62     source  => 'puppet:///files/empty/',
  63     notify  => Exec['bacula-director reload']
  64   }
  65
  66   file { '/etc/bacula/bacula-dir.conf':
  67     content => template('bacula/bacula-dir.conf.erb'),
  68     mode    => '0440',
  69     group   => bacula,
  70     require => Package['bacula-director-pgsql'],
  71     notify  => Exec['bacula-director reload']
  72   }
  73
  74   file { '/etc/bacula/conf.d/empty.conf':
  75     content => '',
  76     mode    => '0440',
  77     group   => bacula,
  78     require => Package['bacula-director-pgsql'],
  79     notify  => Exec['bacula-director reload']
  80   }
  81
  82   Bacula::Director::Client             <<| tag == "bacula::to-director::${::fqdn}" |>>
  83   Bacula::Director::Client_from_storage<<| tag == "bacula::to-director::${::fqdn}" |>>
  84
  85   package { 'bacula-console':
  86     ensure => installed;
  87   }
  88
  89   file { '/etc/bacula/bconsole.conf':
  90     content => template('bacula/bconsole.conf.erb'),
  91     mode    => '0640',
  92     group   => bacula,
  93     require => Package['bacula-console']
  94   }
  95
  96   package { 'python3-psycopg2': ensure => installed }
  97   file { '/etc/bacula/scripts/volume-purge-action':
  98     mode   => '0555',
  99     source => 'puppet:///modules/bacula/volume-purge-action',
 100     ;
 101   }
 102   file { '/etc/bacula/scripts/volumes-delete-old':
 103     mode   => '0555',
 104     source => 'puppet:///modules/bacula/volumes-delete-old',
 105     ;
 106   }
 107   file { '/etc/bacula/storages-list.d':
 108     ensure  => directory,
 109     mode    => '0755',
 110     group   => bacula,
 111     purge   => true,
 112     force   => true,
 113     recurse => true,
 114     source  => 'puppet:///files/empty/',
 115   }
 116   file { '/usr/local/sbin/dsa-bacula-scheduler':
 117     source => 'puppet:///modules/bacula/dsa-bacula-scheduler',
 118     mode   => '0555',
 119   }
 120
 121   file { '/etc/cron.d/puppet-bacula-stuff': ensure => absent, }
 122   concat::fragment { 'puppet-crontab--bacula-director':
 123     target  => '/etc/cron.d/puppet-crontab',
 124     content => @(EOF)
 125       @daily root chronic /etc/bacula/scripts/volume-purge-action -v
 126       @daily root chronic /etc/bacula/scripts/volumes-delete-old -v
 127       */3 * * * * root sleep $(( $RANDOM \% 60 )); flock -w 0 -e /usr/local/sbin/dsa-bacula-scheduler /usr/local/sbin/dsa-bacula-scheduler
 128       | EOF
 129   }
 130
 131   concat { $bacula::bacula_dsa_client_list:
 132   }
 133   concat::fragment { 'bacula-dsa-client-list::header' :
 134     target  => $bacula::bacula_dsa_client_list,
 135     content => '',
 136     order   => '00',
 137   }
 138   Concat::Fragment <<| tag == $bacula::tag_bacula_dsa_client_list |>>
 139
 140   @@ferm::rule::simple { "bacula::director-to-fd::${::fqdn}":
 141     tag         => "bacula::director-to-fd::${::fqdn}",
 142     description => 'Allow bacula-fd from the bacula-director',
 143     port        => '7', # overridden on collecting
 144     saddr       => $bacula::public_addresses,
 145   }
 146   @@ferm::rule::simple { "bacula::director-to-storage::${::fqdn}":
 147     tag         => "bacula::director-to-storage::${::fqdn}",
 148     description => 'Allow bacula-storage access from the bacula-director',
 149     chain       => 'bacula-sd',
 150     saddr       => $bacula::public_addresses,
 151   }
 152 }