dsa-nagios-checks/checks/dsa-check-hpacucli

   1 #!/usr/bin/perl -w
   2
   3 # check _physical_ disk status of disks on HP smart array controllers
   4 # requires hpacucli
   5 #
   6 # does _not_ check raid status.  use arrayprobe for that.
   7
   8 # Copyright (c) 2008,2009 Peter Palfrader <peter@palfrader.org>
   9 #
  10 # Permission is hereby granted, free of charge, to any person obtaining
  11 # a copy of this software and associated documentation files (the
  12 # "Software"), to deal in the Software without restriction, including
  13 # without limitation the rights to use, copy, modify, merge, publish,
  14 # distribute, sublicense, and/or sell copies of the Software, and to
  15 # permit persons to whom the Software is furnished to do so, subject to
  16 # the following conditions:
  17 #
  18 # The above copyright notice and this permission notice shall be
  19 # included in all copies or substantial portions of the Software.
  20 #
  21 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  22 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  23 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  24 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
  25 # LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
  26 # OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
  27 # WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  28
  29 use strict;
  30 use English;
  31 use Getopt::Long;
  32
  33 # nagios exit codes
  34 my %CODE = (
  35         'OK'            => 0,
  36         'WARNING'       => 1,
  37         'CRITICAL'      => 2,
  38         'UNKNOWN'       => 3
  39 );
  40
  41 my $EXITCODE = 'OK';
  42
  43 $SIG{'__DIE__'} = sub {
  44         print STDERR @_;
  45         exit $CODE{'UNKNOWN'};
  46 };
  47
  48 sub runcmd($) {
  49         my ($cmd) = @_;
  50         $cmd = "sudo hpacucli $cmd";
  51         open(FH, $cmd."|") or die ("Cannot run $cmd: $!");
  52         my @lines = <FH>;
  53         close FH;
  54         die ("no results from $cmd\n") if (scalar @lines == 0);
  55         return \@lines;
  56 }
  57
  58 sub record($) {
  59         my ($newexit) = @_;
  60         die "code $newexit not defined\n" unless defined $CODE{$newexit};
  61
  62         if ($CODE{$newexit} > $CODE{$EXITCODE}) {
  63                 $EXITCODE = $newexit;
  64         };
  65 }
  66
  67 my $usage = "$PROGRAM_NAME: Usage: $PROGRAM_NAME [--ignore-transfer-speed=<pd> [--ignore-transfer-speed=<pd> ...]]\n";
  68 my $params;
  69 Getopt::Long::Configure('bundling');
  70 if (!GetOptions (
  71         '--help'                      => \$params->{'help'},
  72         '--ignore-transfer-speed=s@'  => \$params->{'ignore-transfer-speed'},
  73         )) {
  74         die ($usage);
  75 };
  76 if ($params->{'help'}) {
  77         print $usage;
  78         exit (0);
  79 };
  80 die ($usage) unless (scalar @ARGV == 0);
  81
  82 my $ctrlallshow = runcmd("controller all show");
  83 my @controllers;
  84 for (@$ctrlallshow) {
  85         chomp;
  86         next if /^$/;
  87         if (/in Slot ([0-9a-z]+)/) {
  88                 push @controllers, $1;
  89                 next;
  90         };
  91         die ("Cannot read line '$_' gotten from hpacucli controller all show\n");
  92 };
  93
  94 if (scalar @controllers == 0) {
  95         print "UNKNONW: No smartarray controllers found with hpacucli\n";
  96         exit $CODE{'UNKNOWN'}
  97 };
  98
  99 my @resultstr;
 100
 101 for my $slot (sort @controllers) {
 102         my $pds = runcmd("controller slot=$slot pd all show");
 103         my @drives;
 104         my $nodrives = 0;
 105         my %status;
 106         for (@$pds) {
 107                 chomp;
 108                 next if /^$/;
 109                 next if (/^\S.*in Slot $slot/);
 110                 next if /^ *array [A-Z]$/;
 111                 if (/^ *(array [A-Z]) \(Failed\)$/) {
 112                         record('CRITICAL');
 113                         push @{$status{'Failed'}}, $1;
 114                 } elsif (/^Error: The specified controller does not have any physical drives on it.$/) {
 115                         $nodrives = 1;
 116                 } elsif (/^ *physicaldrive (\S+) .* (OK|Predictive Failure|Failed|Rebuilding)(?:, (?:active )?spare)?\)$/) {
 117                         my $drive = $1;
 118                         my $status = $2;
 119                         push @{$status{$status}}, $drive;
 120                         if ($status eq 'OK') {
 121                         } elsif ($status eq 'Predictive Failure' ||
 122                                  $status eq 'Rebuilding') {
 123                                 record('WARNING');
 124                         } elsif ($status eq 'Failed') {
 125                                 record('CRITICAL');
 126                         } else {
 127                                 record('UNKNOWN');
 128                         };
 129                         push @drives, $drive;
 130                 } else {
 131                         die ("Cannot read line '$_' gotten from hpacucli controller slot=$slot pd all show\n");
 132                 };
 133         };
 134
 135         # Check that all drives have the proper transfer speed.
 136         # sometimes stuff breaks and they fall back to 10mb/sec.
 137         for my $drive (@drives) {
 138                 # skip drives that are known to have failed
 139                 next if (exists $status{'Failed'} && grep {$drive eq $_} @{$status{'Failed'}});
 140                 my $type;
 141                 if ($drive =~ /^[0-9]+:[0-9]+$/) { # scsi drives
 142                         $type = 'SCSI';
 143                 } elsif ($drive =~ /^[0-9]+[EI]:[0-9]+:[0-9]+$/) { # SAS
 144                         $type = 'SAS';
 145                 } elsif ($drive =~ /^[0-9]+[C]:[0-9]+:[0-9]+$/) { # New 6GBPS SAS
 146                         $type = 'SAS+';
 147                 } else {
 148                         # I'm not going to run pass arguments of unknown form to the shell..
 149                         warn ("Unknown diskdrive ID $drive\n");
 150                         next;
 151                 }
 152
 153                 my $pd = runcmd("controller slot=$slot pd $drive show");
 154                 while (defined $pd->[0] && !($pd->[0] =~ /physicaldrive/)) {
 155                         shift @$pd;
 156                 };
 157                 shift @$pd;
 158                 my %value;
 159                 for (@$pd) {
 160                         if (m/^\s*(.*?):\s*(.*?)\s*$/) {
 161                                 $value{$1} = $2;
 162                         }
 163                 }
 164
 165                 my $key;
 166                 my $expected;
 167                 if ($type eq 'SCSI') {
 168                         $key = 'Transfer Speed';
 169                         if (!defined $value{'Transfer Mode'}) {
 170                                 record('WARNING');
 171                                 push @{$status{'unknown transfer mode'}}, $drive;
 172                                 next;
 173                         } elsif ($value{'Transfer Mode'} eq 'Ultra 3 Wide') {
 174                                 $expected = '160 MB/Sec';
 175                         } elsif ($value{'Transfer Mode'} eq 'Ultra 320 Wide') {
 176                                 $expected = '320 MB/Sec';
 177                         } else {
 178                                 record('WARNING');
 179                                 push @{$status{'unknown transfer mode'}}, $drive."(".$value{'Transfer Mode'}.")";
 180                                 next;
 181                         };
 182                 } elsif ($type eq 'SAS') {
 183                         $key = 'PHY Transfer Rate';
 184                         if ($value{'PHY Count'} eq '2') {
 185                                 if (defined($value{'Redundant Path(s)'})) {
 186                                         $expected = '3.0GBPS, 3.0GBPS';
 187                                 } else {
 188                                         $expected = [ '3.0GBPS, Unknown', 'Unknown, 3.0GBPS' ];
 189                                 }
 190                         } else {
 191                                 $expected = '3.0GBPS';
 192                         }
 193                 } elsif ($type eq 'SAS+') {
 194                         $key = 'PHY Transfer Rate';
 195                         if ($value{'PHY Count'} eq '2') {
 196                                 $expected = '6.0GBPS, Unknown';
 197                         } else {
 198                                 $expected = '6.0GBPS';
 199                         }
 200                 } else {
 201                         warn "Should not be here.  Do not know what to do with type '$type'\n";
 202                         next;
 203                 }
 204
 205                 if (exists $params->{'ignore-transfer-speed'}) {
 206                         if (grep { $drive eq $_ } @{$params->{'ignore-transfer-speed'}}) {
 207                                 push @{$status{'ignored transfer speed'}}, $drive."(".$value{$key}.")";
 208                         };
 209                         next;
 210                 };
 211                 if (!defined $value{$key}) {
 212                         record('WARNING');
 213                         push @{$status{'unknown transfer speed'}}, $drive;
 214                 } elsif (ref($expected) eq 'ARRAY') {
 215                         if (scalar(grep { $value{$key} eq $_ } @$expected) == 0) {
 216                                 record('WARNING');
 217                                 push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
 218                         };
 219                 } elsif ($value{$key} ne $expected) {
 220                         record('WARNING');
 221                         push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
 222                 };
 223         };
 224
 225         if ($nodrives && scalar keys %status > 0) {
 226                 push @resultstr, "Slot $slot: have no drives but status results?";
 227                 record('UNKNOWN');
 228                 next;
 229         } elsif ($nodrives) {
 230                 push @resultstr, "Slot $slot: no drives";
 231                 next;
 232         };
 233
 234         my $cst = runcmd("controller slot=$slot show status");
 235         for (@$cst) {
 236                 chomp;
 237                 next if /^$/;
 238                 next if (/^\S.*in Slot $slot/);
 239                 if (/^ *(.*) Status: (.*)$/) {
 240                         my $system = $1;
 241                         my $status = $2;
 242                         push @{$status{$status}}, $system;
 243                         if ($status ne 'OK') {
 244                                 record('WARNING');
 245                         };
 246                 } else {
 247                         die ("Cannot read line '$_' gotten from hpacucli controller slot=$slot show status\n");
 248                 };
 249         };
 250
 251         my $status = join(" - ", (map { $_.": ".join(", ", @{$status{$_}}) } keys %status));
 252         push @resultstr, "Slot $slot: $status";
 253 };
 254
 255 print "$EXITCODE: ", join(" --- ", @resultstr), "\n";
 256 exit $CODE{$EXITCODE};