3rdparty/modules/postgresql/manifests/repo/yum_postgresql_org.pp

   1 # PRIVATE CLASS: do not use directly
   2 class postgresql::repo::yum_postgresql_org inherits postgresql::repo {
   3   $version_parts   = split($postgresql::repo::version, '[.]')
   4   $package_version = "${version_parts[0]}${version_parts[1]}"
   5   $gpg_key_path    = "/etc/pki/rpm-gpg/RPM-GPG-KEY-PGDG-${package_version}"
   6
   7   file { $gpg_key_path:
   8     source => 'puppet:///modules/postgresql/RPM-GPG-KEY-PGDG',
   9     owner  => 'root',
  10     group  => 'root',
  11     mode   => '0644',
  12     before => Yumrepo['yum.postgresql.org']
  13   }
  14
  15   if($::operatingsystem == 'Fedora') {
  16     $label1 = 'fedora'
  17     $label2 = $label1
  18   } else {
  19     $label1 = 'redhat'
  20     $label2 = 'rhel'
  21   }
  22   $default_baseurl = "https://download.postgresql.org/pub/repos/yum/${postgresql::repo::version}/${label1}/${label2}-\$releasever-\$basearch"
  23
  24   $_baseurl = pick($postgresql::repo::baseurl, $default_baseurl)
  25
  26   yumrepo { 'yum.postgresql.org':
  27     descr    => "PostgreSQL ${postgresql::repo::version} \$releasever - \$basearch",
  28     baseurl  => $_baseurl,
  29     enabled  => 1,
  30     gpgcheck => 1,
  31     gpgkey   => "file:///etc/pki/rpm-gpg/RPM-GPG-KEY-PGDG-${package_version}",
  32     proxy    => $postgresql::repo::proxy,
  33   }
  34
  35   Yumrepo['yum.postgresql.org'] -> Package<|tag == 'postgresql'|>
  36 }