# our puppet master role
class roles::puppetmaster {
  include puppetmaster

  ssh::authorized_key_collect { 'dsa_wiki_buildhost':
    target_user => 'dsa',
    collect_tag => 'puppetmaster',
  }

  ssh::authorized_key_collect { 'puppetmaster':
    target_user => 'puppet',
    collect_tag => 'puppetmaster',
  }

  # we have installed a newer libtrapperkeeper-webserver-jetty9-clojure,
  # cf. Debian#924005, Debian#930562
  if versioncmp(Timestamp().strftime('%F'), '2019-12-01') <= 0 {
    $ensure = versioncmp($::operatingsystemrelease, '10.1') <= 0 ? {
      true    => 'present',
      default => 'absent',
    }
    file { '/etc/nagios/obsolete-packages-ignore.d/libtrapperkeeper-webserver-jetty9-clojure':
      ensure  => $ensure,
      content => "libtrapperkeeper-webserver-jetty9-clojure\n",
    }
  } elsif versioncmp(Timestamp().strftime('%F'), '2020-02-01') <= 0 {
    notify {'Temporary ignore rule expired, package should be in the archive':
      loglevel => warning, }
  } else {
    fail('Clean up roles::puppetmaster')
  }
}