#
define postgres::backup_cluster(
  String $pg_version,
  String $pg_cluster = 'main',
  Integer $pg_port = 5432,
  String $db_backup_role = 'debian-backup',
  String $db_backup_role_password = hkdf('/etc/puppet/secret', "postgresql-${::hostname}-${$pg_cluster}-${pg_port}-backup_role}"),
  Boolean $do_role = false,
  Boolean $do_hba = false,
) {
  $datadir = "/var/lib/postgresql/${pg_version}/${pg_cluster}"
  file { "${datadir}/.nobackup":
    content  => ''
  }

  ## XXX - get these from the roles and ldap
  # backuphost, storace
  $backup_servers_addrs = ['5.153.231.12/32', '93.94.130.161/32', '2001:41c8:1000:21::21:12/128', '2a02:158:380:280::161/128']

  if $do_role {
    postgresql::server::role { $db_backup_role:
      password_hash => postgresql_password($db_backup_role, $db_backup_role_password),
      replication   => true,
    }
  }
  if $do_hba {
    $backup_servers_addrs.each |String $address| {
      postgresql::server::pg_hba_rule { "debian_backup-${address}":
        description => 'Open up PostgreSQL for backups',
        type        => 'hostssl',
        database    => 'replication',
        user        => $db_backup_role,
        address     => $address,
        auth_method => 'md5',
      }
    }
  }
  ferm::rule::simple { "dsa-postgres-backup-${pg_port}":
    description => 'Allow postgress access from backup host',
    port        => $pg_port,
    saddr       => $backup_servers_addrs,
  }

  postgres::backup_server::register_backup_cluster { "backup-role-${::fqdn}}-${pg_port}":
    pg_port     => $pg_port,
    pg_role     => $db_backup_role,
    pg_password => $db_backup_role_password,
    pg_cluster  => $pg_cluster,
    pg_version  => $pg_version,
  }
}