X-Git-Url: https://git.adam-barratt.org.uk/?a=blobdiff_plain;f=modules%2Fvsftpd%2Fmanifests%2Fsite.pp;fp=modules%2Fvsftpd%2Fmanifests%2Fsite.pp;h=543332515ea3802e45b073145c016479b8ceab6e;hb=d0f5d088b88902979760c97ab31fd8cba677296b;hp=0000000000000000000000000000000000000000;hpb=46efb1d7284108553bc312019338f574a940030e;p=mirror%2Fdsa-puppet.git

diff --git a/modules/vsftpd/manifests/site.pp b/modules/vsftpd/manifests/site.pp
new file mode 100644
index 000000000..543332515
--- /dev/null
+++ b/modules/vsftpd/manifests/site.pp
@@ -0,0 +1,87 @@
+define vsftpd::site (
+	$root,
+	$binds=['[::]'],
+	$chown_user='',
+	$writable=false,
+	$writable_other=false,
+	$banner="${name} FTP Server",
+	$max_clients=100,
+	$logfile="/var/log/ftp/vsftpd-${name}.debian.org.log",
+	$ensure=present,
+) {
+	include vsftpd
+	include ferm::ftp_conntrack
+
+	case $ensure {
+		present,absent: {}
+		default: { fail ( "Invald ensure `$ensure' for $name" ) }
+	}
+
+	$ensure_service = $ensure ? {
+		present => running,
+		absent  => stopped,
+	}
+
+	$ensure_enable = $ensure ? {
+		present => true,
+		absent  => false,
+	}
+
+	$ftpsite = $name
+
+	$fname = "/etc/vsftpd-${name}.conf"
+
+	file { $fname:
+		ensure  => $ensure,
+		content => template('vsftpd/vsftpd.conf.erb'),
+		owner   => 'root',
+		group   => 'root',
+		mode    => '0444',
+	}
+
+	file { "/etc/logrotate.d/vsftpd-${name}":
+		ensure => absent
+	}
+
+	file { "/etc/systemd/system/vsftpd-${name}@.service":
+		ensure  => $ensure,
+		content => template('vsftpd/systemd-vsftpd.service.erb'),
+		owner   => 'root',
+		group   => 'root',
+		mode    => '0444',
+		require => File[$fname],
+		notify  => Exec['systemctl daemon-reload'],
+	}
+
+	file { "/etc/systemd/system/vsftpd-${name}.socket":
+		ensure  => $ensure,
+		content => template('vsftpd/systemd-vsftpd.socket.erb'),
+		owner   => 'root',
+		group   => 'root',
+		mode    => '0444',
+		notify  => [
+			Exec['systemctl daemon-reload'],
+			Service["vsftpd-${name}.socket"],
+		],
+	}
+
+	service { "vsftpd-${name}.socket":
+		ensure   => $ensure_service,
+		enable   => $ensure_enable,
+		require  => [
+			Exec['systemctl daemon-reload'],
+			File["/etc/systemd/system/vsftpd-${name}@.service"],
+			File["/etc/systemd/system/vsftpd-${name}.socket"],
+		],
+		provider => systemd,
+	}
+
+	munin::check { "vsftpd-${name}":
+		ensure => $ensure,
+		script => 'vsftpd'
+	}
+	munin::conf { "vsftpd-${name}":
+		ensure  => $ensure,
+		content => template('vsftpd/munin.erb')
+	}
+}