X-Git-Url: https://git.adam-barratt.org.uk/?a=blobdiff_plain;f=modules%2Froles%2Fmanifests%2Fsecurity_mirror.pp;h=30f0ea0421efb20e764bfa04404b8e8715c2b2e1;hb=3324b4ae702172197fe7ad725a36f052f1e67c71;hp=13cba753058b848c2763374e74652204cc0c2131;hpb=3eb533e5499e66423bafdedaf6c7d08ead1772de;p=mirror%2Fdsa-puppet.git

diff --git a/modules/roles/manifests/security_mirror.pp b/modules/roles/manifests/security_mirror.pp
index 13cba7530..30f0ea042 100644
--- a/modules/roles/manifests/security_mirror.pp
+++ b/modules/roles/manifests/security_mirror.pp
@@ -1,11 +1,55 @@
 class roles::security_mirror {
+  include roles::archvsync_base
 
-	apache2::site { '010-security.debian.org':
-		site   => 'security.debian.org',
-		config => 'puppet:///modules/roles/security_mirror/security.debian.org'
-	}
+  # security abusers
+  #  198.108.67.48 DoS against our rsync service
+  ferm::rule { 'dsa-security-abusers':
+    prio => '005',
+    rule => 'saddr ( 198.108.67.48/32 ) DROP',
+  }
 
-	apache2::site { 'security.debian.org':
-		ensure => absent,
-	}
+  $binds = $::hostname ? {
+    mirror-anu => [ '150.203.164.61', '[2001:388:1034:2900::3d]' ],
+    mirror-isc => [ '149.20.4.14', '[2001:4f8:1:c::14]' ],
+    mirror-umn => [ '128.101.240.215', '[2607:ea00:101:3c0b::1deb:215]' ],
+    schmelzer  => [ '217.196.149.233', '[2a02:16a8:dc41:100::233]' ],
+    default    => [ '[::]' ],
+  }
+
+  include apache2::expires
+  include apache2::rewrite
+
+  apache2::site { '010-security.debian.org':
+    site    => 'security.debian.org',
+    content => template('roles/security_mirror/security.debian.org.erb')
+  }
+
+  $mirrors = hiera('roles.security_mirror', {})
+  $fastly_mirrors = $mirrors.filter |$h| { $h[1]['fastly-backend'] }
+  $hosts_to_check = $fastly_mirrors.map |$h| { $h[1]['service-hostname'] }
+
+  roles::mirror_health { 'security':
+    check_hosts   => $hosts_to_check,
+    check_service => 'security',
+    url           => 'http://security.backend.mirrors.debian.org/debian-security/dists/stable/updates/Release',
+    health_url    => 'http://security.backend.mirrors.debian.org/_health',
+        }
+
+  rsync::site { 'security':
+    source      => 'puppet:///modules/roles/security_mirror/rsyncd.conf',
+    max_clients => 100,
+    binds       => $binds,
+  }
+
+  $onion_v4_addr = hiera('roles.security_mirror', {})
+    .dig($::fqdn, 'onion_v4_address')
+  if $onion_v4_addr {
+    onion::service { 'security.debian.org':
+      port           => 80,
+      target_port    => 80,
+      target_address => $onion_v4_addr,
+    }
+  }
+
+  Ferm::Rule::Simple <<| tag == 'ssh::server::from::security_master' |>>
 }