# the bacula storage node
#
# @param backup_path the directory where backups should be stored
# @param filestor_device Storage device name prefix
# @param filestor_name Storage device media type name prefix
class bacula::storage (
  String $backup_path     = '/srv/bacula',
  String $filestor_device = 'FileStorage',
  String $filestor_name   = 'File',
) inherits bacula {
  package { 'bacula-sd':
    ensure => installed
  }

  service { 'bacula-sd':
    ensure    => running,
    enable    => true,
    hasstatus => true,
  }
  dsa_systemd::override { 'bacula-sd':
    content => @(EOT)
      [Service]
      Group=bacula
      SupplementaryGroups=ssl-cert
      | EOT
  }

  exec { 'bacula-sd restart-when-idle':
    path        => '/usr/bin:/usr/sbin:/bin:/sbin',
    command     => "sh -c 'setsid /usr/local/sbin/bacula-idle-restart ${bacula::bacula_storage_port} bacula-sd &'",
    refreshonly => true,
    subscribe   => File[$bacula::bacula_ssl_server_cert],
    require     => File['/usr/local/sbin/bacula-idle-restart'],
  }


  file { '/etc/bacula/bacula-sd.conf':
    content => template('bacula/bacula-sd.conf.erb'),
    mode    => '0640',
    group   => bacula,
    notify  => Exec['bacula-sd restart-when-idle']
  }

  file { '/etc/bacula/storage-conf.d':
    ensure  => directory,
    mode    => '0755',
    group   => bacula,
    purge   => true,
    force   => true,
    recurse => true,
    source  => 'puppet:///files/empty/',
    notify  => Exec['bacula-sd restart-when-idle']
  }

  # allow access from director and fds
  ferm::rule::simple { 'dsa-bacula-sd':
    description => 'Access to the bacula-storage',
    port        => $bacula::bacula_storage_port,
    target      => 'bacula-sd',
  }
  Ferm::Rule::Simple <<| tag == "bacula::director-to-storage::${bacula::bacula_director_address}" |>>;
  Ferm::Rule::Simple <<| tag == "bacula::fd-to-storage::${::fqdn}" |>>;

  file { '/etc/bacula/storage-conf.d/empty.conf':
    content => '',
    mode    => '0440',
    group   => bacula,
    notify  => Exec['bacula-sd restart-when-idle']
  }

  package { 'python3-psycopg2': ensure => installed }
  file { '/usr/local/bin/bacula-unlink-removed-volumes':
    source => 'puppet:///modules/bacula/bacula-unlink-removed-volumes',
    mode   => '0555',
  }
  file { '/etc/cron.d/puppet-bacula-storage-stuff': ensure => absent, }
  concat::fragment { 'puppet-crontab--bacula-storage':
    target  => '/etc/cron.d/puppet-crontab',
    content => @(EOF)
      @daily bacula chronic /usr/local/bin/bacula-unlink-removed-volumes -v
      | EOF
  }

  Bacula::Storage::Client<<| tag == "bacula::to-storage::${::fqdn}" |>>
}