# db server providing (secondary) snapshot databases
#
# @param db_port          port of the snapshot cluster
# @param guest_addresses  addresses to allow for the guest account
class roles::snapshot_db (
  Integer $db_port,
  Array[Stdlib::IP::Address] $guest_addresses = ['127.0.0.1', '::1'],
) {
  $now = Timestamp()
  $date = $now.strftime('%F')

  if versioncmp($date, '2020-01-15') <= 0 {
    $ensure = 'present'
  } else {
    $ensure = 'absent'
    notify {'Temporary old pg ignore rule expired, clean up puppet':
      loglevel => warning,
    }
  }
  file { '/etc/nagios/obsolete-packages-ignore.d/puppet-postgres':
    ensure  => $ensure,
    content => @(EOF),
      libperl5.24:amd64
      postgresql-client-9.6
      postgresql-contrib-9.6
      perl-modules-5.24
      postgresql-plperl-9.6
      postgresql-9.6-debversion
      libgdbm3:amd64
      postgresql-9.6
      | EOF
  }


  postgres::cluster::hba_entry { 'snapshot-guest':
    pg_port  => $db_port,
    database => 'snapshot',
    user     => 'guest',
    address  => $guest_addresses,
    method   => 'trust',
  }


}