# Bacula storage configuration for a client.
#
# This is stored config by a client and then collected on the storage
#
# @param director_server  director for this client
# @param client           name/address of the client (relevant for device names, media type names, etc.)
define bacula::storage::client(
  String $director_server,
  Stdlib::Host $client = $name
) {
  include bacula::storage

  $device_name     = "${bacula::storage::filestor_device}-${client}"
  $media_type_name = "${bacula::storage::filestor_name}-${client}"
  $directory       = "${bacula::storage::backup_path}/${client}"

  file {
    "/etc/bacula/storage-conf.d/${client}.conf":
      content => template('bacula/storage/sd-per-client.conf.erb'),
      mode    => '0440',
      group   => bacula,
      notify  => Exec['bacula-sd restart-when-idle'],
      ;
    $directory:
      ensure => directory,
      mode   => '0755',
      owner  => bacula,
      group  => bacula,
      ;
  }

  # enable the director to make (client, storage) specific configuration
  @@bacula::director::client_from_storage { $client:
    tag                     => "bacula::to-director::${director_server}",
    client                  => $client,
    storage_address         => $bacula::storage::storage_address,
    port_sd                 => $bacula::storage::port_sd,
    storage_secret          => $bacula::storage::storage_secret,
    storage_device_name     => $device_name,
    storage_media_type_name => $media_type_name,
  }
}