dsa-nagios-checks/checks/dsa-check-dnssec-delegation

   1 #!/usr/bin/perl
   2
   3 # Copyright (c) 2010 Peter Palfrader <peter@palfrader.org>
   4 #
   5 # Permission is hereby granted, free of charge, to any person obtaining
   6 # a copy of this software and associated documentation files (the
   7 # "Software"), to deal in the Software without restriction, including
   8 # without limitation the rights to use, copy, modify, merge, publish,
   9 # distribute, sublicense, and/or sell copies of the Software, and to
  10 # permit persons to whom the Software is furnished to do so, subject to
  11 # the following conditions:
  12 #
  13 # The above copyright notice and this permission notice shall be
  14 # included in all copies or substantial portions of the Software.
  15 #
  16 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  17 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  18 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  19 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
  20 # LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
  21 # OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
  22 # WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  23
  24 use strict;
  25 use warnings;
  26 use English;
  27 use Net::DNS::Resolver;
  28 use Getopt::Long;
  29
  30 $SIG{'__DIE__'} = sub { print @_; exit 4; };
  31
  32 my $RES = Net::DNS::Resolver->new;
  33 my $DLV = 'dlv.isc.org';
  34
  35 sub get_tag_generic {
  36         my $zone = shift;
  37         my $type = shift;
  38
  39         my @result;
  40         my $pkt = $RES->send($zone, $type);
  41         return () unless $pkt;
  42         return () unless $pkt->answer;
  43         for my $rr ($pkt->answer) {
  44                 next unless ($rr->type eq $type);
  45                 next unless (lc($rr->name) eq lc($zone));
  46
  47                 # only handle KSKs, i.e. keys with the SEP flag set
  48                 next if ($type eq 'DNSKEY' && !($rr->is_sep));
  49
  50                 push @result, $rr->keytag;
  51         };
  52         my %unique = ();
  53         @result = sort {$a <=> $b} grep {!$unique{$_}++} @result;
  54         return @result
  55 };
  56
  57 sub get_dnskeytags {
  58         my $zone = shift;
  59         return get_tag_generic($zone, 'DNSKEY');
  60 };
  61 sub get_dstags {
  62         my $zone = shift;
  63         return get_tag_generic($zone, 'DS');
  64 };
  65 sub get_dlvtags {
  66         my $zone = shift;
  67         $zone .= ".".$DLV;
  68         return get_tag_generic($zone, 'DLV');
  69 };
  70
  71 sub usage {
  72         my $fd = shift;
  73         my $exit = shift;
  74
  75         print $fd "Usage: $PROGRAM_NAME [--dir <dir>] overview|check-dlv|check-ds|check-header zone [zone...]\n";
  76         print $fd "       $PROGRAM_NAME --dir <dir> overview|check-dlv|check-ds|check-header\n";
  77         print $fd "       $PROGRAM_NAME --help\n";
  78         exit $exit;
  79 }
  80
  81 sub what_to_check {
  82         my $zone = shift;
  83         my $indir = shift;
  84
  85         my $do_dlv = 0;
  86         my $do_ds = 0;
  87
  88         open(F, "<", $indir."/".$zone) or die ("Cannot open zonefile for $zone: $!\n");
  89         while (<F>) {
  90                 if (/^;\s*dlv-submit\s*=\s*yes\s*$/) { $do_dlv = 1; }
  91                 if (/^;\s*ds-in-parent\s*=\s*yes\s*$/) { $do_ds = 1; }
  92         }
  93         close(F);
  94
  95         my @keys = ();
  96         push @keys, 'dlv' if $do_dlv;
  97         push @keys, 'ds' if $do_ds;
  98         return @keys;
  99 }
 100
 101 my $params;
 102 Getopt::Long::config('bundling');
 103 GetOptions (
 104         '--help' => \$params->{'help'},
 105         '--dir=s' => \$params->{'dir'},
 106         '--dlv=s' => \$params->{'dlv'},
 107 ) or usage(\*STDERR, 1);
 108 usage(\*STDOUT, 0) if ($params->{'help'});
 109
 110 my $mode = shift @ARGV;
 111 usage(\*STDOUT, 0) unless (defined $mode && $mode =~ /^(overview|check-dlv|check-ds|check-header)$/);
 112 die ("check-header needs --dir") if ($mode eq 'check-header' && !defined $params->{'dir'});
 113
 114 my @zones;
 115 if (scalar @ARGV) {
 116         if (defined $params->{'dir'} && $mode ne 'check-header') {
 117                 warn "--dir option ignored"
 118         }
 119         @zones = @ARGV;
 120 } else {
 121         my $dir = $params->{'dir'};
 122         usage(\*STDOUT, 0) unless (defined $dir);
 123
 124         chdir $dir or die "chdir $dir failed? $!\n";
 125         opendir DIR, '.' or die ("Cannot opendir $dir\n");
 126         for my $file (readdir DIR) {
 127                 next if ( -l "$file" );
 128                 next unless ( -f "$file" );
 129                 next if $file =~ /^(dsset|keyset)-/;
 130
 131                 push @zones, $file;
 132         }
 133         closedir(DIR);
 134 };
 135
 136 $DLV = $params->{'dlv'} if $params->{'dlv'};
 137
 138 my %data;
 139 for my $zone (@zones) {
 140         $data{$zone} = { 'dnskey' => join(', ', get_dnskeytags($zone)),
 141                          'ds'     => join(', ', get_dstags($zone)),
 142                          'dlv'    => join(', ', get_dlvtags($zone)) };
 143 }
 144
 145 if ($mode eq 'overview') {
 146         my $format = "%60s %-10s %-10s %-10s\n";
 147         printf $format, "zone", "DNSKEY", "DS\@parent", "DLV";
 148         printf $format, "-"x 60,  "-"x 10,  "-"x 10,  "-"x 10;
 149         for my $zone (sort {$a cmp $b} keys %data) {
 150                 printf $format, $zone,
 151                         $data{$zone}->{'dnskey'},
 152                         $data{$zone}->{'ds'},
 153                         $data{$zone}->{'dlv'};
 154         }
 155         exit(0);
 156 } elsif ($mode eq 'check-dlv' || $mode eq 'check-ds' || $mode eq 'check-header') {
 157         my $key;
 158         $key = 'dlv' if $mode eq 'check-dlv';
 159         $key = 'ds' if $mode eq 'check-ds';
 160         $key = 'per-zone' if $mode eq 'check-header';
 161         die ("key undefined") unless $key;
 162
 163         my @warn;
 164         my @ok;
 165         for my $zone (sort {$a cmp $b} keys %data) {
 166                 my @thiskeys = $key eq 'per-zone' ? what_to_check($zone, $params->{'dir'}) : ($key);
 167
 168                 for my $thiskey (@thiskeys) {
 169                         my $dnskey = $data{$zone}->{'dnskey'} || '-';
 170                         my $target = $data{$zone}->{$thiskey} || '-';
 171
 172                         if ($dnskey ne $target) {
 173                                 push @warn, "$zone ($dnskey != $target)";
 174                         } else  {
 175                                 push @ok, "$zone ($dnskey)";
 176                         };
 177                 }
 178         }
 179         print "WARNING: ", join(", ", @warn), "\n" if (scalar @warn);
 180         print "OK: ", join(", ", @ok), "\n" if (scalar @ok);
 181         exit (1) if (scalar @warn);
 182         exit (0);
 183 } else {
 184         die ("Invalid mode '$mode'\n");
 185 };
 186