class roles::debian_mirror {
	include roles::archvsync_base

	$mirror_basedir_prefix = hiera('role_config__mirrors.mirror_basedir_prefix')
	$archive_root = "${mirror_basedir_prefix}debian"
        $listen_addresses = Hash(hiera('roles.debian_mirror').map |$h| {
                $h.map |$k, $v| { [$k,$v] }[0]
        }).dig($::fqdn, 'listen-addresses')
                .lest || { ['*:80'] }

        $vhost_listen = join([
                *$listen_addresses,
		has_role('bgp') ? {
			true => '193.31.7.2:80 [2a02:158:ffff:deb::2]:80',
			default => '',
		}], ' ')
	$onion_v4_addr = $::hostname ? {
		mirror-bytemark => '5.153.231.45',
		klecker    => '130.89.148.12',
		mirror-isc => '149.20.4.15',
		default    => undef,
	}

	apache2::site { '010-ftp.debian.org':
		site   => 'ftp.debian.org',
		content => template('roles/apache-ftp.debian.org.erb'),
	}

	if has_role('debian_mirror_onion') {
		if ! $onion_v4_addr {
			fail("Do not have an onion_v4_addr set for $::hostname.")
		}

		onion::service { 'ftp.debian.org':
			port => 80,
			target_port => 80,
			target_address => $onion_v4_addr,
		}
	}

        # roles is a list of hashes, which needs to be unpacked into a regular hash
        $mirrors = hiera('roles.debian_mirror', [])
        # unpack $mirrors and construct a hash
        $m2 = Hash($mirrors.map |$h| { $h.map |$k, $v| { [$k, $v] }[0]})
        $fastly_mirrors = $m2.filter |$h| { $h[1]['fastly-backend'] }
        $hosts_to_check = $fastly_mirrors.map |$h| { $h[1]['service-hostname'] }

        roles::mirror_health { 'ftp':
		check_hosts   => $hosts_to_check,
		check_service => 'ftp',
		url           => 'http://debian.backend.mirrors.debian.org/debian/dists/sid/Release',
		health_url    => 'http://debian.backend.mirrors.debian.org/_health',
        }
}