X-Git-Url: https://git.adam-barratt.org.uk/?a=blobdiff_plain;f=modules%2Froles%2Fmanifests%2Fsyncproxy.pp;h=aa452f0dc14f5ea5e5e93b3d2c8efb5168da9114;hb=e9e6c1abe830ad5d653c9afd237f437fb07ee3ed;hp=1aa82bbab2eaebf47b35d1d29a05f90af66fb48c;hpb=9f40474a37a6dec6418e4498f0b5ea3c7e25a8df;p=mirror%2Fdsa-puppet.git

diff --git a/modules/roles/manifests/syncproxy.pp b/modules/roles/manifests/syncproxy.pp
index 1aa82bbab..aa452f0dc 100644
--- a/modules/roles/manifests/syncproxy.pp
+++ b/modules/roles/manifests/syncproxy.pp
@@ -1,68 +1,76 @@
-class roles::syncproxy {
-	include roles::archvsync_base
+# a syncproxy
+# @param syncproxy_name  the service name of this syncproxy
+# @param listen_addr IP addresses to have rsync and apache listen on, and ssh to trigger from
+class roles::syncproxy(
+  String $syncproxy_name,
+  Array[Stdlib::IP::Address] $listen_addr = [],
+) {
+  include roles::archvsync_base
 
-	$mirror_basedir_prefix = hiera('role_config__syncproxy.mirror_basedir_prefix')
+  $enclosed_addresses_rsync = empty($listen_addr) ? {
+    true    => ['[::]'],
+    default => enclose_ipv6($listen_addr),
+  }
+  $enclosed_addresses_apache = empty($listen_addr) ? {
+    true    => ['*'],
+    default => enclose_ipv6($listen_addr),
+  }
+  $ssh_source_addresses = empty($listen_addr) ? {
+    true    => $base::public_addresses,
+    default => $listen_addr,
+  }
 
-	$binds = $::hostname ? {
-		'milanollo'    => [ '5.153.231.9', '[2001:41c8:1000:21::21:9]' ],
-		'mirror-anu'   => [ '150.203.164.60', '[2001:388:1034:2900::3c]' ],
-		'mirror-conova' => [ '217.196.149.237', '[2a02:16a8:dc41:100::237]' ],
-		'mirror-isc'   => [ '149.20.4.16', '[2001:4f8:1:c::16]' ],
-		'mirror-umn'   => [ '128.101.240.216', '[2607:ea00:101:3c0b::1deb:216]' ],
-		'klecker'      => [ '130.89.148.10', '[2001:67c:2564:a119::148:10]' ],
-		'gretchaninov' => [ '209.87.16.40', '[2607:f8f0:614:1::1274:40]' ],
-		default        => [ '[::]' ],
-	}
-	$syncproxy_name = $::hostname ? {
-		'milanollo' => 'syncproxy3.eu.debian.org',
-		'mirror-anu' => 'syncproxy.au.debian.org',
-		'mirror-conova' => 'syncproxy4.eu.debian.org',
-		'schmelzer' => 'syncproxy4.eu.debian.org',
-		'mirror-isc' => 'syncproxy2.wna.debian.org',
-		'mirror-umn' => 'syncproxy.cna.debian.org',
-		'klecker' => 'syncproxy2.eu.debian.org',
-		'gretchaninov' => 'syncproxy3.wna.debian.org',
-		default => 'unknown'
-	}
+  $mirror_basedir_prefix = hiera('role_config__syncproxy.mirror_basedir_prefix')
 
-	file { '/etc/rsyncd':
-		ensure => 'directory'
-	}
+  file { '/etc/rsyncd':
+    ensure => 'directory'
+  }
 
-	file { '/etc/rsyncd/debian.secrets':
-		owner => 'root',
-		group => 'mirroradm',
-		mode => '0660',
-	}
+  file { '/etc/rsyncd/debian.secrets':
+    owner => 'root',
+    group => 'mirroradm',
+    mode  => '0660',
+  }
 
-	if $::apache2 and $syncproxy_name != 'unknown' {
-		include apache2::ssl
-		ssl::service { "$syncproxy_name":
-			notify  => Exec['service apache2 reload'],
-			key => true,
-		}
-		apache2::site { '010-syncproxy.debian.org':
-			site   => 'syncproxy.debian.org',
-			content => template('roles/syncproxy/syncproxy.debian.org-apache.erb')
-		}
+  include apache2
+  include apache2::ssl
+  ssl::service { $syncproxy_name:
+    notify => Exec['service apache2 reload'],
+    key    => true,
+  }
+  apache2::site { '010-syncproxy.debian.org':
+    site    => 'syncproxy.debian.org',
+    content => template('roles/syncproxy/syncproxy.debian.org-apache.erb')
+  }
 
-		file { [ '/srv/www/syncproxy.debian.org', '/srv/www/syncproxy.debian.org/htdocs' ]:
-			ensure  => directory,
-			mode    => '0755',
-		}
-		file { '/srv/www/syncproxy.debian.org/htdocs/index.html':
-			content => template('roles/syncproxy/syncproxy.debian.org-index.html.erb')
-		}
+  file { [ '/srv/www/syncproxy.debian.org', '/srv/www/syncproxy.debian.org/htdocs' ]:
+    ensure => directory,
+    mode   => '0755',
+  }
+  file { '/srv/www/syncproxy.debian.org/htdocs/index.html':
+    content => template('roles/syncproxy/syncproxy.debian.org-index.html.erb')
+  }
 
-		rsync::site { 'syncproxy':
-			content => template('roles/syncproxy/rsyncd.conf.erb'),
-			binds   => $binds,
-			sslname => "$syncproxy_name",
-		}
-	} else {
-		rsync::site { 'syncproxy':
-			content => template('roles/syncproxy/rsyncd.conf.erb'),
-			binds   => $binds,
-		}
-	}
+  rsync::site { 'syncproxy':
+    content => template('roles/syncproxy/rsyncd.conf.erb'),
+    binds   => $enclosed_addresses_rsync,
+    sslname => $syncproxy_name,
+  }
+
+
+  # ssh firewalling setup
+  ###
+  @@ferm::rule::simple { "dsa-ssh-from-syncproxy-${::fqdn}":
+    tag         => 'ssh::server::from::syncproxy',
+    description => 'Allow ssh access from a syncproxy',
+    chain       => 'ssh',
+    saddr       => $ssh_source_addresses,
+  }
+  # syncproxies should be accessible from various role hosts
+  Ferm::Rule::Simple <<|
+    tag == 'ssh::server::from::syncproxy' or
+    tag == 'ssh::server::from::ftp_master' or
+    tag == 'ssh::server::from::ports_master' or
+    tag == 'ssh::server::from::security_master'
+    |>>
 }