modules/apache2/manifests/init.pp

   1 # = Class: apache2
   2 #
   3 # Standard apache config debian.org hosts
   4 #
   5 # == Sample Usage:
   6 #
   7 #   include apache2
   8 #
   9 # @param smaller_number_of_threads by default the worker config is geared towards
  10 #                                  serving static/cheap content.  If the host is very
  11 #                                  script heavy (say the bug tracking system), set this
  12 #                                  to reduce the number of worker threads.
  13 # @param rlimitnproc A resource limit for number of processes.  The default is usually fine.
  14 # @param rlimitmem   A resource limit for memory usage.  The default is usually fine.
  15 # @param public Whether this host's apache should be accessible from the public internet.
  16 #               Sets appropriate firewall rules and optionally rate limits.
  17 class apache2(
  18   Boolean $smaller_number_of_threads = false,
  19   Integer $rlimitnproc = 256,
  20   Integer $rlimitmem = 192 * 1024 * 1024,
  21   Boolean $public = true,
  22 ) {
  23   include webserver
  24
  25   package { 'apache2':
  26     ensure => installed,
  27   }
  28
  29   service { 'apache2':
  30     ensure  => running,
  31     require => Package['apache2'],
  32   }
  33
  34   apache2::module { 'reqtimeout': }
  35   apache2::module { 'info': }
  36   apache2::module { 'status': }
  37   apache2::module { 'headers': }
  38   apache2::module { 'macro': }
  39
  40   apache2::site { '00-default':
  41     site    => 'default-debian.org',
  42     content => template('apache2/default-debian.org.erb'),
  43   }
  44   apache2::site { 'xx-default-ssl':
  45     site    => 'default-debian.org-ssl',
  46     content => template('apache2/default-debian.org-ssl.erb'),
  47   }
  48
  49   apache2::site { '000-default':
  50     ensure => absent,
  51   }
  52
  53   apache2::config { 'serve-cgi-bin':
  54     ensure => absent,
  55   }
  56
  57   if has_role('udd') {
  58     $memlimit = 512 * 1024 * 1024
  59   } elsif has_role('popcon') {
  60     $memlimit = 512 * 1024 * 1024
  61   } else {
  62     $memlimit = $rlimitmem
  63   }
  64
  65   apache2::config { 'resource-limits':
  66     content => template('apache2/resource-limits.erb'),
  67   }
  68
  69   apache2::config { 'security':
  70     source => 'puppet:///modules/apache2/security',
  71   }
  72
  73   apache2::config { 'logformat-privacy':
  74     source => 'puppet:///modules/apache2/logformat-privacy',
  75   }
  76
  77   apache2::config { 'local-serverinfo':
  78     source => 'puppet:///modules/apache2/local-serverinfo',
  79   }
  80
  81   apache2::config { 'server-status':
  82     source => 'puppet:///modules/apache2/server-status',
  83   }
  84
  85   apache2::config { 'puppet-ssl-macros':
  86     source => 'puppet:///modules/apache2/puppet-ssl-macros',
  87   }
  88
  89   apache2::config { 'puppet-ftp-macros':
  90     source => 'puppet:///modules/apache2/puppet-ftp-macros',
  91   }
  92
  93   apache2::config { 'puppet-config':
  94     content => template('apache2/puppet-config.erb'),
  95   }
  96
  97   apache2::config { 'headers':
  98     source => 'puppet:///modules/apache2/headers',
  99   }
 100
 101   apache2::config { 'disabled-service':
 102     source => 'puppet:///modules/apache2/disabled-service',
 103   }
 104
 105   apache2::module { 'mpm_event': ensure => absent }
 106   if has_role('apache_prefork') {
 107     apache2::module { 'mpm_worker': ensure => absent }
 108     apache2::module { 'mpm_prefork': }
 109   } else {
 110     apache2::module { 'mpm_prefork': ensure => absent }
 111     apache2::module { 'mpm_worker': }
 112   }
 113   file { '/etc/apache2/mods-available/mpm_worker.conf':
 114     content => template('apache2/mpm_worker.erb'),
 115   }
 116
 117   file { '/etc/logrotate.d/apache2':
 118     source => 'puppet:///modules/apache2/apache2.logrotate',
 119   }
 120
 121   file { '/var/log/apache2':
 122     ensure => directory,
 123     mode   => '0755',
 124   }
 125   file { '/var/log/apache2/.nobackup':
 126     mode    => '0644',
 127     content => '',
 128   }
 129
 130   munin::check { 'apache_accesses': }
 131   munin::check { 'apache_processes': }
 132   munin::check { 'apache_volume': }
 133   munin::check { 'apache_servers': }
 134   munin::check { 'ps_apache2':
 135     script => 'ps_',
 136   }
 137   # The munin script needs this
 138   package { 'libwww-perl':
 139     ensure => installed,
 140   }
 141
 142   if $public {
 143     if has_role('apache_ratelimited') {
 144       include apache2::dynamic
 145     } else {
 146       ferm::rule { 'dsa-http':
 147         domain      => '(ip ip6)',
 148         prio        => '23',
 149         description => 'Allow web access',
 150         rule        => '&SERVICE(tcp, (http https))'
 151       }
 152     }
 153   }
 154
 155   exec { 'service apache2 reload':
 156     path        => '/usr/bin:/usr/sbin:/bin:/sbin',
 157     command     => 'service apache2 reload',
 158     refreshonly => true,
 159     require     =>  Package['apache2'],
 160   }
 161
 162   apache2::config { 'puppet-ssl-key-pins':
 163     content => template('apache2/ssl-key-pins.erb'),
 164     notify  => Exec['service apache2 reload'],
 165   }
 166
 167   apache2::config { 'local-scheduled-shutdown':
 168     source => 'puppet:///modules/apache2/local-scheduled-shutdown',
 169   }
 170 }