dsa-nagios-checks/checks/dsa-check-hpacucli

   1 #!/usr/bin/perl -w
   2
   3 # check _physical_ disk status of disks on HP smart array controllers
   4 # requires hpacucli
   5 #
   6 # does _not_ check raid status.  use arrayprobe for that.
   7
   8 # Copyright (c) 2008,2009 Peter Palfrader <peter@palfrader.org>
   9 #
  10 # Permission is hereby granted, free of charge, to any person obtaining
  11 # a copy of this software and associated documentation files (the
  12 # "Software"), to deal in the Software without restriction, including
  13 # without limitation the rights to use, copy, modify, merge, publish,
  14 # distribute, sublicense, and/or sell copies of the Software, and to
  15 # permit persons to whom the Software is furnished to do so, subject to
  16 # the following conditions:
  17 #
  18 # The above copyright notice and this permission notice shall be
  19 # included in all copies or substantial portions of the Software.
  20 #
  21 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  22 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  23 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  24 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
  25 # LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
  26 # OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
  27 # WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  28
  29 use strict;
  30
  31 # nagios exit codes
  32 my %CODE = (
  33         'OK'            => 0,
  34         'WARNING'       => 1,
  35         'CRITICAL'      => 2,
  36         'UNKNOWN'       => 3
  37 );
  38
  39 my $EXITCODE = 'OK';
  40
  41 $SIG{'__DIE__'} = sub {
  42         print STDERR @_;
  43         exit $CODE{'UNKNOWN'};
  44 };
  45
  46 sub runcmd($) {
  47         my ($cmd) = @_;
  48         $cmd = "sudo hpacucli $cmd";
  49         open(FH, $cmd."|") or die ("Cannot run $cmd: $!");
  50         my @lines = <FH>;
  51         close FH;
  52         die ("no results from $cmd\n") if (scalar @lines == 0);
  53         return \@lines;
  54 }
  55
  56 sub record($) {
  57         my ($newexit) = @_;
  58         die "code $newexit not defined\n" unless defined $CODE{$newexit};
  59
  60         if ($CODE{$newexit} > $CODE{$EXITCODE}) {
  61                 $EXITCODE = $newexit;
  62         };
  63 }
  64
  65
  66 my $ctrlallshow = runcmd("controller all show");
  67 my @controllers;
  68 for (@$ctrlallshow) {
  69         chomp;
  70         next if /^$/;
  71         if (/in Slot ([0-9a-z]+)/) {
  72                 push @controllers, $1;
  73                 next;
  74         };
  75         die ("Cannot read line '$_' gotten from hpacucli controller all show\n");
  76 };
  77
  78 if (scalar @controllers == 0) {
  79         print "UNKNONW: No smartarray controllers found with hpacucli\n";
  80         exit $CODE{'UNKNOWN'}
  81 };
  82
  83 my @resultstr;
  84
  85 for my $slot (sort @controllers) {
  86         my $pds = runcmd("controller slot=$slot pd all show");
  87         my @drives;
  88         my $nodrives = 0;
  89         my %status;
  90         for (@$pds) {
  91                 chomp;
  92                 next if /^$/;
  93                 next if (/^\S.*in Slot $slot/);
  94                 next if /^ *array [A-Z]$/;
  95                 if (/^ *(array [A-Z]) \(Failed\)$/) {
  96                         record('CRITICAL');
  97                         push @{$status{'Failed'}}, $1;
  98                 } elsif (/^Error: The specified controller does not have any physical drives on it.$/) {
  99                         $nodrives = 1;
 100                 } elsif (/^ *physicaldrive (\S+) .* (OK|Predictive Failure|Failed|Rebuilding)(?:, (?:active )?spare)?\)$/) {
 101                         my $drive = $1;
 102                         my $status = $2;
 103                         push @{$status{$status}}, $drive;
 104                         if ($status eq 'OK') {
 105                         } elsif ($status eq 'Predictive Failure' ||
 106                                  $status eq 'Rebuilding') {
 107                                 record('WARNING');
 108                         } elsif ($status eq 'Failed') {
 109                                 record('CRITICAL');
 110                         } else {
 111                                 record('UNKNOWN');
 112                         };
 113                         push @drives, $drive;
 114                 } else {
 115                         die ("Cannot read line '$_' gotten from hpacucli controller slot=$slot pd all show\n");
 116                 };
 117         };
 118
 119         # Check that all drives have the proper transfer speed.
 120         # sometimes stuff breaks and they fall back to 10mb/sec.
 121         for my $drive (@drives) {
 122                 # skip drives that are known to have failed
 123                 next if (exists $status{'Failed'} && grep {$drive eq $_} @{$status{'Failed'}});
 124                 my $type;
 125                 if ($drive =~ /^[0-9]+:[0-9]+$/) { # scsi drives
 126                         $type = 'SCSI';
 127                 } elsif ($drive =~ /^[0-9]+[EI]:[0-9]+:[0-9]+$/) { # SAS
 128                         $type = 'SAS';
 129                 } elsif ($drive =~ /^[0-9]+[C]:[0-9]+:[0-9]+$/) { # New 6GBPS SAS
 130                         $type = 'SAS+';
 131                 } else {
 132                         # I'm not going to run pass arguments of unknown form to the shell..
 133                         warn ("Unknown diskdrive ID $drive\n");
 134                         next;
 135                 }
 136
 137                 my $pd = runcmd("controller slot=$slot pd $drive show");
 138                 while (defined $pd->[0] && !($pd->[0] =~ /physicaldrive/)) {
 139                         shift @$pd;
 140                 };
 141                 shift @$pd;
 142                 my %value;
 143                 for (@$pd) {
 144                         if (m/^\s*(.*?):\s*(.*?)\s*$/) {
 145                                 $value{$1} = $2;
 146                         }
 147                 }
 148
 149                 my $key;
 150                 my $expected;
 151                 if ($type eq 'SCSI') {
 152                         $key = 'Transfer Speed';
 153                         if (!defined $value{'Transfer Mode'}) {
 154                                 record('WARNING');
 155                                 push @{$status{'unknown transfer mode'}}, $drive;
 156                                 next;
 157                         } elsif ($value{'Transfer Mode'} eq 'Ultra 3 Wide') {
 158                                 $expected = '160 MB/Sec';
 159                         } elsif ($value{'Transfer Mode'} eq 'Ultra 320 Wide') {
 160                                 $expected = '320 MB/Sec';
 161                         } else {
 162                                 record('WARNING');
 163                                 push @{$status{'unknown transfer mode'}}, $drive."(".$value{'Transfer Mode'}.")";
 164                                 next;
 165                         };
 166                 } elsif ($type eq 'SAS') {
 167                         $key = 'PHY Transfer Rate';
 168                         if ($value{'PHY Count'} eq '2') {
 169                                 if (defined($value{'Redundant Path(s)'})) {
 170                                         $expected = '3.0GBPS, 3.0GBPS';
 171                                 } else {
 172                                         $expected = [ '3.0GBPS, Unknown', 'Unknown, 3.0GBPS' ];
 173                                 }
 174                         } else {
 175                                 $expected = '3.0GBPS';
 176                         }
 177                 } elsif ($type eq 'SAS+') {
 178                         $key = 'PHY Transfer Rate';
 179                         if ($value{'PHY Count'} eq '2') {
 180                                 $expected = '6.0GBPS, Unknown';
 181                         } else {
 182                                 $expected = '6.0GBPS';
 183                         }
 184                 } else {
 185                         warn "Should not be here.  Do not know what to do with type '$type'\n";
 186                         next;
 187                 }
 188
 189                 if (!defined $value{$key}) {
 190                         record('WARNING');
 191                         push @{$status{'unknown transfer speed'}}, $drive;
 192                 } elsif (ref($expected) eq 'ARRAY') {
 193                         if (scalar(grep { $value{$key} eq $_ } @$expected) == 0) {
 194                                 record('WARNING');
 195                                 push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
 196                         };
 197                 } elsif ($value{$key} ne $expected) {
 198                         record('WARNING');
 199                         push @{$status{'bad transfer speed'}}, $drive."(".$value{$key}.")";
 200                 };
 201         };
 202
 203         if ($nodrives && scalar keys %status > 0) {
 204                 push @resultstr, "Slot $slot: have no drives but status results?";
 205                 record('UNKNOWN');
 206                 next;
 207         } elsif ($nodrives) {
 208                 push @resultstr, "Slot $slot: no drives";
 209                 next;
 210         };
 211
 212         my $cst = runcmd("controller slot=$slot show status");
 213         for (@$cst) {
 214                 chomp;
 215                 next if /^$/;
 216                 next if (/^\S.*in Slot $slot/);
 217                 if (/^ *(.*) Status: (.*)$/) {
 218                         my $system = $1;
 219                         my $status = $2;
 220                         push @{$status{$status}}, $system;
 221                         if ($status ne 'OK') {
 222                                 record('WARNING');
 223                         };
 224                 } else {
 225                         die ("Cannot read line '$_' gotten from hpacucli controller slot=$slot show status\n");
 226                 };
 227         };
 228
 229         my $status = join(" - ", (map { $_.": ".join(", ", @{$status{$_}}) } keys %status));
 230         push @resultstr, "Slot $slot: $status";
 231 };
 232
 233 print "$EXITCODE: ", join(" --- ", @resultstr), "\n";
 234 exit $CODE{$EXITCODE};